4-bull4zo-be/build.gradle at develop · 100-hours-a-week/4-bull4zo-be · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.4.5'
	id 'io.spring.dependency-management' version '1.1.7'

	id 'checkstyle'
	id 'com.diffplug.spotless' version '6.25.0'
}

group = 'com.moa'
version = 'v3.2.1'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}

	configureEach {
		exclude group: 'commons-logging', module: 'commons-logging'
	}
}

repositories {
	mavenCentral()
}

dependencyManagement {
  imports {
    mavenBom "software.amazon.awssdk:bom:2.20.0"
  }
}

dependencies {
	// Spring
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	developmentOnly 'org.springframework.boot:spring-boot-devtools'

	// DB & JPA
	implementation 'com.mysql:mysql-connector-j'
	implementation 'org.apache.commons:commons-lang3:3.12.0'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'

	// JWT
	implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'

	// QueryDSL
	implementation "com.querydsl:querydsl-core:5.1.0"
	implementation "com.querydsl:querydsl-jpa:5.1.0:jakarta"
	annotationProcessor "com.querydsl:querydsl-apt:5.1.0:jakarta"
	annotationProcessor 'jakarta.persistence:jakarta.persistence-api'
	annotationProcessor 'jakarta.annotation:jakarta.annotation-api'

  // Redis
  implementation 'org.springframework.boot:spring-boot-starter-data-redis'

  // MongoDB
  implementation 'org.springframework.boot:spring-boot-starter-data-mongodb'

  // AWS
  implementation 'software.amazon.awssdk:s3'

	// Swagger
	implementation "org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.8"

	// 기타
	implementation "org.apache.httpcomponents.client5:httpclient5:5.4.4" // RestTemplate
	implementation 'com.navercorp.lucy:lucy-xss:1.6.3' // XSS Filtering
  implementation 'com.fasterxml.jackson.core:jackson-databind' // JSON 직렬화/역직렬화

	// Test
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.security:spring-security-test'
  testImplementation 'com.h2database:h2'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
  testImplementation 'com.jayway.jsonpath:json-path'

  // Prometheus / Micrometer
  implementation 'org.springframework.boot:spring-boot-starter-actuator'
  implementation 'io.micrometer:micrometer-registry-prometheus'
}

spotless {
	java {
		googleJavaFormat('1.17.0')
		target 'src/**/*.java'
	}
}

checkstyle {
	toolVersion = '10.23.1'
	configFile = file("$rootDir/config/checkstyle/checkstyle.xml")
	configProperties = [
			'checkstyle.suppressions.file': file("$rootDir/config/checkstyle/suppressions.xml")
	]
}

tasks.named('test') {
	useJUnitPlatform()
}

tasks.named("checkstyleMain") {
  dependsOn "compileJava", "compileTestJava"
}

// QueryDSL Q파일 생성용
def querydslDir = layout.buildDirectory.dir("generated/querydsl").get().asFile

sourceSets {
	main {
		java {
			srcDir querydslDir
		}
	}
}

tasks.withType(JavaCompile).configureEach {
	options.generatedSourceOutputDirectory.set(querydslDir)
}

compileJava {
	options.annotationProcessorPath = configurations.annotationProcessor
}