verbs.dm

//TODO: rewrite and standardise all controller datums to the datum/controller type
//TODO: allow all controllers to be deleted for clean restarts (see WIP master controller stuff) - MC done - lighting done

// Clickable stat() button.
/obj/effect/statclick
	name = "Initializing..."
	icon = null
	var/target

INITIALIZE_IMMEDIATE(/obj/effect/statclick)

/obj/effect/statclick/Initialize(mapload, text, target) //Don't port this to Initialize it's too critical
	. = ..()
	name = text
	src.target = target

/obj/effect/statclick/Destroy()
	target = null
	return ..()

/obj/effect/statclick/proc/update(text)
	if(name == text)
		return src	// let's ont change for no reason shall we
	name = text
	return name

/obj/effect/statclick/statpanel_click(client/C, action)
	Click()

/obj/effect/statclick/debug
	var/class

/obj/effect/statclick/debug/Click()
	if(!usr.client.holder || !target)
		return
	if(!class)
		if(istype(target, /datum/controller/subsystem))
			class = "subsystem"
		else if(istype(target, /datum/controller))
			class = "controller"
		else if(istype(target, /datum))
			class = "datum"
		else
			class = "unknown"

	usr.client.debug_variables(target)
	message_admins("Admin [key_name_admin(usr)] is debugging the [target] [class].")

ADMIN_VERB(restart_controller, R_DEBUG, "Restart Controller", "Restart one of the various periodic loop controllers for the game (be careful!)", ADMIN_CATEGORY_DEBUG, controller in list("Master", "Failsafe"))
	switch(controller)
		if("Master")
			Recreate_MC()
			// BLACKBOX_LOG_ADMIN_VERB("Restart Master Controller")
		if("Failsafe")
			new /datum/controller/failsafe()
			// BLACKBOX_LOG_ADMIN_VERB("Restart Failsafe Controller")

	message_admins("Admin [key_name_admin(user)] has restarted the [controller] controller.")

ADMIN_VERB(debug_controller, R_DEBUG, "Debug Controller", "Debug the various periodic loop controllers for the game (be careful!)", ADMIN_CATEGORY_DEBUG)
	var/list/controllers = list()
	var/list/controller_choices = list()

	// Please read the verb description. <- although we allow /d/c/repository lmao
	for (var/var_key in global.vars)
		var/datum/controller/controller = global.vars[var_key]
		if(!istype(controller) || istype(controller, /datum/controller/subsystem))
			continue
		controllers[controller.name] = controller //we use an associated list to ensure clients can't hold references to controllers
		controller_choices += controller.name

	controller_choices += "INTERNAL: Gas Data"
	controller_choices += "LEGACY: Configuration"
	controller_choices += "LEGACY: paiController"
	controllers["INTERNAL: Gas Data"] = global.gas_data
	controllers["LEGACY: Configuration"] = config_legacy
	controllers["LEGACY: paiController"] = paiController

	var/datum/controller/controller_string = input("Select controller to debug", "Debug Controller") as null|anything in controller_choices
	var/datum/controller/controller = controllers[controller_string]

	if (!istype(controller))
		return

	user.debug_variables(controller)

	// BLACKBOX_LOG_ADMIN_VERB("Debug Controller")
	message_admins("Admin [key_name_admin(user)] is debugging the [controller] controller.")

/client/proc/debug_antagonist_template(antag_type in GLOB.all_antag_types)
	set category = "Debug"
	set name = "Debug Antagonist"
	set desc = "Debug an antagonist template."

	var/datum/antagonist/antag = GLOB.all_antag_types[antag_type]
	if(antag)
		usr.client.debug_variables(antag)
		message_admins("Admin [key_name_admin(usr)] is debugging the [antag.role_text] template.")