darma-utility/CMakeLists.txt at devel · DARMA-tasking-internal/darma-utility · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148

cmake_minimum_required(VERSION 3.4)

project (DarmaUtility
  VERSION 0.5
  LANGUAGES CXX
)

set(CMAKE_MODULE_PATH
  ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules
)

################################################################################
#------------------------------------------------------------------------------#
# darma_utility interface library                                              #
#------------------------------------------------------------------------------#

add_library(darma_utility INTERFACE)
add_library(darma_utility::darma_utility ALIAS darma_utility)

target_include_directories(darma_utility INTERFACE
  $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/source/include>
  $<INSTALL_INTERFACE:include>
)
target_compile_features(darma_utility INTERFACE cxx_std_14)

install(TARGETS darma_utility EXPORT darmaUtilityTargets
  INCLUDES DESTINATION include
)

install(EXPORT darmaUtilityTargets
  FILE darmaUtilityTargets.cmake
  NAMESPACE darma_utility::
  DESTINATION cmake
)

export(TARGETS darma_utility
  NAMESPACE darma_utility::
  FILE darmaUtilityTargets.cmake
)

################################################################################
# Dependencies
################################################################################

find_package(TinyMPL REQUIRED 2.0)

message(STATUS "Found TinyMPL: ${TinyMPL_DIR}")

target_link_libraries(darma_utility INTERFACE tinympl::tinympl)

################################################################################
# Compilation Checks, etc.
################################################################################

include (CheckCXXCompilerFlag)
include (CheckCXXSourceCompiles)

#-------------------------------------------------------------------------------
# Check for available attributes
set(CMAKE_REQUIRED_FLAGS_TMP ${CMAKE_REQUIRED_FLAGS})
set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS_TMP} -Werror=attributes -std=c++14 ${CMAKE_CXX_FLAGS}")

check_cxx_source_compiles("
[[ gnu::nonnull(1,2) ]]
extern void* my_memcpy(void *dest, const void *src);
int main() { }
"
  DARMA_HAVE_ATTRIBUTE_NONNULL
)

check_cxx_source_compiles("
[[ deprecated ]] void* my_memcpy(void *dest, const void *src);
int main() { }
"
  DARMA_HAVE_ATTRIBUTE_DEPRECATED
)

check_cxx_source_compiles("
[[ deprecated(\"reason\") ]]
void* my_memcpy(void *dest, const void *src);
int main() { }
"
  DARMA_HAVE_ATTRIBUTE_DEPRECATED_WITH_MESSAGE
)

check_cxx_source_compiles("
[[ gnu::always_inline ]] inline
int foo(int a) { return a + 5; }
int main() { }
"
  DARMA_HAVE_ATTRIBUTE_ALWAYS_INLINE
)

check_cxx_source_compiles("
[[ gnu::flatten ]]
int foo(int a) { return a + 5; }
int main() { }
"
  DARMA_HAVE_ATTRIBUTE_FLATTEN
)

set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS_TMP}")
# end of attribute checks
#-------------------------------------------------------------------------------

check_cxx_source_compiles("
#include <cxxabi.h>
int main() { }
"
  DARMA_HAVE_CXXABI_H
)

#-------------------------------------------------------------------------------
# Generate the configuration header

configure_file(
  source/include/darma/utility/config-generated.h.in
  ${CMAKE_CURRENT_BINARY_DIR}/include/darma/utility/config-generated.h
)
install (
  FILES ${CMAKE_CURRENT_BINARY_DIR}/include/darma/utility/config-generated.h
  DESTINATION include/darma/utility
)
target_compile_definitions(darma_utility INTERFACE DARMA_CONFIG_GENERATED_H_AVAILABLE)

#-------------------------------------------------------------------------------

install(DIRECTORY source/include/darma/utility DESTINATION include/darma FILES_MATCHING PATTERN "*.h")

################################################################################

include(CMakePackageConfigHelpers)
configure_package_config_file(cmake/DarmaUtilityConfig.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/DarmaUtilityConfig.cmake
  INSTALL_DESTINATION cmake
)
write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/DarmaUtilityConfigVersion.cmake
  COMPATIBILITY SameMajorVersion
)

install(FILES ${CMAKE_CURRENT_BINARY_DIR}/DarmaUtilityConfig.cmake ${CMAKE_CURRENT_BINARY_DIR}/DarmaUtilityConfigVersion.cmake
    DESTINATION cmake
)

################################################################################

export(PACKAGE DarmaUtility)