CMakeLists.txt

# Disable in-source builds to prevent source tree corruption.
if(" ${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL " ${CMAKE_CURRENT_BINARY_DIR}")
    message(
        FATAL_ERROR
        "
FATAL: In-source builds are not allowed.
       You should create a separate directory for build files.
"
    )
endif()

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# Windows SDK version checks
if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
    set(sdk_minimum 10.0.18362.0)

    # If no CMAKE_SYSTEM_VERSION is set, warn the user and set a default
    # If it's set but below the defined minimum, warn the user but don't change it
    if(NOT DEFINED CMAKE_SYSTEM_VERSION)
        message(WARNING "No CMAKE_SYSTEM_VERSION set, defaulting to ${sdk_minimum}")
        set(CMAKE_SYSTEM_VERSION "${sdk_minimum}" CACHE STRING "Windows SDK target")
    elseif(CMAKE_SYSTEM_VERSION VERSION_LESS sdk_minimum)
        message(
            WARNING
            "Current Windows SDK target ${CMAKE_SYSTEM_VERSION} is below the recommended"
            "minimum target of ${sdk_minimum}. Some features may be limited or unavailable."
            "If this is incorrect, you may need to manually set CMAKE_SYSTEM_VERSION"
            "to a higher target."
        )
    endif()
endif()

# Set default build type to release with debug info (i.e. release mode optimizations
# are performed, but debug info still exists).
if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "" FORCE)
endif()

cmake_minimum_required(VERSION 3.21)
project(allwpilib)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")

# Make timestamps of extracted files from FetchContent the time of extraction
if(POLICY CMP0135)
    cmake_policy(SET CMP0135 NEW)
endif()

set(WPILIB_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})

include(CMakeDependentOption)
include(CPack)
include(OptionValidation)

set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS TRUE)
set(CMAKE_POSITION_INDEPENDENT_CODE TRUE)
if(MSVC)
    add_compile_options(/Zc:__cplusplus)
endif()
set_property(GLOBAL PROPERTY USE_FOLDERS ON)

set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${WPILIB_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${WPILIB_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${WPILIB_BINARY_DIR}/bin)

# use, i.e. don't skip the full RPATH for the build tree
set(CMAKE_SKIP_BUILD_RPATH FALSE)

# when building, don't use the install RPATH already
# (but later on when installing)
set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)

set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")

# add the automatically determined parts of the RPATH
# which point to directories outside the build tree to the install RPATH
set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)

# Options for building certain parts of the repo. Everything is built by default.
option(BUILD_SHARED_LIBS "Build with shared libs" ON)
option(WPILIB_WITH_DOCS "Build Doxygen docs (needs Git for versioning)" OFF)
cmake_dependent_option(
    DOCS_WARNINGS_AS_ERRORS
    "Make docs warnings into errors"
    OFF
    WPILIB_WITH_DOCS
    OFF
)
option(WPILIB_WITH_CSCORE "Build cscore (needs OpenCV)" ON)
option(WPILIB_WITH_NTCORE "Build ntcore" ON)
option(WPILIB_WITH_WPICAL "Build wpical" OFF)
option(WPILIB_WITH_WPIMATH "Build wpimath" ON)
option(WPILIB_WITH_WPILIB "Build hal, wpilibc/j, and developerRobot (needs OpenCV)" ON)
option(WPILIB_WITH_EXAMPLES "Build examples" OFF)
option(WPILIB_WITH_TESTS "Build unit tests (requires internet connection)" ON)
option(WPILIB_WITH_GUI "Build GUI items (needs SDL3)" OFF)
cmake_dependent_option(
    WPILIB_WITH_FIELDS
    "Build the fields target"
    OFF
    "NOT WPILIB_WITH_GUI;NOT WPILIB_WITH_EXAMPLES"
    ON
)
option(WPILIB_WITH_SIMULATION_MODULES "Build simulation modules" ON)
option(WPILIB_WITH_BENCHMARK "Build the benchmark project" ON)

# Options for using a package manager (e.g., vcpkg) for certain dependencies.
option(WPILIB_USE_SYSTEM_EIGEN "Use system Eigen" OFF)
option(WPILIB_USE_SYSTEM_LIBUV "Use system libuv" OFF)
option(WPILIB_USE_SYSTEM_SLEIPNIR "Use system Sleipnir" OFF)
option(WPILIB_USE_LINKED_AVAHI "Use directly linked Avahi instead of loading at runtime" OFF)

