PicoUSBKeyBridge/CMakeLists.txt at main · 2opremio/PicoUSBKeyBridge · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
cmake_minimum_required(VERSION 3.13)

option(PICOUSBKEYBRIDGE_FORCE_RP2350_DEFAULT "Force RP2350 defaults if unset or rp2040" OFF)
if (PICOUSBKEYBRIDGE_FORCE_RP2350_DEFAULT)
  if (NOT DEFINED PICO_PLATFORM OR PICO_PLATFORM STREQUAL "" OR PICO_PLATFORM STREQUAL "rp2040")
    set(PICO_PLATFORM rp2350-arm-s CACHE STRING "Pico platform")
  endif ()
  if (NOT DEFINED PICO_BOARD OR PICO_BOARD STREQUAL "" OR PICO_BOARD STREQUAL "pico" OR PICO_BOARD STREQUAL "pico2")
    set(PICO_BOARD waveshare_rp2350_usb_a CACHE STRING "Pico board")
  endif ()
else ()
  if (NOT PICO_PLATFORM)
    set(PICO_PLATFORM rp2350-arm-s CACHE STRING "Pico platform")
  endif ()
  if (NOT PICO_BOARD)
    set(PICO_BOARD waveshare_rp2350_usb_a CACHE STRING "Pico board")
  endif ()
endif ()

if (NOT PICO_SDK_PATH AND EXISTS "${CMAKE_CURRENT_LIST_DIR}/third_party/pico-sdk")
  set(PICO_SDK_PATH "${CMAKE_CURRENT_LIST_DIR}/third_party/pico-sdk")
endif ()

include(cmake/pico_sdk_import.cmake)

project(PicoUSBKeyBridge C CXX ASM)
set(CMAKE_C_STANDARD 11)
set(CMAKE_CXX_STANDARD 17)

pico_sdk_init()

set(PUSBKB_UART_INDEX "1" CACHE STRING "UART instance index (0 or 1)")
set(PUSBKB_UART_BAUDRATE "115200" CACHE STRING "UART baud rate")
set(PUSBKB_UART_TX_PIN "4" CACHE STRING "UART TX GPIO pin")
set(PUSBKB_UART_RX_PIN "5" CACHE STRING "UART RX GPIO pin")
option(PUSBKB_HID_TEST "Enable USB-C HID test mode" OFF)

execute_process(
  COMMAND git rev-parse --short HEAD
  WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}
  RESULT_VARIABLE PUSBKB_GIT_RESULT
  OUTPUT_VARIABLE PUSBKB_GIT_COMMIT
  OUTPUT_STRIP_TRAILING_WHITESPACE
)
if (NOT PUSBKB_GIT_RESULT EQUAL 0)
  set(PUSBKB_GIT_COMMIT "unknown")
endif ()

add_executable(PicoUSBKeyBridge
  src/log.c
  src/main.c
  src/usb_descriptors.c
)

target_include_directories(PicoUSBKeyBridge PRIVATE src)
target_link_libraries(PicoUSBKeyBridge PRIVATE
  pico_stdlib
  hardware_watchdog
  tinyusb_device
)

target_compile_definitions(PicoUSBKeyBridge PRIVATE
  PUSBKB_GIT_COMMIT=\"${PUSBKB_GIT_COMMIT}\"
  PUSBKB_UART_INDEX=${PUSBKB_UART_INDEX}
  PUSBKB_UART_BAUDRATE=${PUSBKB_UART_BAUDRATE}
  PUSBKB_UART_TX_PIN=${PUSBKB_UART_TX_PIN}
  PUSBKB_UART_RX_PIN=${PUSBKB_UART_RX_PIN}
  $<$<BOOL:${PUSBKB_HID_TEST}>:PUSBKB_HID_TEST=1>
)

pico_enable_stdio_uart(PicoUSBKeyBridge 1)
pico_enable_stdio_usb(PicoUSBKeyBridge 0)
pico_add_extra_outputs(PicoUSBKeyBridge)