OrdinaryDiffEq.jl/lib/DiffEqBase/src/calculate_residuals.jl at bf025b4fb307e2806a1797e5fe0df91f1293d284 · ChrisRackauckas-Claude/OrdinaryDiffEq.jl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
"""
    calculate_residuals(ũ, u₀, u₁, α, ρ, internalnorm, t)

Calculate element-wise residuals
```math
\\frac{ũ}{α+\\max{|u₀|,|u₁|}*ρ}
```
"""
@inline @muladd function calculate_residuals(
        ũ::Number, u₀::Number, u₁::Number,
        α, ρ, internalnorm, t
    )
    @fastmath ũ / (α + max(internalnorm(u₀, t), internalnorm(u₁, t)) * ρ)
end

@inline function calculate_residuals(
        ũ::Array{T}, u₀::Array{T}, u₁::Array{T}, α::T2,
        ρ::Real, internalnorm,
        t
    ) where
    {T <: Number, T2 <: Number}
    out = similar(ũ)
    calculate_residuals!(out, ũ, u₀, u₁, α, ρ, internalnorm, t)
    return out
end

@inline function calculate_residuals(ũ, u₀, u₁, α, ρ, internalnorm, t)
    return @.. broadcast = false calculate_residuals(ũ, u₀, u₁, α, ρ, internalnorm, t)
end

"""
    calculate_residuals(u₀, u₁, α, ρ, internalnorm, t)

Calculate element-wise residuals
```math
\\frac{u₁ - u₀}{α+\\max{|u₀|,|u₁|}*ρ}
```
"""

@inline @muladd function calculate_residuals(
        u₀::Number, u₁::Number,
        α, ρ, internalnorm, t
    )
    @fastmath (u₁ - u₀) / (α + max(internalnorm(u₀, t), internalnorm(u₁, t)) * ρ)
end

@inline function calculate_residuals(
        u₀::Array{T}, u₁::Array{T}, α::T2,
        ρ::Real, internalnorm,
        t
    ) where {T <: Number, T2 <: Number}
    out = similar(u₀)
    calculate_residuals!(out, u₀, u₁, α, ρ, internalnorm, t)
    return out
end

@inline function calculate_residuals(u₀, u₁, α, ρ, internalnorm, t)
    return @.. broadcast = false calculate_residuals(u₀, u₁, α, ρ, internalnorm, t)
end

"""
    calculate_residuals(E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, t)

Return element-wise residuals
```math
\\frac{δ E₁ + E₂}{α+\\max{scalarnorm(u₀),scalarnorm(u₁)}*ρ}.
```
"""
@inline @muladd function calculate_residuals(
        E₁::Number, E₂::Number, u₀::Number, u₁::Number,
        α::Real, ρ::Real, δ::Number, scalarnorm, t
    )
    @fastmath (δ * E₁ + E₂) / (α + max(scalarnorm(u₀, t), scalarnorm(u₁, t)) * ρ)
end

@inline function calculate_residuals(
        E₁::Array{<:Number}, E₂::Array{<:Number},
        u₀::Array{<:Number}, u₁::Array{<:Number}, α::Real,
        ρ::Real, δ::Number, scalarnorm, t
    )
    out = similar(u₀)
    calculate_residuals!(out, E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, t)
    return out
end

@inline function calculate_residuals(E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, t)
    return @.. broadcast = false calculate_residuals(E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, t)
end

# Inplace Versions

"""
    DiffEqBase.calculate_residuals!(out, ũ, u₀, u₁, α, ρ, thread=False())

Save element-wise residuals
```math
\\frac{ũ}{α+\\max{|u₀|,|u₁|}*ρ}
```
in `out`.

The argument `thread` determines whether internal broadcasting on
appropriate CPU arrays should be serial (`thread = False()`, default)
or use multiple threads (`thread = True()`) when Julia is started
with multiple threads.
"""
@inline function calculate_residuals!(
        out, ũ, u₀, u₁, α, ρ, internalnorm, t,
        thread::Union{False, True} = False()
    )
    @.. broadcast = false thread = thread out = calculate_residuals(
        ũ, u₀, u₁, α, ρ, internalnorm,
        t
    )
    return nothing
end

@inline function calculate_residuals!(
        out::Array, ũ::Array, u₀::Array, u₁::Array, α::Number,
        ρ::Number, internalnorm::F, t, ::False
    ) where {F}
    @inbounds @simd ivdep for i in eachindex(out, ũ, u₀, u₁)
        out[i] = calculate_residuals(ũ[i], u₀[i], u₁[i], α, ρ, internalnorm, t)
    end
    return nothing
end

"""
    calculate_residuals!(out, u₀, u₁, α, ρ, thread=False())

Save element-wise residuals
```math
\\frac{u₁ - u₀}{α+\\max{|u₀|,|u₁|}*ρ}
```
in `out`.

The argument `thread` determines whether internal broadcasting on
appropriate CPU arrays should be serial (`thread = False()`, default)
or use multiple threads (`thread = True()`) when Julia is started
with multiple threads.
"""
@inline function calculate_residuals!(
        out, u₀, u₁, α, ρ, internalnorm, t,
        thread::Union{False, True} = False()
    )
    @.. broadcast = false thread = thread out = calculate_residuals(u₀, u₁, α, ρ, internalnorm, t)
    return nothing
end

"""
    calculate_residuals!(out, E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, thread=False())

Calculate element-wise residuals
```math
\\frac{δ E₁ + E₂}{α+\\max{scalarnorm(u₀),scalarnorm(u₁)}*ρ}.
```

The argument `thread` determines whether internal broadcasting on
appropriate CPU arrays should be serial (`thread = False()`, default)
or use multiple threads (`thread = True()`) when Julia is started
with multiple threads.
"""
@inline function calculate_residuals!(
        out, E₁, E₂, u₀, u₁, α, ρ, δ, scalarnorm, t,
        thread::Union{False, True} = False()
    )
    @.. broadcast = false thread = thread out = calculate_residuals(
        E₁, E₂, u₀, u₁, α, ρ, δ,
        scalarnorm, t
    )
    return nothing
end