xenopsd: trigger online resize by writing xenstore

Signed-off-by: Anthoine Bourgeois <anthoine.bourgeois@vates.tech>

Author: AnthoineB

ocaml/idl/datamodel.ml

@@ -6504,6 +6504,7 @@ module VBD = struct
         ; ("unplug_force", "Attempting to forcibly unplug this VBD")
         ; ("pause", "Attempting to pause a block device backend")
         ; ("unpause", "Attempting to unpause a block device backend")
+        ; ("resize_online", "Attempting to online resize a block device backend")
         ]
       )
 
@@ -6533,6 +6534,17 @@ module VBD = struct
       ~errs:[Api_errors.vbd_not_removable_media; Api_errors.vbd_not_empty]
       ~allowed_roles:_R_VM_OP ()
 
+  let resize_online =
+    call ~name:"resize_online"
+      ~lifecycle:[(Published, rel_rio, "Resize a media online")]
+      ~doc:"Resize a media online"
+      ~params:
+        [
+          (Ref _vbd, "vbd", "The vbd representing the device")
+        ; (Int, "size", "The new size of the media")
+        ]
+      ~allowed_roles:_R_VM_ADMIN ()
+
   let plug =
     call ~name:"plug"
       ~lifecycle:
@@ -6714,6 +6726,7 @@ module VBD = struct
         ; pause
         ; unpause
         ; set_mode
+        ; resize_online
         ]
       ~contents:
         ([

ocaml/idl/schematest.ml

@@ -3,7 +3,7 @@ let hash x = Digest.string x |> Digest.to_hex
 (* BEWARE: if this changes, check that schema has been bumped accordingly in
    ocaml/idl/datamodel_common.ml, usually schema_minor_vsn *)
 
-let last_known_schema_hash = "3b20f4304cfaaa7b6213af91ae632e64"
+let last_known_schema_hash = "acf96a87d6dad370c7000e7d299c1f41"
 
 let current_schema_hash : string =
   let open Datamodel_types in

ocaml/xapi-cli-server/cli_operations.ml

@@ -2008,9 +2008,25 @@ let vdi_resize _printer rpc session_id params =
   let online =
     List.mem_assoc "online" params && List.assoc "online" params = "true"
   in
-  if online then
-    Client.VDI.resize_online ~rpc ~session_id ~vdi ~size:new_size
-  else
+  if online then (
+    Client.VDI.resize_online ~rpc ~session_id ~vdi ~size:new_size;
+    let all_vbds = Client.VDI.get_VBDs ~rpc ~session_id ~self:vdi in
+    let all_vbd_records = List.map (vbd_record rpc session_id) all_vbds in
+    let active_records =
+      List.filter
+        (fun x -> (field_lookup x.fields "currently-attached").get () = "true")
+        all_vbd_records
+    in
+    List.iter
+      (fun vbd_record ->
+        let vbd_uuid = (field_lookup vbd_record.fields "uuid").get () in
+        let vbd =
+          Client.VBD.get_by_uuid ~rpc ~session_id ~uuid:vbd_uuid
+        in
+        Client.VBD.resize_online ~rpc ~session_id ~vbd ~size:new_size
+      )
+      active_records
+  ) else
     Client.VDI.resize ~rpc ~session_id ~vdi ~size:new_size
 
 let vdi_generate_config printer rpc session_id params =

ocaml/xapi-idl/xen/xenops_interface.ml

@@ -954,6 +954,11 @@ module XenopsAPI (R : RPC) = struct
     let remove =
       declare "VBD.remove" []
         (debug_info_p @-> vbd_id_p @-> returning unit_p err)
+
+    let resize_online =
+      let new_size_p = Param.mk ~name:"new_size" Types.int64 in
+      declare "VBD.resize_online" []
+        (debug_info_p @-> vbd_id_p @-> new_size_p @-> returning task_id_p err)
   end
 
   module VUSB = struct

ocaml/xapi/message_forwarding.ml

@@ -5694,6 +5694,15 @@ functor
       let assert_attachable ~__context ~self =
         info "VBD.assert_attachable: VBD = '%s'" (vbd_uuid ~__context self) ;
         Local.VBD.assert_attachable ~__context ~self
+
+      let resize_online ~__context ~vbd ~size =
+        info "VBD.resize_online: VBD = '%s'; size = %Ld" (vbd_uuid ~__context vbd) size ;
+        let local_fn = Local.VBD.resize_online ~vbd ~size in
+        let remote_fn = Client.VBD.resize_online ~vbd ~size in
+        with_vbd_marked ~__context ~vbd ~doc:"VBD.resize_online" ~op:`resize_online (fun () ->
+          forward_vbd_op ~local_fn ~__context ~self:vbd ~remote_fn
+        ) ;
+        update_vbd_and_vdi_operations ~__context ~vbd
     end
 
     module VBD_metrics = struct end

ocaml/xapi/xapi_vbd.ml

@@ -342,6 +342,10 @@ let insert ~__context ~vbd ~vdi =
   assert_ok_to_insert ~__context ~vbd ~vdi ;
   Xapi_xenops.vbd_insert ~__context ~self:vbd ~vdi
 
+let resize_online ~__context ~vbd ~size =
+  assert_not_empty ~__context ~vbd ;
+  Xapi_xenops.vbd_resize_online ~__context ~self:vbd ~value:size
+
 let assert_ok_to_eject ~__context ~vbd =
   let vm = Db.VBD.get_VM ~__context ~self:vbd in
   assert_removable ~__context ~vbd ;

ocaml/xapi/xapi_vbd_helpers.ml

@@ -29,7 +29,7 @@ open D
 open Record_util
 
 let all_ops : API.vbd_operations_set =
-  [`attach; `eject; `unplug; `unplug_force; `insert; `plug; `pause; `unpause]
+  [`attach; `eject; `unplug; `unplug_force; `insert; `plug; `pause; `unpause; `resize_online]
 
 type table = (API.vbd_operations, (string * string list) option) Hashtbl.t
 

ocaml/xapi/xapi_xenops.ml

@@ -4213,6 +4213,22 @@ let vbd_insert_hvm ~__context ~self ~vdi =
           (Ref.string_of self) (Ref.string_of vdi) (Ref.string_of vdi)
   )
 
