CMakeLists.txt

#-------------------------------------------------------------------------------
# CMake/C++ configuration
#-------------------------------------------------------------------------------

cmake_minimum_required(VERSION 3.13.4)
project(Dynamatic)

if(POLICY CMP0075)
  cmake_policy(SET CMP0075 NEW)
endif()

if(POLICY CMP0077)
  cmake_policy(SET CMP0077 NEW)
endif()

# CMP0116: Ninja generators transform `DEPFILE`s from `add_custom_command()`
# New in CMake 3.20. https://cmake.org/cmake/help/latest/policy/CMP0116.html
if(POLICY CMP0116)
  cmake_policy(SET CMP0116 OLD)
endif()

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED YES)

if (MSVC)
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHs-c- /GR-")
else ()
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-exceptions -fno-rtti")
endif ()

include(FindPackageHandleStandardArgs)
find_package(Python3 3.6 REQUIRED COMPONENTS Interpreter)
find_package(Boost REQUIRED COMPONENTS)

# Build Dynamatic with ccache if the package is present
set(DYNAMATIC_CCACHE_BUILD OFF CACHE BOOL "Set to ON for a ccache enabled build")
if(DYNAMATIC_CCACHE_BUILD)
    find_program(CCACHE_PROGRAM ccache)
    if(CCACHE_PROGRAM)
        message(STATUS "Using ccache: ${CCACHE_PROGRAM}")
        set(CMAKE_C_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
        set(CMAKE_CXX_COMPILER_LAUNCHER ${CCACHE_PROGRAM})
    else()
        message(WARNING "ccache not found, but DYNAMATIC_CCACHE_BUILD is ON")
    endif()
endif()

# Workaround for 'HandleLLVMArgs' and LLVM_PARALLEL_LINK_JOBS not being idempotent.
# This causes it to be applied twice (once when adding LLVM as subdirectory and
# once when included below) which generates an invalid Ninja file.
set(DYNAMATIC_PARALLEL_LINK_JOBS "" CACHE STRING
        "Define the maximum number of concurrent link jobs (Ninja only).")
if(CMAKE_GENERATOR MATCHES "Ninja")
  if(NOT DYNAMATIC_PARALLEL_LINK_JOBS AND uppercase_LLVM_ENABLE_LTO STREQUAL "THIN")
    message(STATUS "ThinLTO provides its own parallel linking - limiting parallel link jobs to 2.")
    set(DYNAMATIC_PARALLEL_LINK_JOBS "2")
  endif()
  if(DYNAMATIC_PARALLEL_LINK_JOBS)
    set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${DYNAMATIC_PARALLEL_LINK_JOBS})
    set(CMAKE_JOB_POOL_LINK link_job_pool)
  endif()
elseif(DYNAMATIC_PARALLEL_LINK_JOBS)
  message(WARNING "Job pooling is only available with Ninja generators.")
endif()

#-------------------------------------------------------------------------------
# MLIR/LLVM configuration
#-------------------------------------------------------------------------------

option(DYNAMATIC_BUILD_LLVM "Build LLVM as part of the Dynamatic build" OFF)
if (DYNAMATIC_BUILD_LLVM)
  set(LLVM_ENABLE_PROJECTS "mlir;clang;polly" CACHE STRING "" FORCE)
  set(LLVM_TARGETS_TO_BUILD "host"  CACHE STRING "" FORCE)
  add_subdirectory(llvm-project/llvm "llvm-project" EXCLUDE_FROM_ALL)

  set(LLVM_CMAKE_DIR "${PROJECT_SOURCE_DIR}/llvm-project/llvm/cmake/modules")
  list(APPEND CMAKE_MODULE_PATH ${LLVM_CMAKE_DIR})
  set(MLIR_CMAKE_DIR "${CMAKE_BINARY_DIR}/lib/cmake/mlir")
  list(APPEND CMAKE_MODULE_PATH ${MLIR_CMAKE_DIR})
  set(CLANG_CMAKE_DIR "${CMAKE_BINARY_DIR}/lib/cmake/clang")
  list(APPEND CMAKE_MODULE_PATH ${CLANG_CMAKE_DIR})
  set(LLVM_EXTERNAL_LIT "${CMAKE_CURRENT_SOURCE_DIR}/llvm-project/llvm/utils/lit/lit.py" CACHE STRING "" FORCE)
  set(LLVM_INCLUDE_DIRS
          llvm-project/llvm/include
          ${CMAKE_BINARY_DIR}/llvm-project/include
  )
  set(LLVM_TOOLS_BINARY_DIR "${CMAKE_BINARY_DIR}/llvm-project/bin")
  set(MLIR_INCLUDE_DIRS
          llvm-project/mlir/include
          ${CMAKE_BINARY_DIR}/llvm-project/tools/mlir/include
  )
  set(CLANG_INCLUDE_DIRS
          llvm-project/clang/include
          ${CMAKE_BINARY_DIR}/llvm-project/tools/clang/include
  )
  set(Polly_INCLUDE_DIRS
          llvm-project/polly/include
          llvm-project/polly/lib/External/isl/include
          ${CMAKE_BINARY_DIR}/llvm-project/tools/polly/include
          ${CMAKE_BINARY_DIR}/llvm-project/tools/polly/lib/External/isl/include
  )
