Add modelica blocks of hydraulic structures.

Author: k-horvath-deltares

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/Orifice/Orifice.mo

@@ -0,0 +1,8 @@
+within Deltares.ChannelFlow.HydraulicStructures.Orifice;
+
+model Orifice "Orifice that only allows flow when HQDown.H < HQUp.H"
+  extends Deltares.ChannelFlow.Hydraulic.Structures.DischargeControlledStructure(Q(min=0.0));
+  parameter Modelica.Units.SI.Length dH_max = 10.0;
+  parameter Modelica.Units.SI.Area area = 1.0;
+  parameter Real discharge_coefficient = 0.61;
+end Orifice;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/Orifice/package.mo

@@ -0,0 +1,4 @@
+within Deltares.ChannelFlow.HydraulicStructures;
+
+package Orifice
+end Orifice;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/Orifice/package.order

@@ -0,0 +1 @@
+Orifice

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/PumpingStation/Pump.mo

@@ -0,0 +1,56 @@
+within Deltares.ChannelFlow.HydraulicStructures.PumpingStation;
+
+partial model Pump "Pump with QHP relationship"
+  extends Deltares.ChannelFlow.Hydraulic.Structures.Pump;
+
+  // Increasing row number is increasing H power (staring at 0th power).
+  // Increasing column number is increasing Q power (staring at 0th power).
+  parameter Real power_coefficients[:, :, :];
+  parameter Real speed_coefficients[:, :] = {{0.0}};
+
+
+  // Array of working area polynomials, each a function of Q and H. The
+  // coefficients of each polynomial are like the power coefficients, in that
+  // increasing row (second index) is increasing power of H, and increasing
+  // column (third index) is increasing power of Q.
+  parameter Real working_area[:, :, :];
+
+  // For each of the polynomials in the working area we have to specify whether
+  // the expression should evaluate to a positive expression (=1), or a
+  // negative expression (=-1).
+  // NOTE: May become unnecessary to specify this in the future, if we can
+  // figure out a way to determine this automatically based on the working
+  // area.
+  parameter Real working_area_direction[:];
+
+  // Pump's minimum on and off time.
+  parameter Modelica.Units.SI.Duration minimum_on = 0.0;
+  parameter Modelica.Units.SI.Duration minimum_off = 0.0;
+
+  // NOTE: Enumerations are not supported in JModelica's CasADi interface. We
+  // therefore resort to an integer.
+  // What head to use for the pump head. This can be
+  // -1: The upstream head
+  //  0: The differential head (i.e. downstream head minus upstream head)
+  //  1: The downstream head.
+  parameter Integer head_option = 0;
+
+  parameter Modelica.Units.SI.Energy start_up_energy = 0.0;
+  parameter Real start_up_cost = 0.0;
+
+  parameter Modelica.Units.SI.Energy shut_down_energy = 0.0;
+  parameter Real shut_down_cost = 0.0;
+
+  // NOTE: The equality constraint setting dH to some combination of HQUp and
+  // HQDown (based on head_option) will be added in the Mixin.
+  Modelica.Units.SI.Distance dH;
+
+equation
+  if head_option == -1 then
+    dH = HQUp.H;
+  elseif head_option == 1 then
+    dH = HQDown.H;
+  else
+    dH = HQDown.H - HQUp.H;
+  end if;
+end Pump;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/PumpingStation/PumpingStation.mo

@@ -0,0 +1,26 @@
+within Deltares.ChannelFlow.HydraulicStructures.PumpingStation;
+
+model PumpingStation
+  extends Deltares.ChannelFlow.Internal.HQTwoPort;
+  import SI = Modelica.Units.SI;
+  parameter Integer n_pumps = 0;
+
+  // FIXME: For some reason JModelica/CasADi returns {1, 2} for the expression
+  // 1:3 if we store it as an Integer, whereas it returns {1, 2, 3} if we
+  // store it as a Real. The weird thing is that JModelica does not complain
+  // about any size mismatches. Furthermore, transposes also do not seem to
+  // work well.
+  // To work around these issues, we detect the -999 default array, and
+  // overwrite it in Python with the correct one.
+  parameter Integer pump_switching_matrix[n_pumps, n_pumps] = fill(-999, n_pumps, n_pumps);
+  parameter Integer pump_switching_constraints[n_pumps, 2] = fill(-999, n_pumps, 2);
+
+  SI.VolumeFlowRate Q;
+equation
+  // Discharge
+  Q = HQUp.Q;
+
+  HQUp.M = -HQDown.M;
+
+  // TODO: Annotation / pretty picture. Currently inheriting TwoPort.
+end PumpingStation;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/PumpingStation/Resistance.mo

@@ -0,0 +1,22 @@
+within Deltares.ChannelFlow.HydraulicStructures.PumpingStation;
+
+// TODO: Negative flows (from down to up) are not supported. Do we want to support them?
+model Resistance "Quadratic resistance of form dH=C*Q^2"
+  extends Deltares.ChannelFlow.Internal.HQTwoPort;
+
+  parameter Real C = 0.0;
+
+  // Head loss
+  input Modelica.Units.SI.Distance dH;
+equation
+  // Head
+  HQDown.H = HQUp.H - dH;
+
+  // Discharge
+  HQUp.Q + HQDown.Q = 0;
+
+  // Substances
+  HQUp.M = -HQDown.M;
+
+  // TODO: Annotation / pretty picture. Currently inheriting TwoPort.
+end Resistance;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/PumpingStation/package.mo

@@ -0,0 +1,4 @@
+within Deltares.ChannelFlow.HydraulicStructures;
+
+package PumpingStation
+end PumpingStation;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/PumpingStation/package.order

@@ -0,0 +1,3 @@
+Resistance
+PumpingStation
+Pump

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/Weir/Weir.mo

@@ -0,0 +1,21 @@
+within Deltares.ChannelFlow.HydraulicStructures.Weir;
+
+model Weir
+  import SI = Modelica.Units.SI;
+  extends Deltares.ChannelFlow.Internal.HQTwoPort;
+
+  // Inputs
+  input SI.VolumeFlowRate Q;
+
+  // Parameters
+  parameter SI.Length width "Width of the weir";
+  parameter SI.VolumeFlowRate q_min "Minimum flow of the weir; has to be positive";
+  parameter SI.VolumeFlowRate q_max "Maximum flow of the weir. Should be as low as possible.";
+  parameter SI.Length hw_min "Minimum height of the weir";
+  parameter SI.Length hw_max "Maximum height of the weir";
+  parameter Real weir_coef=0.61 "Weir discharge coefficient";
+equation
+  HQUp.Q + HQDown.Q = 0; // Negative comes in, positive out, so in a branch positive goes in
+  HQUp.Q = Q;
+  annotation(Icon(coordinateSystem(extent = {{-100, -100}, {100, 100}}, preserveAspectRatio = true, initialScale = 0.1, grid = {10, 10}), graphics = {Polygon(visible = true, origin = {0, -16.667}, fillColor = {255, 128, 0}, fillPattern = FillPattern.Solid, lineThickness = 2, points = {{0, 66.667}, {-50, -33.333}, {50, -33.333}})}), Diagram(coordinateSystem(extent = {{-100, -100}, {100, 100}}, preserveAspectRatio = true, initialScale = 0.1, grid = {10, 10})));
+end Weir;

src/rtctools_channel_flow/modelica/Deltares/ChannelFlow/HydraulicStructures/Weir/package.mo

@@ -0,0 +1,4 @@
+within Deltares.ChannelFlow.HydraulicStructures;
+
+package Weir
+end Weir;