MuCHSALSA/CMakeLists.txt at develop · 0x002A/MuCHSALSA · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
cmake_minimum_required(VERSION 3.16.0)

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

set(VERSION_MAJOR 0 CACHE STRING "Project major version number.")
set(VERSION_MINOR 0 CACHE STRING "Project minor version number.")
set(VERSION_PATCH 2 CACHE STRING "Project patch version number.")
mark_as_advanced(VERSION_MAJOR VERSION_MINOR VERSION_PATCH)

set(CMAKE_C_COMPILER "clang-15")
set(CMAKE_CXX_COMPILER "clang++-15")

set(TARGET "muchsalsa")
set(LIBNAME "ms")

project(${TARGET} CXX)
include(cmake/StandardProjectSettings.cmake)
include(cmake/PreventInSourceBuilds.cmake)

add_library(project_options INTERFACE)

option(ENABLE_BUILD_WITH_TIME_TRACE "Enable -ftime-trace to generate time tracing .json files on clang" OFF)
if (ENABLE_BUILD_WITH_TIME_TRACE)
    target_compile_options(project_options INTERFACE -ftime-trace)
endif ()

add_library(project_warnings INTERFACE)

include(cmake/Cache.cmake)

include(cmake/CompilerWarnings.cmake)
set_project_warnings(project_warnings)

include(cmake/Sanitizers.cmake)
enable_sanitizers(project_options)

include(cmake/StaticAnalyzers.cmake)

option(ENABLE_TESTING "Enable Test Builds" ON)

option(ENABLE_PCH "Enable Precompiled Headers" ON)
if (ENABLE_PCH)
    target_precompile_headers(
            project_options
            INTERFACE
            <cstddef>
            <map>
            <string>
            <tuple>
            <unordered_map>
            <utility>
            <vector>)
endif ()

if (ENABLE_TESTING)
    enable_testing()
endif ()

add_subdirectory("lib${LIBNAME}")

file(GLOB_RECURSE SOURCES RELATIVE ${CMAKE_SOURCE_DIR} "src/*.cpp")
add_executable(${TARGET} ${SOURCES})

option(ENABLE_TRACK_MEMORY_USAGE "Enable tracking of memory allocations" OFF)
if (ENABLE_TRACK_MEMORY_USAGE)
    target_compile_definitions(${TARGET} PRIVATE TRACK_MEMORY_USAGE)
endif ()

option(ENABLE_BUILD_FAT_EXE "Enable linking dependencies statically" OFF)
if (ENABLE_BUILD_FAT_EXE)
    target_link_options(${TARGET} PRIVATE -static)
endif ()

target_include_directories(${TARGET} PRIVATE "include")
target_link_libraries(
        ${TARGET}
        PRIVATE ${LIBNAME}
        PRIVATE c++
        PRIVATE c++abi
        PRIVATE project_options
        PRIVATE project_warnings)