gravity-world/justfile at main · Galxe/gravity-world · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
# AI Town Game - Development Commands

# -- Anvil (local chain) --

# Start local Anvil chain
anvil-start:
    anvil

# Deploy contracts to local chain
# Usage: just anvil-deploy [rpc_url] [private_key] [operator_address]
[working-directory: "contracts"]
anvil-deploy \
    rpc_url="http://127.0.0.1:8545" \
    private_key="0xac0974bec39a17e36ba4a6b4d238ff944bacb478cbed5efcae784d7bf4f2ff80" \
    operator_address="0xf39Fd6e51aad88F6F4ce6aB8827279cffFb92266":
    PRIVATE_KEY={{private_key}} OPERATOR_ADDRESS={{operator_address}} \
    forge script script/Deploy.s.sol --rpc-url {{rpc_url}} --broadcast -v
    @echo ""
    @echo "Router: $(grep -o '0x[0-9a-fA-F]*' ../deployed-addresses.json)"
    @echo ""
    @echo "Next steps:"
    @echo "  just agent-start config/localhost.toml"
    @echo "  just frontend-start"

# Deploy contracts to Gravity Testnet
[working-directory: "contracts"]
gravity-deploy:
    #!/usr/bin/env bash
    source ../agent-runner/config/gravity.env 2>/dev/null || true
    PRIVATE_KEY=${PRIVATE_KEY:-"0x859b68e0eddb79598540a35dcd0f7cf4df7c7b8cad35151177439268566cbfa9"} \
    OPERATOR_ADDRESS=${OPERATOR_ADDRESS:-"$(cast wallet address 0x859b68e0eddb79598540a35dcd0f7cf4df7c7b8cad35151177439268566cbfa9)"} \
    forge script script/Deploy.s.sol \
        --rpc-url https://rpc-testnet.gravity.xyz \
        --broadcast \
        --use 0.8.30 \
        -v
    echo ""
    echo "Router: $(grep -o '0x[0-9a-fA-F]*' ../deployed-addresses.json)"
    echo ""
    echo "Next steps:"
    echo "  1. Update frontend/config/gravity.json with the new router address"
    echo "  2. just agent-start config/gravity.toml"
    echo "  3. just frontend-start gravity"

# Upgrade contracts on Gravity Testnet (keeps proxy addresses, only swaps implementations)
[working-directory: "contracts"]
gravity-upgrade:
    #!/usr/bin/env bash
    source ../agent-runner/config/gravity.env 2>/dev/null || true
    PRIVATE_KEY=${PRIVATE_KEY:-"0x859b68e0eddb79598540a35dcd0f7cf4df7c7b8cad35151177439268566cbfa9"} \
    ROUTER_ADDRESS=$(grep -o '0x[0-9a-fA-F]*' ../frontend/config/gravity.json | head -1) \
    forge script script/Upgrade.s.sol \
        --rpc-url https://rpc-testnet.gravity.xyz \
        --broadcast \
        -v
    echo ""
    echo "All implementations upgraded. Proxy addresses unchanged."

# Upgrade contracts on local Anvil
[working-directory: "contracts"]
anvil-upgrade:
    #!/usr/bin/env bash
    PRIVATE_KEY=0xac0974bec39a17e36ba4a6b4d238ff944bacb478cbed5efcae784d7bf4f2ff80 \
    ROUTER_ADDRESS=$(grep -o '0x[0-9a-fA-F]*' ../deployed-addresses.json) \
    NO_PROXY="*" HTTP_PROXY="" HTTPS_PROXY="" \
    forge script script/Upgrade.s.sol \
        --rpc-url http://127.0.0.1:8545 \
        --broadcast \
        -v
    echo ""
    echo "All implementations upgraded. Proxy addresses unchanged."

# -- Agent runner --

# Start agent runner
# Usage: just agent-start [config-file]
#   e.g.  just agent-start config/localhost.toml
#         just agent-start /abs/path/to/config.toml
[working-directory: "agent-runner"]
agent-start config="config/localhost.toml":
    npm run dev -- --config {{config}}

# -- MCP server --

# Start MCP server dev server
[working-directory: "mcp-server"]
mcp-start:
    npm run dev

# -- Keeper (arena matchmaking + settlement heartbeat) --

# Start the arena keeper against local Anvil (uses anvil dev key #0).
# RPC from frontend/config/localhost.json; router from deployed-addresses.json.
[working-directory: "mcp-server"]
keeper-start tick="15":
    NO_PROXY="127.0.0.1,localhost" HTTP_PROXY="" HTTPS_PROXY="" \
    NETWORK="localhost" \
    KEEPER_KEY="0xac0974bec39a17e36ba4a6b4d238ff944bacb478cbed5efcae784d7bf4f2ff80" \
    TICK_SECONDS={{tick}} \
    node scripts/keeper.mjs

# Start the arena keeper against Gravity Testnet.
# RPC + router are read from frontend/config/gravity.json — no addresses to pass.
# Usage: just keeper-gravity <keeper_private_key> [tick_seconds]
[working-directory: "mcp-server"]
keeper-gravity keeper_key tick="60":
    NETWORK="gravity" \
    KEEPER_KEY="{{keeper_key}}" \
    TICK_SECONDS={{tick}} \
    node scripts/keeper.mjs

# -- Frontend --

# Start frontend dev server
# Usage: just frontend-start [config] [port] [host]
#   e.g.  just frontend-start localhost
#         just frontend-start localhost 3001
[working-directory: "frontend"]
frontend-start config="localhost" port="3000" host="0.0.0.0":
    APP_CONFIG={{config}} npm run dev -- -H {{host}} -p {{port}}