fictional-drug-and-disease-ref-backend-kotlin/build.gradle.kts at main · Corvus400/fictional-drug-and-disease-ref-backend-kotlin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
plugins {
    alias(libs.plugins.kotlin.jvm)
    alias(libs.plugins.kotlin.serialization)
    alias(libs.plugins.ktor)
    alias(libs.plugins.spotless)
    alias(libs.plugins.detekt)
    application
}

group = "io.github.corvus400.fictionaldrugdiseaserefbackendkotlin"
version = "0.1.0"

application {
    mainClass.set("io.github.corvus400.fictionaldrugdiseaserefbackendkotlin.ApplicationKt")
}

kotlin {
    jvmToolchain(21)
}

val seedSourceSet = sourceSets.create("seed") {
    java.srcDir("src/seed/kotlin")
    compileClasspath += sourceSets.main.get().output
    runtimeClasspath += output + compileClasspath
}

configurations.named(seedSourceSet.implementationConfigurationName) {
    extendsFrom(configurations.implementation.get())
}

configurations.named(seedSourceSet.runtimeOnlyConfigurationName) {
    extendsFrom(configurations.runtimeOnly.get())
}

dependencies {
    implementation(libs.ktor.server.core)
    implementation(libs.ktor.server.host.common)
    implementation(libs.ktor.server.status.pages)
    implementation(libs.ktor.server.call.logging)
    implementation(libs.ktor.server.call.id)
    implementation(libs.ktor.server.content.negotiation)
    implementation(libs.ktor.serialization.kotlinx.json)
    implementation(libs.ktor.server.netty)
    implementation(libs.ktor.server.di)
    implementation(libs.ktor.server.config.yaml)
    implementation(libs.ktor.server.auth)
    implementation(libs.ktor.server.auth.jwt)
    implementation(libs.java.jwt)
    implementation(libs.ktor.server.rate.limit)
    implementation(libs.ktor.server.cors)
    implementation(libs.ktor.server.forwarded.header)
    implementation(libs.logback.classic)
    implementation(libs.logstash.logback.encoder)
    implementation(libs.kotlinx.coroutines.slf4j)
    implementation(libs.ktor.server.metrics.micrometer)
    implementation(libs.micrometer.registry.prometheus)
    implementation(libs.ipaddress)
    implementation(libs.exposed.core)
    implementation(libs.exposed.jdbc)
    implementation(libs.exposed.json)
    implementation(libs.exposed.kotlin.datetime)
    implementation(libs.postgresql)
    implementation(libs.hikari)
    implementation(libs.flyway.core)
    implementation(libs.flyway.database.postgresql)
    implementation(libs.smiley4.ktor.openapi)
    implementation(libs.smiley4.ktor.swagger.ui)
    implementation(libs.smiley4.ktor.redoc)
    implementation(libs.smiley4.schema.kenerator.core)
    implementation(libs.smiley4.schema.kenerator.serialization)
    implementation(libs.smiley4.schema.kenerator.swagger)

    testImplementation(libs.ktor.server.test.host)
    testImplementation(libs.kotlin.test.junit)
    testImplementation(libs.testcontainers.postgresql)
    testImplementation(libs.testcontainers.junit.jupiter)

    add(seedSourceSet.implementationConfigurationName, libs.ktor.client.core)
    add(seedSourceSet.implementationConfigurationName, libs.ktor.client.cio)
    add(seedSourceSet.implementationConfigurationName, libs.ktor.client.content.negotiation)
}

ktor {
    fatJar {
        archiveFileName.set("fictional-drug-and-disease-ref-backend-kotlin-all.jar")
    }
}

detekt {
    buildUponDefaultConfig = true
    config.setFrom("$projectDir/config/detekt/detekt.yml")
    source.setFrom(
        "src/main/kotlin",
        "src/test/kotlin",
    )
}

spotless {
    val ratchetBase = "origin/main"
    val ratchetEnabled = providers.environmentVariable("CI").orNull == "true" ||
        providers.gradleProperty("spotless.ratchet").orNull == "true"
    if (ratchetEnabled) {
        ratchetFrom(ratchetBase)
    }
    kotlin {
        target("src/**/*.kt")
        targetExclude("build/**/*.kt")
        ktlint(libs.versions.ktlint.get())
    }
    kotlinGradle {
        target("*.gradle.kts")
        ktlint(libs.versions.ktlint.get())
    }
}

tasks.test {
    maxParallelForks = (Runtime.getRuntime().availableProcessors() / 2).coerceAtLeast(1)
}

tasks.register<JavaExec>("exportSeedSql") {
    group = "seed"
    description = "Export fixed Flyway seed SQL from the mock-server API."
    dependsOn("compileSeedKotlin")
    classpath = seedSourceSet.runtimeClasspath
    mainClass.set("io.github.corvus400.fictionaldrugdiseaserefbackendkotlin.tools.SeedExporterKt")
    args(
        "--base-url",
        providers.gradleProperty("seedBaseUrl").orElse("http://localhost:8080").get(),
        "--output-dir",
        layout.projectDirectory.dir("src/main/resources/db/migration").asFile.absolutePath,
    )
}

tasks.register<JavaExec>("printAdminToken") {
    group = "security"
    description = "Print a local admin JWT signed with JWT_SECRET."
    classpath = sourceSets.main.get().runtimeClasspath
    mainClass.set("io.github.corvus400.fictionaldrugdiseaserefbackendkotlin.tools.AdminTokenPrinterKt")
}