terraform-aws-stac-server/opensearch_serverless.tf at main · Element84/terraform-aws-stac-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
resource "aws_opensearchserverless_security_policy" "stac_server_opensearch_serverless_encryption_policy" {
  count = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  name  = lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server-ep" : var.opensearch_stac_server_domain_name_override)
  type  = "encryption"
  policy = jsonencode({
    "Rules" = [
      {
        "Resource" = [
          "collection/${lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)}"
        ],
        "ResourceType" = "collection"
      }
    ],
    "AWSOwnedKey" = true
  })
}

resource "aws_opensearchserverless_security_policy" "stac_server_opensearch_serverless_network_policy" {
  count = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  name  = lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-np" : var.opensearch_stac_server_domain_name_override)
  type  = "network"
  policy = jsonencode([
    {
      Description = "Public access for collection endpoint",
      Rules = [
        {
          ResourceType = "collection",
          Resource = [
            "collection/${lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)}"
          ]
        }
      ],
      AllowFromPublic = true,
    },
    {
      Description = "Public access for dashboards",
      Rules = [
        {
          ResourceType = "dashboard"
          Resource = [
            "collection/${lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)}"
          ]
        }
      ],
      AllowFromPublic = true
    }
  ])
}

resource "aws_opensearchserverless_access_policy" "stac_server_opensearch_serverless_access_policy" {
  count = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  name  = lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-ap" : var.opensearch_stac_server_domain_name_override)
  type  = "data"
  policy = jsonencode([
    {
      Rules = [
        {
          ResourceType = "index",
          Resource = [
            "index/${lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)}/*"
          ],
          Permission = [
            "aoss:*"
          ]
        },
        {
          ResourceType = "collection",
          Resource = [
            "collection/${lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)}"
          ],
          Permission = [
            "aoss:*"
          ]
        }
      ],
      Principal = [
        data.aws_caller_identity.current.arn,
        aws_iam_role.stac_api_lambda_role.arn
      ]
    }
  ])

  lifecycle {
    ignore_changes = [policy]
  }
}

resource "aws_opensearchserverless_collection" "stac_server_opensearch_serverless_collection" {
  count       = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  name        = lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)
  description = "Stac-server database for ${local.name_prefix}-stac-server"
  type        = "SEARCH"

  depends_on = [
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_encryption_policy,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_network_policy,
    aws_opensearchserverless_access_policy.stac_server_opensearch_serverless_access_policy
  ]
}

resource "aws_lambda_function" "stac_server_waiting_for_opensearch_serverless_active_collections" {
  count            = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  filename         = data.archive_file.waiting_for_opensearch_lambda_zip.output_path
  source_code_hash = data.archive_file.waiting_for_opensearch_lambda_zip.output_base64sha256
  function_name    = "${local.name_prefix}-stac-server-oss-wait-collections"
  role             = aws_iam_role.stac_api_lambda_role.arn
  description      = "Polls an opensearch serverless collection to ensure it is active prior to attempting to ingest."
  handler          = "main.lambda_handler"
  runtime          = "python3.11"
  memory_size      = "512"
  timeout          = "900"

  environment {
    variables = {
      COLLECTION_NAME = lower(var.opensearch_stac_server_domain_name_override == null ? "${local.name_prefix}-stac-server" : var.opensearch_stac_server_domain_name_override)
      REGION          = data.aws_region.current.region
    }
  }

  depends_on = [
    aws_lambda_function.stac_server_ingest,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_encryption_policy,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_network_policy,
    aws_opensearchserverless_access_policy.stac_server_opensearch_serverless_access_policy,
    aws_opensearchserverless_collection.stac_server_opensearch_serverless_collection
  ]
}

resource "aws_lambda_invocation" "stac_server_opensearch_serverless_wait_for_collections" {
  count         = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  function_name = aws_lambda_function.stac_server_waiting_for_opensearch_serverless_active_collections[0].function_name

  input = "{}"

  depends_on = [
    aws_lambda_function.stac_server_ingest,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_encryption_policy,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_network_policy,
    aws_opensearchserverless_access_policy.stac_server_opensearch_serverless_access_policy,
    aws_opensearchserverless_collection.stac_server_opensearch_serverless_collection,
    aws_lambda_function.stac_server_waiting_for_opensearch_serverless_active_collections
  ]
}


resource "aws_lambda_invocation" "stac_server_opensearch_serverless_ingest_create_indices" {
  count         = var.deploy_stac_server_opensearch_serverless ? 1 : 0
  function_name = aws_lambda_function.stac_server_ingest.function_name

  input = "{ \"create_indices\": true }"

  depends_on = [
    aws_lambda_function.stac_server_ingest,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_encryption_policy,
    aws_opensearchserverless_security_policy.stac_server_opensearch_serverless_network_policy,
    aws_opensearchserverless_access_policy.stac_server_opensearch_serverless_access_policy,
    aws_opensearchserverless_collection.stac_server_opensearch_serverless_collection,
    aws_lambda_function.stac_server_waiting_for_opensearch_serverless_active_collections,
    aws_lambda_invocation.stac_server_opensearch_serverless_wait_for_collections
  ]
}