# Options for compilation flags.
option(WPILIB_NO_WERROR "Disable -Werror flag during compilation" OFF)

wpilib_config(
    OPTIONS WPILIB_WITH_SIMULATION_MODULES
    REQUIRES BUILD_SHARED_LIBS WPILIB_WITH_WPILIB WPILIB_WITH_NTCORE
)

wpilib_config(OPTIONS WPILIB_WITH_CSCORE REQUIRES WPILIB_WITH_NTCORE)

wpilib_config(OPTIONS WPILIB_WITH_GUI REQUIRES WPILIB_WITH_NTCORE WPILIB_WITH_WPIMATH)

wpilib_config(OPTIONS WPILIB_WITH_WPILIB REQUIRES WPILIB_WITH_NTCORE WPILIB_WITH_WPIMATH)

wpilib_config(OPTIONS WPILIB_WITH_FIELDS REQUIRES WPILIB_WITH_WPIMATH)

set(include_dest include)

if(WPILIB_WITH_DOCS)
    find_package(Doxygen REQUIRED)
    find_package(Git REQUIRED)
    include(AddDoxygenDocs)
    add_doxygen_docs()
endif()

find_package(LIBSSH CONFIG 0.7.1)

get_property(isMultiConfig GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)

if(isMultiConfig)
    if(NOT "Asan" IN_LIST CMAKE_CONFIGURATION_TYPES)
        list(APPEND CMAKE_CONFIGURATION_TYPES Asan)
    endif()
    if(NOT "Tsan" IN_LIST CMAKE_CONFIGURATION_TYPES)
        list(APPEND CMAKE_CONFIGURATION_TYPES Tsan)
    endif()
    if(NOT "Ubsan" IN_LIST CMAKE_CONFIGURATION_TYPES)
        list(APPEND CMAKE_CONFIGURATION_TYPES Ubsan)
    endif()
else()
    set(allowedBuildTypes
        Asan
        Tsan
        Ubsan
        Debug
        Release
        RelWithDebInfo
        MinSizeRel
    )
    set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${allowedBuildTypes}")

    if(CMAKE_BUILD_TYPE AND NOT CMAKE_BUILD_TYPE IN_LIST allowedBuildTypes)
        message(FATAL_ERROR "Invalid build type: ${CMAKE_BUILD_TYPE}")
    endif()
endif()

set(CMAKE_C_FLAGS_ASAN
    "${CMAKE_C_FLAGS_DEBUG} -fsanitize=address -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C compiler for Asan build type or configuration."
    FORCE
)

set(CMAKE_CXX_FLAGS_ASAN
    "${CMAKE_CXX_FLAGS_DEBUG} -fsanitize=address -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C++ compiler for Asan build type or configuration."
    FORCE
)

set(CMAKE_EXE_LINKER_FLAGS_ASAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=address"
    CACHE STRING
    "Linker flags to be used to create executables for Asan build type."
    FORCE
)

set(CMAKE_SHARED_LINKER_FLAGS_ASAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=address"
    CACHE STRING
    "Linker flags to be used to create shared libraries for Asan build type."
    FORCE
)

set(CMAKE_C_FLAGS_TSAN
    "${CMAKE_C_FLAGS_DEBUG} -fsanitize=thread -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C compiler for Tsan build type or configuration."
    FORCE
)

set(CMAKE_CXX_FLAGS_TSAN
    "${CMAKE_CXX_FLAGS_DEBUG} -fsanitize=thread -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C++ compiler for Tsan build type or configuration."
    FORCE
)

set(CMAKE_EXE_LINKER_FLAGS_TSAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=thread"
    CACHE STRING
    "Linker flags to be used to create executables for Tsan build type."
    FORCE
)

set(CMAKE_SHARED_LINKER_FLAGS_TSAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=thread"
    CACHE STRING
    "Linker flags to be used to create shared libraries for Tsan build type."
    FORCE
)

set(CMAKE_C_FLAGS_UBSAN
    "${CMAKE_C_FLAGS_DEBUG} -fsanitize=undefined -fno-sanitize-recover=all -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C compiler for Ubsan build type or configuration."
    FORCE
)

set(CMAKE_CXX_FLAGS_UBSAN
    "${CMAKE_CXX_FLAGS_DEBUG} -fsanitize=undefined -fno-sanitize-recover=all -fno-omit-frame-pointer"
    CACHE STRING
    "Flags used by the C++ compiler for Ubsan build type or configuration."
    FORCE
)