else ()
  set(LLVM_EXTERNAL_LIT "${CMAKE_CURRENT_SOURCE_DIR}/llvm-project/llvm/utils/lit/lit.py" CACHE STRING "" FORCE)
  message(STATUS "Using LLVMConfig.cmake in: ${LLVM_DIR}")
  message(STATUS "Using MLIRConfig.cmake in: ${MLIR_DIR}")
  message(STATUS "Using ClangConfig.cmake in: ${CLANG_DIR}")
  message(STATUS "Using PollyConfig.cmake in: ${Polly_DIR}")
  set(Clang_DIR ${CLANG_DIR})
  find_package(Clang REQUIRED CONFIG)
  find_package(Polly REQUIRED CONFIG)
  find_package(MLIR REQUIRED CONFIG)
endif ()

set(LLVM_TABLEGEN_EXE "llvm-tblgen")
set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/bin)
set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/lib)

list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_DIR}")
list(APPEND CMAKE_MODULE_PATH "${MLIR_CMAKE_DIR}")
list(APPEND CMAKE_MODULE_PATH "${CLANG_CMAKE_DIR}")

include(TableGen)
include(AddLLVM)
include(AddMLIR)
include(AddClang)
include(HandleLLVMOptions)
include(FetchContent)

link_directories(${LLVM_BUILD_LIBRARY_DIR})
add_definitions(${LLVM_DEFINITIONS})

link_directories(${Polly_LIBRARIES})

include_directories(${LLVM_INCLUDE_DIRS})
include_directories(${MLIR_INCLUDE_DIRS})
include_directories(${CLANG_INCLUDE_DIRS})
include_directories(${Polly_INCLUDE_DIRS})
# Explicitly add the path resolved by CMake so that Boost includes are
# found reliably everywhere.
include_directories(${Boost_INCLUDE_DIRS})
message(STATUS "Including from ${Polly_INCLUDE_DIRS}")
message(STATUS "Including from ${Boost_INCLUDE_DIRS}")

option(LLVM_BUILD_TOOLS "Build the LLVM tools. If OFF, just generate build targets." ON)

#-------------------------------------------------------------------------------
# Dynamatic configuration 
#-------------------------------------------------------------------------------

# Define some variables for Dynamatic
set(DYNAMATIC_SOURCE_DIR ${CMAKE_SOURCE_DIR})
set(DYNAMATIC_INCLUDE_DIR ${DYNAMATIC_SOURCE_DIR}/include)
set(DYNAMATIC_BINARY_DIR ${CMAKE_BINARY_DIR})
set(DYNAMATIC_TOOLS_DIR ${DYNAMATIC_BINARY_DIR}/bin)
set(DYNAMATIC_EXPERIMENTAL_DIR ${DYNAMATIC_SOURCE_DIR}/experimental)
set(DYNAMATIC_BIN_INCLUDE_DIR ${DYNAMATIC_BINARY_DIR}/include)

# Add our own directory to the list of search paths for CMake modules 
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules")

# Dynamatic include directories
include_directories(${DYNAMATIC_INCLUDE_DIR})
include_directories(DYNAMATIC_BINARY_DIR ${CMAKE_BINARY_DIR})
include_directories(${DYNAMATIC_BIN_INCLUDE_DIR})
include_directories(${DYNAMATIC_EXPERIMENTAL_DIR}/include)
include_directories(${DYNAMATIC_BINARY_DIR}/experimental/include)

add_custom_target(dynamatic-headers)
set_target_properties(dynamatic-headers PROPERTIES FOLDER "Misc")

