Add duplicate exact mappings & dup unscoped xrefs reports to DO QC

These reports address issues with duplicate xrefs and mappings.
Prompted by #1494.

Author: allenbaron

src/sparql/report/duplicate_exact_mappings.rq

@@ -0,0 +1,32 @@
+# Identify xrefs/exact mappings annotated to multiple diseases
+
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX owl: <http://www.w3.org/2002/07/owl#>
+PREFIX oboInOwl: <http://www.geneontology.org/formats/oboInOwl#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+SELECT DISTINCT ?entity ?property ?value
+WHERE {
+    {
+        SELECT ?value
+        WHERE {
+            VALUES ?property {
+                oboInOwl:hasDbXref
+                skos:exactMatch
+            }
+            ?entity a owl:Class ;
+                skos:exactMatch ?value .
+            FILTER(
+                STRSTARTS(STR(?entity), "http://purl.obolibrary.org/obo/DOID_")
+            )
+            FILTER NOT EXISTS { ?entity owl:deprecated ?any }
+        }
+        GROUP BY ?value
+        HAVING (COUNT(DISTINCT ?entity) > 1)
+    } 
+    ?entity a owl:Class ;
+        ?property ?value .
+    FILTER(STRSTARTS(STR(?entity), "http://purl.obolibrary.org/obo/DOID_"))
+    FILTER NOT EXISTS { ?entity owl:deprecated ?any }
+}
+ORDER BY ?value ?entity ?property

src/sparql/report/duplicate_unscoped_xrefs.rq

@@ -0,0 +1,38 @@
+# Identify "unscoped" xrefs (i.e. those without corresponding skos mappings)
+# that are annotated to multiple diseases
+
+PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
+PREFIX owl: <http://www.w3.org/2002/07/owl#>
+PREFIX oboInOwl: <http://www.geneontology.org/formats/oboInOwl#>
+PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
+
+SELECT DISTINCT ?entity ?property ?value
+WHERE {
+    {
+        SELECT ?property ?value
+        WHERE {
+            VALUES ?property { oboInOwl:hasDbXref }
+            ?entity a owl:Class ;
+                ?property ?value .
+            FILTER(
+                STRSTARTS(STR(?entity), "http://purl.obolibrary.org/obo/DOID_")
+            )
+            FILTER NOT EXISTS { ?entity owl:deprecated ?any }
+            FILTER NOT EXISTS {
+                VALUES ?skos {
+                    skos:exactMatch
+                    skos:narrowMatch
+                    skos:broadMatch
+                    skos:relatedMatch
+                }
+                ?entity ?skos ?value .
+            }
+        }
+        GROUP BY ?property ?value
+        HAVING (COUNT(DISTINCT ?entity) > 1)
+    } 
+    ?entity ?property ?value .
+    FILTER(STRSTARTS(STR(?entity), "http://purl.obolibrary.org/obo/DOID_"))
+    FILTER NOT EXISTS { ?entity owl:deprecated ?any }
+}
+ORDER BY ?value ?entity

src/sparql/report/report_profile.txt

@@ -1,6 +1,7 @@
 ERROR	equivalent_pair
 ERROR	invalid_xref
 ERROR	file:./src/sparql/report/def_src_not_url.rq
+ERROR	file:./src/sparql/report/duplicate_exact_mappings.rq
 ERROR	file:./src/sparql/report/invalid_class_id.rq
 ERROR	file:./src/sparql/report/invalid_obo_namespace.rq
 ERROR	file:./src/sparql/report/invalid_syn_type_property.rq
@@ -12,5 +13,6 @@ WARN	file:./src/sparql/report/invalid_mapping.rq
 WARN	file:./src/sparql/report/newline_in_text.rq
 WARN	file:./src/sparql/report/unpunctuated_definition.rq
 WARN	file:./src/sparql/report/xref_as_synonym.rq
+INFO	file:./src/sparql/report/duplicate_unscoped_xrefs.rq
 INFO	file:./src/sparql/report/missing_definition_xref.rq
 INFO	file:./src/sparql/report/xref_is_url.rq