ECClientSettingsNeoForge/build.gradle at master · EaseCation/ECClientSettingsNeoForge · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
plugins {
    id 'java-library'
    id 'net.neoforged.moddev' version '2.0.141'
}

version = mod_version
group = mod_group_id

repositories {
    maven { url = 'https://maven.shedaniel.me/' }
    maven { url = 'https://libraries.minecraft.net/' }
    mavenCentral()
}

base {
    archivesName = mod_id
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

dependencies {
    implementation "me.shedaniel.cloth:cloth-config-neoforge:${cloth_config_version}"
    implementation "net.easecation:netease-bridge-client-neoforge:1.0.0"
    implementation "net.easecation:netease-bridge-client-common:1.0.0"
    implementation "org.oryxel.viabedrockutility:viabedrockutility:1.0.0"
    implementation "org.msgpack:msgpack-core:0.9.8"

    testImplementation platform('org.junit:junit-bom:5.12.2')
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

neoForge {
    version = neo_version

    runs {
        configureEach {
            systemProperty 'forge.logging.markers', 'REGISTRIES'
            systemProperty 'forge.logging.console.level', 'debug'
            gameDirectory = project.file("run/${name}")
        }
        client {
            client()
        }
    }

    mods {
        "${mod_id}" {
            sourceSet sourceSets.main
        }
    }

    unitTest {
        testedMod = mods."${mod_id}"
        enable()
    }
}

tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            cloth_config_version   : cloth_config_version,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/neoforge.mods.toml']) {
        expand replaceProperties
    }

    from('THIRD_PARTY_NOTICES.md') {
        into 'META-INF'
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

tasks.named('test') {
    useJUnitPlatform()
}