ast-jetbrains-plugin/build.gradle at main · Checkmarx/ast-jetbrains-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
plugins {
    id 'io.freefair.lombok' version "${lombokPluginVersion}"
    id 'org.jetbrains.intellij' version "${intellijPluginVersion}"
    id 'java'
    id 'jacoco'
}

def javaWrapperVersion = System.getenv('JAVA_WRAPPER_VERSION') ?: defaultJavaWrapperVersion

// Common configuration for all projects
allprojects {
    group "${projectGroup}"
    version System.getenv('RELEASE_VERSION') ?: "dev"

    repositories {
        mavenCentral()
        maven {
            url = 'https://packages.jetbrains.team/maven/p/ij/intellij-dependencies'
        }
        maven {
            url = 'https://oss.sonatype.org/content/repositories/snapshots'
        }
    }
}

// Common configuration for all submodules
subprojects {
    apply plugin: 'java'

    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(Integer.parseInt(javaVersion)))
        }
    }

    dependencies {
        testImplementation "com.intellij.remoterobot:remote-robot:${remoteRobotVersion}"
        testImplementation("com.intellij.remoterobot:remote-fixtures:${remoteRobotVersion}") {
            exclude group: 'com.square.okio', module: 'okio'
        }
        testImplementation "com.squareup.okio:okio:${okioVersion}"
        testImplementation "org.junit.jupiter:junit-jupiter-api:${junitBomVersion}"
        testImplementation "com.squareup.okhttp3:okhttp:${okhttpVersion}"
        testImplementation 'junit:junit:4.11-redhat-1'
        testImplementation 'junit:junit:4.13.1'
        testImplementation group: 'org.mockito', name: 'mockito-core', version: '5.15.2'

        // Video Recording
        testImplementation('com.automation-remarks:video-recorder-junit5:2.0') {
            exclude group: 'log4j', module: 'log4j'
        }
        testImplementation "org.apache.logging.log4j:log4j-api:${log4jVersion}"
        testImplementation "org.apache.logging.log4j:log4j-core:${log4jVersion}"
        testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${junitEngineVersion}"

        // https://mvnrepository.com/artifact/com.miglayout/miglayout-swing
        implementation "com.miglayout:miglayout-swing:${miglayoutVersion}"

        implementation("com.checkmarx.ast:ast-cli-java-wrapper:${javaWrapperVersion}"){
            exclude group: 'junit', module: 'junit'
            // Exclude wrapper's Jackson to prevent version conflicts. The enforcedPlatform above will provide aligned versions.
            exclude group: 'com.fasterxml.jackson.core', module: 'jackson-databind'
            exclude group: 'com.fasterxml.jackson.core', module: 'jackson-annotations'
            exclude group: 'com.fasterxml.jackson.core', module: 'jackson-core'
        }
        implementation(enforcedPlatform("com.fasterxml.jackson:jackson-bom:${jacksonBomVersion}"))
        // enforcedPlatform forces ALL Jackson jars (databind, annotations, core) to use the SAME version.

        testImplementation "org.mockito:mockito-core:${mockitoVersion}"
        testImplementation "org.mockito:mockito-junit-jupiter:${mockitoVersion}"
    }

    jacoco {
        toolVersion = "${jacocoVersion}"
    }
}

// See https://github.com/JetBrains/gradle-intellij-plugin/
intellij {
    version = "${intellijVersion}"
    updateSinceUntilBuild = false
}

runPluginVerifier {
    ideVersions = verifierIdeVersions.split(',').toList()
}

[verifyPlugin, runPluginVerifier, buildSearchableOptions, patchPluginXml].each {
    tasks.named(it.name) { enabled = false }
}