set(CMAKE_EXE_LINKER_FLAGS_UBSAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=undefined -fno-sanitize-recover=all"
    CACHE STRING
    "Linker flags to be used to create executables for Ubsan build type."
    FORCE
)

set(CMAKE_SHARED_LINKER_FLAGS_UBSAN
    "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} -fsanitize=undefined"
    CACHE STRING
    "Linker flags to be used to create shared libraries for Ubsan build type."
    FORCE
)

if(WPILIB_WITH_TESTS)
    enable_testing()
    add_subdirectory(thirdparty/googletest)
    include(GoogleTest)
    list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/catch2/extras")
    add_subdirectory(thirdparty/catch2)
    include(Catch)
endif()

if(WPILIB_USE_SYSTEM_LIBUV)
    set(LIBUV_SYSTEM_REPLACE "find_dependency(libuv CONFIG)")
endif()

if(WPILIB_USE_SYSTEM_EIGEN)
    set(EIGEN_SYSTEM_REPLACE "find_package(Eigen3 CONFIG)")
endif()

set(FILENAME_DEP_REPLACE "get_filename_component(SELF_DIR \"$\{CMAKE_CURRENT_LIST_FILE\}\" PATH)")
set(SELF_DIR "$\{SELF_DIR\}")
set(WPIUTIL_DEP_REPLACE "find_dependency(wpiutil)")

add_subdirectory(wpiutil)

if(WPILIB_WITH_NTCORE OR WPILIB_WITH_GUI OR WPILIB_WITH_WPILIB)
    set(DATALOG_DEP_REPLACE "find_dependency(datalog)")
    add_subdirectory(datalog)
endif()

if(WPILIB_WITH_NTCORE)
    set(NTCORE_DEP_REPLACE "find_dependency(ntcore)")
    set(WPINET_DEP_REPLACE "find_dependency(wpinet)")
    add_subdirectory(wpinet)
    add_subdirectory(ntcore)
endif()

if(WPILIB_WITH_WPIMATH)
    set(WPIMATH_DEP_REPLACE "find_dependency(wpimath)")
    add_subdirectory(wpimath)
endif()

if(WPILIB_WITH_FIELDS)
    add_subdirectory(fields)
endif()

if(WPILIB_WITH_GUI)
    find_package(SDL3 CONFIG REQUIRED)
    add_subdirectory(thirdparty/imgui_suite)
    add_subdirectory(wpigui)
    add_subdirectory(glass)
    add_subdirectory(tools/outlineviewer)
    add_subdirectory(tools/sysid)
    if(WPILIB_WITH_WPICAL)
        add_subdirectory(tools/wpical)
    endif()
    if(LIBSSH_FOUND)
        add_subdirectory(tools/datalogtool)
    endif()
endif()

if(WPILIB_WITH_WPILIB OR WPILIB_WITH_SIMULATION_MODULES)
    set(HAL_DEP_REPLACE "find_dependency(hal)")
    add_subdirectory(hal)
endif()

if(WPILIB_WITH_CSCORE)
    set(CSCORE_DEP_REPLACE "find_dependency(cscore)")
    find_package(OpenCV REQUIRED)
    add_subdirectory(cscore)
endif()

if(WPILIB_WITH_WPILIB)
    set(WPILIBC_DEP_REPLACE "find_dependency(wpilibc)")
    set(COMMAND_DEP_REPLACE "find_dependency(commandsv2)")
    add_subdirectory(apriltag)
    add_subdirectory(wpilibc)
    if(WPILIB_WITH_CSCORE)
        add_subdirectory(cameraserver)
    endif()
    add_subdirectory(commandsv2)
    add_subdirectory(romiVendordep)
    add_subdirectory(xrpVendordep)
    if(WPILIB_WITH_EXAMPLES)
        add_subdirectory(wpilibcExamples)
    endif()
    add_subdirectory(developerRobot)
endif()

if(WPILIB_WITH_BENCHMARK)
    add_subdirectory(benchmark)
endif()

if(WPILIB_WITH_SIMULATION_MODULES)
    add_subdirectory(simulation)
endif()

configure_file(wpilib-config.cmake.in ${WPILIB_BINARY_DIR}/wpilib-config.cmake)
install(FILES ${WPILIB_BINARY_DIR}/wpilib-config.cmake DESTINATION share/wpilib)