exiv2/cmake/exiv2Config.cmake.in at a5b5a047a489226f603ecdca2e1c0dad607647d5 · Exiv2/exiv2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
@PACKAGE_INIT@

cmake_minimum_required(VERSION 3.12)
include(CMakeFindDependencyMacro)

if(NOT @BUILD_SHARED_LIBS@) # if(NOT BUILD_SHARED_LIBS)
  if(@EXIV2_ENABLE_PNG@) # if(EXIV2_ENABLE_PNG)
    find_dependency(ZLIB REQUIRED)
  endif()

  if(@EXIV2_ENABLE_BMFF@ AND @EXIV2_ENABLE_BROTLI@) # if(EXIV2_ENABLE_BMFF AND EXIV2_ENABLE_BROTLI)
    find_package(Brotli QUIET)
    if (NOT Brotli_FOUND)
      message(FATAL_ERROR
        "Static builds of exiv2 require Brotli. "
        "Please provide FindBrotli.cmake on CMAKE_MODULE_PATH "
        "or point to the cmake/ dir in the exiv2 source tree.")
    endif()
  endif()

  if(@EXIV2_ENABLE_WEBREADY@) # if(EXIV2_ENABLE_WEBREADY)
    if(@EXIV2_ENABLE_CURL@) # if(EXIV2_ENABLE_CURL)
      find_dependency(CURL REQUIRED)
    endif()
  endif()

  if(@EXIV2_ENABLE_XMP@) # if(EXIV2_ENABLE_XMP)
    find_dependency(EXPAT REQUIRED)
  elseif(@EXIV2_ENABLE_EXTERNAL_XMP@) # elseif(EXIV2_ENABLE_EXTERNAL_XMP)
    find_dependency(XmpSdk REQUIRED)
  endif()

  if(@EXIV2_ENABLE_NLS@) # if(EXIV2_ENABLE_NLS)
    find_dependency(Intl REQUIRED)
  endif()

  if(@EXV_HAVE_LIBICONV@) # if(EXV_HAVE_LIBICONV)
    find_dependency(Iconv REQUIRED)
  endif()

  if(@EXIV2_ENABLE_INIH@) # if(EXIV2_ENABLE_INIH)
    find_package(inih QUIET)
    if (NOT inih_FOUND)
      message(FATAL_ERROR
        "Static builds of exiv2 require inih. "
        "Please provide Findinih.cmake on CMAKE_MODULE_PATH "
        "or point to the cmake/ dir in the exiv2 source tree.")
    endif()
  endif()
endif()

include("${CMAKE_CURRENT_LIST_DIR}/exiv2Targets.cmake")

check_required_components(exiv2)

# compatibility with non-aliased users
if(NOT TARGET exiv2lib)
  add_library(exiv2lib ALIAS Exiv2::exiv2lib)
endif()