Ashwing/build.gradle.kts at main · FTBTeam/Ashwing · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
plugins {
    id("java")
    id("com.gradle.plugin-publish") version "1.2.0"
    `java-gradle-plugin`
}

var isSnapshot = providers.environmentVariable("SNAPSHOT").getOrElse("false").toBoolean()

group = "dev.ftb.plugins"
version = "0.2.0" + (if (isSnapshot) "-SNAPSHOT" else "")

repositories {
    mavenCentral()
    gradlePluginPortal()
}

dependencies {
    implementation("org.jspecify:jspecify:1.0.0")

    // Use modmuss50's plugin to help with publishing
    implementation("me.modmuss50:mod-publish-plugin:2.1.0")

    // Commons lang3
    implementation("org.apache.commons:commons-lang3:3.18.0")

    testImplementation(platform("org.junit:junit-bom:5.10.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")
    testRuntimeOnly("org.junit.platform:junit-platform-launcher")
}

tasks.test {
    useJUnitPlatform()
}

tasks.withType(JavaCompile::class.java).all {
    options.release = 21
}

gradlePlugin {
    website = "https://github.com/ftbteam/Ashwing"
    vcsUrl = "https://github.com/ftbteam/Ashwing"

    plugins.create("ashwing") {
        id = "dev.ftb.plugins.ashwing"
        implementationClass = "dev.ftb.plugins.ashwing.AshwingPlugin"
        displayName = "Ashwing"
        description = "Tools for FTB Mods"
        version = project.version
    }
}

publishing {
    repositories {
        val token = providers.environmentVariable("FTB_MAVEN_TOKEN")
        if (token.isPresent) {
            maven {
                url = uri("https://maven.ftb.dev/releases")
                credentials {
                    username = "ftb"
                    password = token.get()
                }
            }
        }
    }
}