[apple2] change sp_find functions to search by type instead of name

Author: markjfisher

apple2/src/bus/cc65/sp_close.s

@@ -1,7 +1,7 @@
         .export         _sp_close
 
         .import         _sp_cmdlist
-        .import         _sp_dispatch
+        .import         sp_dispatch
 
         .include        "sp.inc"
 
@@ -15,6 +15,6 @@
         sta     _sp_cmdlist+1                   ; sp_cmdlist[1] = dest;
         lda     #SP_CLOSE_PARAM_COUNT
         sta     _sp_cmdlist                     ; sp_cmdlist[0] = SP_CLOSE_PARAM_COUNT;
-        lda     #SP_CMD_CLOSE
-        jmp     _sp_dispatch                    ; return sp_dispatch(SP_CMD_CLOSE);
+        ldx     #SP_CMD_CLOSE
+        jmp     sp_dispatch                    ; return sp_dispatch(SP_CMD_CLOSE);
 .endproc

apple2/src/bus/cc65/sp_close_nw.s

@@ -1,7 +1,7 @@
         .export         _sp_close_nw
 
         .import         _sp_cmdlist
-        .import         _sp_dispatch
+        .import         sp_dispatch
         .import         _sp_nw_unit
 
         .include        "sp.inc"
@@ -20,6 +20,6 @@
         sta     _sp_cmdlist                     ; sp_cmdlist[0] = SP_CLOSE_PARAM_COUNT_NW;
         lda     _sp_nw_unit
         sta     _sp_cmdlist+2                   ; sp_cmdlist[2] = sp_nw_unit;
-        lda     #SP_CMD_CLOSE
-        jmp     _sp_dispatch                    ; return sp_dispatch(SP_CMD_CLOSE);
+        ldx     #SP_CMD_CLOSE
+        jmp     sp_dispatch                    ; return sp_dispatch(SP_CMD_CLOSE);
 .endproc

apple2/src/bus/cc65/sp_common.s

@@ -0,0 +1,44 @@
+        .export         _sp_find_clock
+        .export         _sp_get_clock_id
+        .export         _sp_clock_id
+
+        .import         _sp_find_device
+
+        .import         return0
+        .import         return1
+
+        .macpack        cpu
+
+; bool sp_find_clock()
+_sp_find_clock:
+        lda     #$13
+        jsr     _sp_find_device
+
+        bmi     not_found
+        beq     not_found
+
+        sta     _sp_clock_id
+        jmp     return1
+
+not_found:
+
+.if (.cpu .bitand ::CPU_ISET_65SC02)
+        stz     _sp_clock_id
+.else
+        lda     #$00
+        sta     _sp_clock_id
+.endif
+        jmp     return0
+
+
+; uint8_t sp_get_clock_id()
+_sp_get_clock_id:
+        ldx     #$00                    ; prep the return hi byte for C callers
+        lda     _sp_clock_id
+        beq     _sp_find_clock
+
+        ; A contains the ID > 0, X is 0, so just return
+        rts
+
+.data
+_sp_clock_id:   .byte $00

apple2/src/bus/cc65/sp_control.s

@@ -0,0 +1,44 @@
+        .export         _sp_find_cpm
+        .export         _sp_get_cpm_id
+        .export         _sp_cpm_id
+
+        .import         _sp_find_device
+
+        .import         return0
+        .import         return1
+
+        .macpack        cpu
+
+; bool sp_find_cpm()
+_sp_find_cpm:
+        lda     #$12
+        jsr     _sp_find_device
+
+        bmi     not_found
+        beq     not_found
+
+        sta     _sp_cpm_id
+        jmp     return1
+
+not_found:
+
+.if (.cpu .bitand ::CPU_ISET_65SC02)
+        stz     _sp_cpm_id
+.else
+        lda     #$00
+        sta     _sp_cpm_id
+.endif
+        jmp     return0
+
+
+; uint8_t sp_get_cpm_id()
+_sp_get_cpm_id:
+        ldx     #$00                    ; prep the return hi byte for C callers
+        lda     _sp_cpm_id
+        beq     _sp_find_cpm
+
+        ; A contains the ID > 0, X is 0, so just return
+        rts
+
+.data
+_sp_cpm_id:   .byte $00

apple2/src/bus/cc65/sp_control_nw.s

@@ -0,0 +1,98 @@
+        .export         _sp_find_device
+
+        .import         _sp_cmdlist
+        .import         _sp_init
+        .import         _sp_is_init
+        .import         _sp_nw_unit
+        .import         _sp_payload
+        .import         _sp_status
+
+        .import         pusha
+        .import         negax
+        .import         return0
+
+        .include        "sp.inc"
+
+; int sp_find_device(uint8_t type_id);
+; where type_id is the internal fujinet device type_id:
+;  $10 = fujinet
+;  $11 = network
+;  $12 = cpm
+;  $13 = clock
+;  $14 = printer
+;  $15 = modem
+;  $01 = floppy disk
+;  $02 = hard disk
+_sp_find_device:
+        sta     device_type_id          ; save the type_id
+        ; check if we've already run sp_init
+        lda     _sp_is_init
+        bne     have_init
+
+        ; no, so do it now
+        jsr     _sp_init
+        bne     have_init
+
+        ; return 0 as the network device, and is an error
+        jmp     return0
+
+have_init:
+        lda     #$00
+        jsr     pusha                   ; doesn't change A, so can be used to double up as both params
+        jsr     _sp_status              ; sp_status(0,0) fetches the device count
+
+        beq     status_ok_1
+
+        ; there was an error, negate A/X and return it
+        jmp     negax
+        ; implicit RTS
+
+status_ok_1:
+        ldx     #$00                    ; prep the return value if it's going to be 0
+        lda     _sp_payload             ; device count in sp_payload[0]
+        beq     :+                      ; if the count is zero, just return 0, don't touch X as it's already 0
+        bpl     have_count
+
+        ; byte extend the negative value into X, as A is already negative
+        dex
+:       rts
+
+have_count:
+        ; now repeatedly call sp_status(i, 3) to get the DIB status for the device, which contains name and its device type
+        ; a contains the count of devices, 1 based
+        sta     device_count
+
+        lda     #$01
+        sta     device_id_idx
+device_loop:
+        jsr     pusha                   ; the current Device ID
+        lda     #$03
+        jsr     _sp_status              ; sp_status(id,3) DIB request
+
+        bne     not_found_yet           ; there wasn't a valid DIB for this device index
+
+        ; compare sp_payload[21] to device_type_id
+        lda     _sp_payload+21
+        cmp     device_type_id
+        bne     not_found_yet
+
+        ; found it, so return the current index
+        ldx     #$00
+        lda     device_id_idx
+        rts
+
+not_found_yet:
+        inc     device_id_idx
+        lda     device_id_idx
+        cmp     device_count
+        bcc     device_loop
+        beq     device_loop
+
+        ; we have checked all devices, non had the type we were looking for
+        jmp     return0
+
+
+.bss
+device_type_id: .res 1
+device_count:   .res 1
+device_id_idx:  .res 1