NPatch-Remote-API/build.gradle.kts at master · 7723mod/NPatch-Remote-API · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
plugins {
    id("com.android.library")
    id("maven-publish")
}

group = "top.nkbe.npatch"
version = "1.0.1"

android {
    namespace = "top.nkbe.npatch.remote"
    compileSdk = 37

    defaultConfig {
        minSdk = 28
        consumerProguardFiles("consumer-rules.pro")
    }

    buildFeatures {
        androidResources = false
        buildConfig = false
    }

    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    publishing {
        singleVariant("release") {
            withSourcesJar()
        }
    }
}

dependencies {
    compileOnly("io.github.libxposed:interface:102.0.0")
}

publishing {
    publications {
        register<MavenPublication>("release") {
            groupId = project.group.toString()
            artifactId = "npatch-remote-api"
            version = project.version.toString()
            afterEvaluate {
                from(components["release"])
            }
            pom {
                name = "NPatch Remote API"
                description = "Authenticated NPatch Manager remote storage client for Xposed module apps"
                url = "https://github.com/7723mod/NPatch-Remote-API"
                licenses {
                    license {
                        name = "Apache License 2.0"
                        url = "https://www.apache.org/licenses/LICENSE-2.0"
                    }
                }
                scm {
                    url = "https://github.com/7723mod/NPatch-Remote-API"
                    connection = "scm:git:https://github.com/7723mod/NPatch-Remote-API.git"
                }
            }
        }
    }
}