feat(hyprland): using hidpi-xprop patch to make xwayland apps scale prefectly

read hyprwm/Hyprland#6446 for more details
xcursor size has to scale to x2 by app, because the env var `XCURSOR_SIZE` is also read by wayland apps.

Author: Dreamail

modules/hypr/hyprland/config/monitor.nix

@@ -2,7 +2,4 @@
   monitor = [
     ",preferred,auto,auto"
   ];
-  xwayland = {
-    force_zero_scaling = true;
-  };
 }

modules/hypr/hyprland/hidpi-xprop.nix

@@ -0,0 +1,18 @@
+{pkgs, ...}: {
+  services.xsettingsd = {
+    enable = true;
+    settings = {
+      "Gdk/UnscaledDPI" = 98304;
+      "Gdk/WindowScalingFactor" = 2;
+    };
+  };
+  home.packages = with pkgs.xorg; [
+    xrdb
+    xprop
+  ];
+  wayland.windowManager.hyprland.settings = {
+    exec-once = ["echo \"Xft.dpi: 192\" | xrdb -merge && xprop -root -format _XWAYLAND_GLOBAL_OUTPUT_SCALE 32c -set _XWAYLAND_GLOBAL_OUTPUT_SCALE 2"];
+    xwayland.use_nearest_neighbor = false;
+  };
+  home.sessionVariables.HIDPI_XPROP = 1; # for xwayland app detecting scaling
+}

modules/hypr/hyprland/home.nix

@@ -4,6 +4,8 @@
   isVM,
   ...
 }: {
+  imports = [./hidpi-xprop.nix];
+
   wayland.windowManager.hyprland = {
     enable = true;
     # set the flake package

modules/hypr/hyprland/nixos.nix

@@ -1,8 +1,30 @@
 {
   inputs,
+  lib,
   pkgs,
   ...
-}: {
+}: let
+  # use patch to support scaling xwayland windows
+  hyprland-patch = pkgs.fetchpatch {
+    name = "hyprland-hidpi-xprop.patch";
+    url = "https://patch-diff.githubusercontent.com/raw/hyprwm/Hyprland/pull/6446.patch";
+    hash = "sha256-60g1EvEoa/733teiMSdUCxfgrwfc/JgWTcDN49D74V4=";
+  };
+  xwayland-patch = pkgs.fetchpatch {
+    name = "xwayland-hidpi-xprop.patch";
+    url = "https://aur.archlinux.org/cgit/aur.git/plain/hidpi.patch?h=xorg-xwayland-hidpi-xprop";
+    hash = "sha256-wAsBSyp0B52jC586lDWBV6TTkLuQqEr3juOEus83GTo=";
+  };
+  xwayland = pkgs.xwayland.overrideAttrs (previousArgs: {
+    patches = [xwayland-patch];
+    mesonFlags =
+      previousArgs.mesonFlags
+      ++ [
+        (lib.mesonBool "xvfb" false)
+        (lib.mesonBool "xdmcp" false)
+      ];
+  });
+in {
   nix.settings = {
     # Hyprland cachix
     substituters = ["https://hyprland.cachix.org"];
@@ -13,8 +35,16 @@
     enable = true;
     withUWSM = true;
 
-    package = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.hyprland;
+    package =
+      (inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.hyprland.overrideAttrs {
+        patches = [hyprland-patch];
+      })
+      .override {
+        inherit xwayland;
+      };
     portalPackage = inputs.hyprland.packages.${pkgs.stdenv.hostPlatform.system}.xdg-desktop-portal-hyprland;
   };
+  environment.systemPackages = [xwayland]; # add patched xwayland to path, idkw it cant be added automatically in hyprland drv
+
   environment.sessionVariables.NIXOS_OZONE_WL = "1";
 }