Add a custom CMake find script for the K4A SDK on Windows since this does not seem to come with a CMake config file

Author: puzzlepaint

CMakeLists.txt

@@ -117,7 +117,7 @@ enable_testing()
 
 # libpng (packaged)
 add_subdirectory(libvis/third_party/libpng)
-set_target_properties(png png_static genfiles genprebuilt gensym genvers symbol-check PROPERTIES FOLDER "libvis/third_party/png")
+set_target_properties(png png_static genfiles PROPERTIES FOLDER "libvis/third_party/png")
 
 # GLEW (external, required)
 find_package(GLEW REQUIRED)

applications/badslam/CMakeLists.txt

@@ -25,8 +25,15 @@ if (CMAKE_CUDA_COMPILER)
   find_package(realsense2)
 
   # Optional, only required for live Azure Kinect camera support
-  find_package(k4a)
-  find_package(k4arecord)
+  if (WIN32)
+    # Use a custom find script in the cmake subdirectory since the K4A SDK does
+    # not seem to ship cmake files on Windows
+    find_package(K4A)
+  else()
+    # On Linux, use the SDK-provided CMake files
+    find_package(k4a)
+    find_package(k4arecord)
+  endif()
 
   # Optional, only required for live Structure Core camera support
   find_package(Structure)
@@ -107,12 +114,22 @@ if (CMAKE_CUDA_COMPILER)
     )
   endif()
 
-  if (TARGET k4a::k4a)
-    target_link_libraries(badslam_baselib PRIVATE
-      k4a::k4a
-      k4a::k4arecord
-    )
-    target_compile_definitions(badslam_baselib PUBLIC HAVE_K4A)
+  if (WIN32)
+    if (TARGET K4APrebuilt AND TARGET K4ARecordPrebuilt)
+      target_link_libraries(badslam_baselib PUBLIC
+        K4APrebuilt
+        K4ARecordPrebuilt
+      )
+      target_compile_definitions(badslam_baselib PUBLIC HAVE_K4A)
+    endif()
+  else()
+    if (TARGET k4a::k4a)
+      target_link_libraries(badslam_baselib PUBLIC
+        k4a::k4a
+        k4a::k4arecord
+      )
+      target_compile_definitions(badslam_baselib PUBLIC HAVE_K4A)
+    endif()
   endif()
 
   if(MSVC)

applications/badslam/cmake/FindK4A.cmake

@@ -0,0 +1,49 @@
+# CMake module which defines the "K4A" target if the user points
+# out the location of the K4A SDK in the K4ASDK_ROOT cached variable. No
+# automatic detection of the SDK install location is attempted.
+
+if(NOT K4ASDK_ROOT OR K4ASDK_ROOT EQUAL "K4ASDK_ROOT-NOTFOUND")
+  message(STATUS "K4ASDK_ROOT has not been set. If you would like to use the K4A SDK support, please set this to the root path of the K4A SDK manually.")
+  set(K4ASDK_ROOT "K4ASDK_ROOT-NOTFOUND" CACHE PATH "K4A SDK root directory")
+else()
+  file(TO_CMAKE_PATH ${K4ASDK_ROOT} K4ASDK_ROOT)
+  
+  if(NOT K4ASDK_TARGET_ARCH)
+    message(WARNING "K4ASDK_TARGET_ARCH is not set. Assuming amd64.")
+    set(K4ASDK_TARGET_ARCH amd64)
+  endif()
+  
+  set(K4ASDK_HEADERS ${K4ASDK_ROOT}/sdk/include)
+  
+  if(WIN32)
+    set(K4ASDK_LIBDIR ${K4ASDK_ROOT}/sdk/windows-desktop/${K4ASDK_TARGET_ARCH}/release/lib)
+    set(K4A_IMPORTLIB ${K4ASDK_LIBDIR}/k4a.lib)
+    set(K4ARECORD_IMPORTLIB ${K4ASDK_LIBDIR}/k4arecord.lib)
+  else()
+    message(FATAL_ERROR "Unknown platform for the K4A SDK find script.")
+  endif()
+  
+  # Define K4APrebuilt target if k4a.lib was found
+  if(EXISTS ${K4A_IMPORTLIB})
+    set(K4A_FOUND TRUE)
+    add_library(K4APrebuilt UNKNOWN IMPORTED)
+    set_target_properties(K4APrebuilt PROPERTIES
+        IMPORTED_LOCATION ${K4A_IMPORTLIB}
+        INTERFACE_INCLUDE_DIRECTORIES ${K4ASDK_HEADERS}
+    )
+  else()
+    set(K4A_FOUND FALSE)
+  endif()
+  
+  # Define K4ARecordPrebuilt target if k4a.lib was found
+  if(EXISTS ${K4ARECORD_IMPORTLIB})
+    set(K4ARECORD_FOUND TRUE)
+    add_library(K4ARecordPrebuilt UNKNOWN IMPORTED)
+    set_target_properties(K4ARecordPrebuilt PROPERTIES
+        IMPORTED_LOCATION ${K4ARECORD_IMPORTLIB}
+        INTERFACE_INCLUDE_DIRECTORIES ${K4ASDK_HEADERS}
+    )
+  else()
+    set(K4ARECORD_FOUND FALSE)
+  endif()
+endif()