+let vbd_resize_online ~__context ~self ~value =
+  let@ __context = Context.with_tracing ~__context __FUNCTION__ in
+  let vm = Db.VBD.get_VM ~__context ~self in
+  let queue_name = queue_of_vm ~__context ~self:vm in
+  transform_xenops_exn ~__context ~vm queue_name (fun () ->
+      assert_resident_on ~__context ~self:vm ;
+      let vbd = md_of_vbd ~__context ~self in
+      info "xenops: VBD.resize_online %s.%s %Ld" (fst vbd.Vbd.id) (snd vbd.Vbd.id) value ;
+      let id = id_of_vm ~__context ~self:vm in
+      let dbg = Context.string_of_task_and_tracing __context in
+      let module Client = (val make_client queue_name : XENOPS) in
+      debug "xenops: VBD.resize_online %s" id ;
+      Client.VBD.resize_online dbg vbd.Vbd.id value |> sync_with_task __context queue_name ;
+      Events_from_xenopsd.wait queue_name dbg id ()
+  )
+
 let has_qemu ~__context ~vm =
   let@ __context = Context.with_tracing ~__context __FUNCTION__ in
   let dbg = Context.string_of_task_and_tracing __context in

ocaml/xenopsd/lib/xenops_server.ml

@@ -134,6 +134,7 @@ type atomic =
   | VBD_detach of Vbd.id
   | VBD_insert of Vbd.id * disk
   | VBD_set_active of Vbd.id * bool
+  | VBD_resize_online of Vbd.id * int64
   | VM_remove of Vm.id
   | PCI_plug of Pci.id * bool (* use Qmp.add_device *)
   | PCI_unplug of Pci.id
@@ -223,6 +224,8 @@ let rec name_of_atomic = function
       "VBD_insert"
   | VBD_set_active _ ->
       "VBD_set_active"
+  | VBD_resize_online _ ->
+      "VBD_resize_online"
   | VM_remove _ ->
       "VM_remove"
   | PCI_plug _ ->
@@ -2138,6 +2141,17 @@ let rec perform_atomic ~progress_callback ?result (op : atomic)
       | _ ->
           raise (Xenopsd_error (Bad_power_state (power, Running)))
     )
+  | VBD_resize_online (id, new_size) -> (
+      debug "VBD.resize_online %s" (VBD_DB.string_of_id id) ;
+      let vbd_t = VBD_DB.read_exn id in
+      let power = (B.VM.get_state (VM_DB.read_exn (fst id))).Vm.power_state in
+      match power with
+      | Running | Paused ->
+          B.VBD.resize_online t (VBD_DB.vm_of id) vbd_t new_size ;
+          VBD_DB.signal id
+      | _ ->
+          raise (Xenopsd_error (Bad_power_state (power, Running)))
+    )
   | VM_remove id -> (
       debug "VM.remove %s" id ;
       let vm_t = VM_DB.read_exn id in
@@ -2624,6 +2638,7 @@ and trigger_cleanup_after_failure_atom op t =
   | VBD_unplug (id, _)
   | VBD_deactivate (id, _)
   | VBD_detach id
+  | VBD_resize_online (id, _)
   | VBD_insert (id, _) ->
       immediate_operation dbg (fst id) (VBD_check_state id)
   | VIF_plug id
@@ -3555,6 +3570,9 @@ module VBD = struct
     Debug.with_thread_associated dbg
       (fun () -> debug "VBD.list %s" vm ; DB.list vm)
       ()
+
+  let resize_online _ dbg id new_size =
+    queue_operation dbg (DB.vm_of id) (Atomic (VBD_resize_online (id, new_size)))
 end
 
 module VIF = struct
@@ -4421,6 +4439,7 @@ let _ =
   Server.VBD.unplug (VBD.unplug ()) ;
   Server.VBD.eject (VBD.eject ()) ;
   Server.VBD.insert (VBD.insert ()) ;
+  Server.VBD.resize_online (VBD.resize_online ()) ;
   Server.VUSB.add (VUSB.add ()) ;
   Server.VUSB.remove (VUSB.remove ()) ;
   Server.VUSB.stat (VUSB.stat ()) ;

ocaml/xenopsd/lib/xenops_server_plugin.ml

@@ -229,6 +229,8 @@ module type S = sig
 
     val get_device_action_request :
       Vm.id -> Vbd.t -> device_action_request option
+
+    val resize_online : Xenops_task.task_handle -> Vm.id -> Vbd.t -> int64 -> unit
   end
 
   module VIF : sig