Casper-Feed/casper-feed/build.gradle.kts at af9c3666549d03c3ea2d7acb21d5a839efc32991 · EntryDSM/Casper-Feed · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
plugins {
    id(Plugin.KOTLIN_JVM) version PluginVersion.KOTLIN_VERSION
    id(Plugin.KOTLIN_SPRING) version PluginVersion.KOTLIN_VERSION
    id(Plugin.KOTLIN_KAPT)
    id(Plugin.SPRING_BOOT) version PluginVersion.SPRING_BOOT_VERSION
    id(Plugin.SPRING_DEPENDENCY_MANAGEMENT) version PluginVersion.SPRING_DEPENDENCY_MANAGEMENT_VERSION
    id(Plugin.CASPER_DOCUMENTATION)
    id(Plugin.PROTOBUF) version PluginVersion.PROTOBUF_VERSION
    id(Plugin.OSDETECTOR) version PluginVersion.OSDETECTOR_VERSION
    kotlin(Plugin.JPA) version PluginVersion.KOTLIN_VERSION
}

group = "hs.kr.entrydsm"
version = "0.0.1-SNAPSHOT"

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(17)
	}
}

repositories {
	mavenCentral()
}

dependencyManagement {
    imports {
        mavenBom("org.springframework.cloud:spring-cloud-dependencies:${DependencyVersion.SPRING_CLOUD_CONFIG_VERSION}")
    }
}

dependencies {
    // 스프링 부트 기본 기능
    implementation(Dependencies.SPRING_BOOT_STARTER)

    // 코틀린 리플렉션
    implementation(Dependencies.KOTLIN_REFLECT)

    // 스프링 부트 테스트 도구
    testImplementation(Dependencies.SPRING_BOOT_STARTER_TEST)

    // 코틀린 + JUnit5 테스트
    testImplementation(Dependencies.KOTLIN_TEST_JUNIT5)

    // JUnit5 실행 런처
    testRuntimeOnly(Dependencies.JUNIT_PLATFORM_LAUNCHER)

    // 웹 관련
    implementation(Dependencies.SPRING_BOOT_STARTER_WEB)

    // 데이터베이스
    implementation(Dependencies.SPRING_BOOT_STARTER_DATA_JPA)
    implementation(Dependencies.SPRING_BOOT_STARTER_DATA_REDIS)
    runtimeOnly(Dependencies.MYSQL_CONNECTOR)

    // 보안
    implementation(Dependencies.SPRING_BOOT_STARTER_SECURITY)

    // 검증
    implementation(Dependencies.SPRING_BOOT_STARTER_VALIDATION)

    // JSON 처리
    implementation(Dependencies.JACKSON_MODULE_KOTLIN)
    implementation(Dependencies.ORG_JSON)

    // JWT
    implementation(Dependencies.JWT_API)
    implementation(Dependencies.JWT_IMPL)
    runtimeOnly(Dependencies.JWT_JACKSON)

    implementation(Dependencies.MAPSTRUCT)
    kapt(Dependencies.MAPSTRUCT_PROCESSOR)

    // grpc
    implementation(Dependencies.GRPC_NETTY_SHADED)
    implementation(Dependencies.GRPC_PROTOBUF)
    implementation(Dependencies.GRPC_STUB)
    implementation(Dependencies.GRPC_KOTLIN_STUB)
    implementation(Dependencies.PROTOBUF_KOTLIN)
    testImplementation(Dependencies.GRPC_TESTING)
    implementation(Dependencies.GRPC_CLIENT)
    implementation(Dependencies.GOOGLE_PROTOBUF)

    // 코루틴
    implementation(Dependencies.COROUTINES)

    // swagger
    implementation(Dependencies.SWAGGER)

    // aws
    implementation(Dependencies.AWS)

    // feign
    implementation(Dependencies.OPEN_FEIGN)

    // Cloud Config
    implementation(Dependencies.SPRING_CLOUD_CONFIG)

    // Resilience4j
    implementation(Dependencies.RESILIENCE4J_CIRCUITBREAKER)
    implementation(Dependencies.RESILIENCE4J_RETRY)
    implementation(Dependencies.RESILIENCE4J_SPRING_BOOT)
    implementation(Dependencies.RESILIENCE4J_KOTLIN)
}

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:${DependencyVersion.PROTOBUF}"
    }
    plugins {
        create("grpc") {
            artifact = "io.grpc:protoc-gen-grpc-java:${DependencyVersion.GRPC}:${osdetector.classifier}"
        }
        create("grpckt") {
            artifact = "io.grpc:protoc-gen-grpc-kotlin:${DependencyVersion.GRPC_KOTLIN}:jdk8@jar"
        }
    }
    generateProtoTasks {
        all().forEach {
            it.plugins {
                create("grpc")
                create("grpckt")
            }
        }
    }
}

kotlin {
	compilerOptions {
		freeCompilerArgs.addAll("-Xjsr305=strict")
	}
}

tasks.withType<Test> {
	useJUnitPlatform()
}