spring-boot-realworld-example-app/build.gradle at 98d67204b79176e2a43f65cf659e55c2bd1e4511 · COG-GTM/spring-boot-realworld-example-app · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
plugins {
    id 'org.springframework.boot' version '2.7.18'
    id 'io.spring.dependency-management' version '1.0.15.RELEASE'
    id 'java'
    id "com.netflix.dgs.codegen" version "5.1.17"
    id "com.diffplug.spotless" version "6.2.1"
}

version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'
targetCompatibility = '11'

spotless {
    java {
        target project.fileTree(project.rootDir) {
            include '**/*.java'
            exclude 'build/generated/**/*.*', 'build/generated-examples/**/*.*'
        }
        googleJavaFormat()
    }
}

repositories {
    mavenCentral()
}

// The Spring Boot BOM manages graphql-java for spring-graphql; DGS needs a newer version.
ext['graphql-java.version'] = '19.11'

// Patch releases of BOM-managed libraries that carry security fixes not yet
// picked up by the Spring Boot 2.7.x line.
ext['tomcat.version'] = '9.0.121'
ext['spring-framework.version'] = '5.3.39'
ext['spring-security.version'] = '5.8.16'
ext['jackson-bom.version'] = '2.18.10'
ext['kotlin.version'] = '1.9.25'
ext['logback.version'] = '1.2.13'
ext['snakeyaml.version'] = '2.4'
ext['reactor-bom.version'] = '2020.0.47'
ext['commons-lang3.version'] = '3.18.0'
ext['assertj.version'] = '3.27.7'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

dependencies {
    // Transitive of the DGS starter (via Apollo federation support), vulnerable below 3.25.5.
    implementation 'com.google.protobuf:protobuf-java:3.25.8'

    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-hateoas'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter:2.3.2'
    implementation 'com.netflix.graphql.dgs:graphql-dgs-spring-boot-starter:5.6.2'
    implementation 'org.flywaydb:flyway-core'
    implementation 'io.jsonwebtoken:jjwt-api:0.11.2'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.2',
                'io.jsonwebtoken:jjwt-jackson:0.11.2'
    implementation 'joda-time:joda-time:2.10.13'
    implementation 'org.xerial:sqlite-jdbc:3.41.2.2'

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    testImplementation 'io.rest-assured:rest-assured:4.5.1'
    testImplementation 'io.rest-assured:json-path:4.5.1'
    testImplementation 'io.rest-assured:xml-path:4.5.1'
    testImplementation 'io.rest-assured:spring-mock-mvc:4.5.1'
    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter-test:2.3.2'
}

tasks.named('test') {
	useJUnitPlatform()
}

tasks.named('clean') {
    doFirst {
        delete './dev.db'
    }
}

tasks.named('generateJava') {
    schemaPaths = ["${projectDir}/src/main/resources/schema"] // List of directories containing schema files
    packageName = 'io.spring.graphql' // The package name to use to generate sources
}