function(add_dynamatic_library name)
  add_mlir_library(${ARGV})
  add_dynamatic_library_install(${name})
endfunction()

function(add_dynamatic_library_install name)
  install(TARGETS ${name} COMPONENT ${name} EXPORT DynamaticTargets)
  set_property(GLOBAL APPEND PROPERTY DYNAMATIC_ALL_LIBS ${name})
  set_property(GLOBAL APPEND PROPERTY DYNAMATIC_EXPORTS ${name})
endfunction()

function(add_dynamatic_dialect_library name)
  set_property(GLOBAL APPEND PROPERTY DYNAMATIC_DIALECT_LIBS ${name})
  add_dynamatic_library(${ARGV} DEPENDS dynamatic-headers)
endfunction()

function(add_dynamatic_dialect dialect dialect_namespace)
  add_mlir_dialect(${ARGV})
  add_dependencies(dynamatic-headers MLIR${dialect}IncGen)
endfunction()

function(add_dynamatic_interface interface)
  add_mlir_interface(${ARGV})
  add_dependencies(dynamatic-headers MLIR${interface}IncGen)
endfunction()

#-------------------------------------------------------------------------------
# Gurobi setup
#-------------------------------------------------------------------------------

find_package(GUROBI)
if (GUROBI_FOUND)
  include_directories(${GUROBI_INCLUDE_DIRS})

  # [START Check if the gurobi license is correctly set]
  execute_process(
      COMMAND gurobi_cl --license
      OUTPUT_VARIABLE GRB_LICENSE_VERSION
      RESULT_VARIABLE GRB_LICENSE_RESULT
      OUTPUT_STRIP_TRAILING_WHITESPACE
  )

  if(GRB_LICENSE_RESULT EQUAL 0)
      message(STATUS "gurobi_cl found and the license is correctly set.")
  else()
      message(FATAL_ERROR "gurobi_cl not found or the license is not correctly
      set. Please check out
      https://github.com/EPFL-LAP/dynamatic/blob/main/docs/UserGuide/AdvancedBuild.md#1-gurobi")
  endif()
  # [END Check if the gurobi license is correctly set]

else()
  message(WARNING "Gurobi wasn't found, the buffer placement algorithms \
                   that requires solving MILPs will not be built with the \
                   project.")
  add_compile_definitions(DYNAMATIC_GUROBI_NOT_INSTALLED)
endif()

#-------------------------------------------------------------------------------
# CBC solver setup
#-------------------------------------------------------------------------------

if(DYNAMATIC_ENABLE_CBC)
  if (UNIX)
    FetchContent_Declare(
      cbc
      DOWNLOAD_EXTRACT_TIMESTAMP TRUE
      SOURCE_DIR ${CMAKE_BINARY_DIR}/cbc
      URL https://github.com/coin-or/Cbc/releases/download/releases%2F2.10.12/Cbc-releases.2.10.12-x86_64-ubuntu22-gcc1140-static.tar.gz
      SYSTEM
    )

    FetchContent_MakeAvailable(cbc)
    add_compile_definitions(DYNAMATIC_ENABLE_CBC)
  else()
    message(FATAL_ERROR "Cbc integration is not tested on the OS you use!")
  endif()
endif()

#-------------------------------------------------------------------------------
# ABC setup
#-------------------------------------------------------------------------------

if(DYNAMATIC_ENABLE_ABC)
  if (UNIX)

    # Disable reproducibility warning for third-party code
    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=date-time -Wno-date-time")
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=date-time -Wno-date-time")

    FetchContent_Declare(
      abc
      DOWNLOAD_EXTRACT_TIMESTAMP TRUE
      SOURCE_DIR ${CMAKE_BINARY_DIR}/abc
      URL https://github.com/ETHZ-DYNAMO/abc/archive/refs/tags/v1.0.0.tar.gz
      SYSTEM
    )

    FetchContent_MakeAvailable(abc)
    add_compile_definitions(DYNAMATIC_ENABLE_ABC)
  else()
    message(FATAL_ERROR "ABC integration is not tested on the OS you use!")
  endif()
endif()

#-------------------------------------------------------------------------------
# Python (Virtual Environment)
#-------------------------------------------------------------------------------

find_package(Python3 3.12 REQUIRED COMPONENTS Interpreter)

set(VENV_DIR "${CMAKE_BINARY_DIR}/python3-venv")
message(STATUS "Creating Python virtual environment (Python ${Python3_VERSION})")
execute_process(COMMAND ${Python3_EXECUTABLE} -m venv ${VENV_DIR})

#-------------------------------------------------------------------------------
# XLS Integration (experimental)
#-------------------------------------------------------------------------------

set(DYNAMATIC_XLS_DIR ${DYNAMATIC_SOURCE_DIR}/xls)

if(DYNAMATIC_ENABLE_XLS)
  # Add 'DYNAMATIC_ENABLE_XLS` macro to prepoc + tablegen for conditioanl
  # inclusion of XLS features.
  add_compile_definitions(DYNAMATIC_ENABLE_XLS)
  set(LLVM_TABLEGEN_FLAGS ${LLVM_TABLEGEN_FLAGS} -DDYNAMATIC_ENABLE_XLS)

  include_directories(${DYNAMATIC_EXPERIMENTAL_DIR}/xls/include)
  include_directories(${DYNAMATIC_BINARY_DIR}/experimental/xls/include)
  include_directories(${DYNAMATIC_XLS_DIR})
endif()


#-------------------------------------------------------------------------------
# External binaries
#-------------------------------------------------------------------------------

if(DYNAMATIC_ENABLE_LEQ_BINARIES)
  # Download modified NuSMV binary,
  # which support to print larger sets of reachable states
  set(EXT_BIN_DIR "${DYNAMATIC_SOURCE_DIR}/ext")
  file(DOWNLOAD
      https://github.com/ETHZ-DYNAMO/NuSMV-2.7.0/releases/download/v1.0.1/NuSMV
      ${EXT_BIN_DIR}/NuSMV
  )
  file(CHMOD ${EXT_BIN_DIR}/NuSMV PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ)

  # Download dot2smv Python scripts
  FetchContent_Declare(
    dot2smv
    DOWNLOAD_EXTRACT_TIMESTAMP TRUE
    SOURCE_DIR     ${EXT_BIN_DIR}/dot2smv
    URL https://github.com/Jiahui17/dot2smv/archive/refs/heads/elastic-miter.tar.gz
  )

  FetchContent_Declare(
    nuXmv
    DOWNLOAD_EXTRACT_TIMESTAMP TRUE
    SOURCE_DIR ${EXT_BIN_DIR}/nuXmv
    URL https://nuxmv.fbk.eu/theme/download.php?file=nuXmv-2.1.0-linux64.tar.xz
  )

  FetchContent_MakeAvailable(dot2smv nuXmv)

  # Inform our compiler infrastructure that NuSMV is available.
  add_compile_definitions(DYNAMATIC_ENABLE_LEQ_BINARIES)
endif()

# We use GoogleTest for regression tests
FetchContent_Declare(
  googletest
  DOWNLOAD_EXTRACT_TIMESTAMP true
  URL https://github.com/google/googletest/archive/2ae29b52fdff88c52fef655fa0d245fc514ca35b.zip
  SYSTEM
)

# For Windows: Prevent overriding the parent project's compiler/linker settings
set(gtest_force_shared_crt ON CACHE BOOL "" FORCE)
FetchContent_MakeAvailable(googletest)

# TODO: Use the JSON package from Boost instead.
FetchContent_Declare(
  json
  URL https://github.com/nlohmann/json/releases/download/v3.12.0/json.tar.xz
  SYSTEM
)
FetchContent_MakeAvailable(json)

#-------------------------------------------------------------------------------
# Directory setup
#-------------------------------------------------------------------------------

add_subdirectory(${DYNAMATIC_INCLUDE_DIR}/dynamatic)
add_subdirectory(${DYNAMATIC_SOURCE_DIR}/test)

# CMake macro to add a custom new unit test to dynamatic.
# A unit test should be a test target that does not require any special
# environment setup beyond what is performed by CMake.
# All unit tests are performed as part of the 'check-dynamatic' target.
macro(add_to_unit_testing target)
  add_dependencies(check-dynamatic ${target})
endmacro()

add_subdirectory(${DYNAMATIC_SOURCE_DIR}/experimental)
add_subdirectory(${DYNAMATIC_SOURCE_DIR}/lib)
add_subdirectory(${DYNAMATIC_SOURCE_DIR}/tools)
add_subdirectory(${DYNAMATIC_SOURCE_DIR}/tutorials)
add_subdirectory(${DYNAMATIC_SOURCE_DIR}/unittests)