DHOS-Reborn/flake.nix at master · DragonHeartOS/DHOS-Reborn · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        llvm = pkgs.llvmPackages_21;
        limineClang = pkgs.writeShellScriptBin "limine-clang" ''
          exec ${llvm.clang}/bin/clang "$@"
        '';
        limineSrc = pkgs.fetchFromGitHub {
          owner = "limine-bootloader";
          repo = "limine";
          rev = "5be26a73d7b7b4d4477d18be94e1d16e615adf56";
          hash = "sha256-lBPx5B3yiuWC+CiaygsOwCWKTEnLU2Wv/DE+msGXM6w=";
        };
        dhos = pkgs.stdenvNoCC.mkDerivation {
          pname = "dhos";
          version = "0.1";
          src = pkgs.lib.cleanSource ./.;

          postPatch = ''
            patchShebangs Util/*.sh
          '';

          postUnpack = ''
            cp -R ${limineSrc} "$sourceRoot/limine"
            chmod -R u+w "$sourceRoot/limine"
          '';

          nativeBuildInputs = with pkgs; [
            cmake
            ninja
            gnumake
            nasm
            python3
            xorriso
            llvm.clang-unwrapped
            llvm.bintools
            llvm.lld
          ];

          configurePhase = ''
            cmake -G Ninja -B Build \
              -DCMAKE_BUILD_TYPE=Debug \
              -DCMAKE_TOOLCHAIN_FILE=cmake/x86_64-elf-clang.cmake \
              -DCMAKE_C_COMPILER=${llvm.clang-unwrapped}/bin/clang \
              -DCMAKE_CXX_COMPILER=${llvm.clang-unwrapped}/bin/clang++ \
              -DCLANG=${llvm.clang-unwrapped}/bin/clang \
              -DCLANGXX=${llvm.clang-unwrapped}/bin/clang++ \
              -DLLD=${llvm.lld}/bin/ld.lld \
              -DNASM=${pkgs.nasm}/bin/nasm \
              -DCMAKE_AR=llvm-ar \
              -DCMAKE_RANLIB=llvm-ranlib
          '';

          buildPhase = ''
            export MAKEFLAGS="CC=${limineClang}/bin/limine-clang"
            cmake --build Build --target cdrom
          '';

          installPhase = ''
            mkdir -p "$out"
            cp Build/dhos.iso "$out/dhos.iso"
          '';
        };
      in
      {
        packages.default = dhos;

        devShells.default =
          pkgs.mkShellNoCC {
            packages =
              with pkgs;
              [
                llvm.clang-unwrapped
                llvm.lld
                llvm.clang-tools
                llvm.bintools
                lldb
                codespell

                xorriso
                gnumake
                nasm
                qemu
              ]
              ++ [
                cmake
                ninja
              ];
          };
      }
    );
}