windows_build.bat

@ECHO OFF && setlocal ENABLEDELAYEDEXPANSION
ECHO  _________________________________________________________________________________ 
ECHO ^|                                                                                 ^|
ECHO ^|            You are about to build both projects and install the app.            ^|
ECHO ^|                                                                                 ^|
ECHO ^|     Note that "Cargo" and "npm" are needed to proceed with the installation.    ^|
ECHO ^|_________________________________________________________________________________^|
PAUSE

WHERE cargo >nul 2>nul
IF %ERRORLEVEL% NEQ 0 (
    ECHO cargo wasn't found
    PAUSE
    EXIT
)
cargo -V
WHERE npm >nul 2>nul
IF %ERRORLEVEL% NEQ 0 (
    WHERE fnm >nul 2>nul
    IF !ERRORLEVEL! NEQ 0 (
        ECHO npm wasn't found
        PAUSE
        EXIT
    ) ELSE (
        fnm env --use-on-cd > temp_script.cmd
        call temp_script.cmd
        del temp_script.cmd
    )
)
for /f "delims=" %%a in ('npm -v 2^>nul') do @set "npmV=%%a"
ECHO npm %npmV%
SET /p "instdir=Enter desired installation absolute path: "
SET valid=false
IF "%instdir:~1,2%"==":\" IF EXIST %instdir% set valid=true
IF %valid%==false (
    ECHO *Path must be ABSOLUTE ^(like 'C:\path\to\dir'^)*
    PAUSE
    EXIT
)
ECHO.
ECHO Are you sure? Path: %instdir%
ECHO.
PAUSE
::Remove trailing backslash
IF %instdir:~-1%==\ SET instdir=%instdir:~0,-1%
ECHO Selected folder: %instdir%
mkdir "%instdir%\emergency-backup"
ECHO  ____________________________________
ECHO ^|                                    ^|
ECHO ^| Building main_emergency-backup.exe ^|
ECHO ^|____________________________________^|
cd .\Main
cargo build --release
del .\resource.lib
del .\resource.rc
ECHO  _______________________________________
ECHO ^|                                       ^|
ECHO ^| Copying files to installation folder: ^|
ECHO ^|_______________________________________^|
ECHO  - main_emergency-backup.exe
copy .\target\release\main_emergency-backup.exe "%instdir%\emergency-backup"
ECHO  - cat_ext.json
copy .\cat_ext.json "%instdir%\emergency-backup"
ECHO  - voice_audios
xcopy /E /I .\voice_audios "%instdir%\emergency-backup\voice_audios\"
ECHO  - icons
xcopy /E /I .\icons "%instdir%\emergency-backup\icons\"
ECHO  - disable.bat
copy .\disable.bat "%instdir%\emergency-backup"
ECHO  __________________
ECHO ^|                  ^|
ECHO ^| Building GUI app ^|
ECHO ^|__________________^|
cd ..\BackupGuiRust
call npm install
call npm run tauri build
copy .\src-tauri\target\release\emergency-backup.exe "%instdir%\emergency-backup"
ECHO ** DONE **
%windir%\explorer.exe "%instdir%\emergency-backup"
timeout /t 10