terraform-azurerm-avm-ptn-aiml-landing-zone/main.knowledge_sources.tf at main · Azure/terraform-azurerm-avm-ptn-aiml-landing-zone · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
module "search_service" {
  source  = "Azure/avm-res-search-searchservice/azurerm"
  version = "0.2.0"
  count   = var.ks_ai_search_definition.deploy ? 1 : 0

  location                     = azurerm_resource_group.this.location
  name                         = local.ks_ai_search_name
  resource_group_name          = azurerm_resource_group.this.name
  diagnostic_settings          = local.ks_ai_search_diagnostic_settings
  enable_telemetry             = var.enable_telemetry # see variables.tf
  local_authentication_enabled = var.ks_ai_search_definition.local_authentication_enabled
  partition_count              = var.ks_ai_search_definition.partition_count
  private_endpoints = {
    primary = {
      private_dns_zone_resource_ids = var.private_dns_zones.azure_policy_pe_zone_linking_enabled ? null : (var.flag_platform_landing_zone ? [module.private_dns_zones.ai_search_zone.resource_id] : [local.private_dns_zones_existing.ai_search_zone.resource_id])
      subnet_resource_id            = local.subnet_ids["PrivateEndpointSubnet"]
    }
  }
  public_network_access_enabled = var.ks_ai_search_definition.public_network_access_enabled
  replica_count                 = var.ks_ai_search_definition.replica_count
  role_assignments              = local.ks_ai_search_role_assignments
  semantic_search_sku           = var.ks_ai_search_definition.semantic_search_sku
  sku                           = var.ks_ai_search_definition.sku
  tags                          = var.ks_ai_search_definition.tags

  depends_on = [module.private_dns_zones, module.hub_vnet_peering]
}

resource "azapi_resource" "bing_grounding" {
  count = var.ks_bing_grounding_definition.deploy ? 1 : 0

  location  = "global"
  name      = local.ks_bing_grounding_name
  parent_id = azurerm_resource_group.this.id
  type      = "Microsoft.Bing/accounts@2025-05-01-preview"
  body = {
    kind = "Bing.Grounding"
    sku = {
      name = var.ks_bing_grounding_definition.sku
    }
  }
  create_headers            = var.enable_telemetry ? { "User-Agent" : local.avm_azapi_header } : null
  delete_headers            = var.enable_telemetry ? { "User-Agent" : local.avm_azapi_header } : null
  read_headers              = var.enable_telemetry ? { "User-Agent" : local.avm_azapi_header } : null
  schema_validation_enabled = false
  tags                      = var.ks_bing_grounding_definition.tags
  update_headers            = var.enable_telemetry ? { "User-Agent" : local.avm_azapi_header } : null
}