AA-ContactMerger/build.gradle at main · Alfly-Alyx/AA-ContactMerger · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {

    repositories {
        mavenCentral()
        google()
        gradlePluginPortal()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:8.10.1'
    }
}

repositories {
    google()
    mavenCentral()
    gradlePluginPortal()
    flatDir {
        dirs 'libs'
    }
}

apply plugin: 'com.android.application'

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11

dependencies {
    implementation 'com.tundem.aboutlibraries:library:2.0.3@aar'
    implementation 'androidx.core:core:1.15.0'
    implementation 'org.ow2.asm:asm:4.0'
    implementation 'androidx.localbroadcastmanager:localbroadcastmanager:1.0.0'
    implementation 'com.esotericsoftware.kryo:kryo:2.24.0'
    implementation files('libs/lucene-core-4.7.1-android.jar')
    implementation 'org.apache.lucene:lucene-misc:4.7.1'
    implementation 'org.apache.lucene:lucene-queries:4.7.1'
    implementation 'org.apache.lucene:lucene-analyzers-common:4.7.1'
    implementation 'org.apache.lucene:lucene-codecs:4.7.1'
}

configurations.configureEach {
    // The local Lucene core omits SPIClassIterator so the Android-specific
    // implementation in src/ can load service definitions from app assets.
    exclude group: 'org.apache.lucene', module: 'lucene-core'
}

android {
    namespace = "com.alyx.contactmerger"
    compileSdk 36
    defaultConfig {
        applicationId "com.alyx.contactmerger"
        minSdk 23
        targetSdk 36
    }

    packagingOptions {
        resources {
            excludes += ['META-INF/LICENSE.txt', 'META-INF/NOTICE.txt', 'META-INF/services/org.apache.lucene.codecs.Codec', 'META-INF/services/org.apache.lucene.codecs.PostingsFormat', 'META-INF/services/org.apache.lucene.codecs.DocValuesFormat']
            pickFirsts += ['org/apache/lucene/util/SPIClassIterator.class']
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['src']
            resources.srcDirs = ['src']
            aidl.srcDirs = ['src', 'aidl']
            renderscript.srcDirs = ['src']
            res.srcDirs = ['res']
            assets.srcDirs = ['assets']
        }
    }

    signingConfigs {
        release { }
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release
        }
    }

    def signingPropertiesFile = rootProject.file('signing.properties')
    def signingProperties = new Properties()
    if (signingPropertiesFile.exists()) {
        signingPropertiesFile.withInputStream { signingProperties.load(it) }
    }

    if (!signingProperties.isEmpty()) {
        android.signingConfigs.release.storeFile = rootProject.file(signingProperties.getProperty('storeFile'))
        android.signingConfigs.release.storePassword = signingProperties.getProperty('storePassword')
        android.signingConfigs.release.keyPassword = signingProperties.getProperty('keyPassword')
        android.signingConfigs.release.keyAlias = signingProperties.getProperty('keyAlias')
    } else {
        buildTypes.release.signingConfig = null
    }
}