cubos-jam-template/flake.nix at main · GameDevTecnico/cubos-jam-template · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
# Flake used for development with nix
{
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-24.11";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = inputs:
    inputs.flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import inputs.nixpkgs { inherit system; };
        pkgs-unstable = import inputs.nixpkgs-unstable { inherit system; };

        sysLibs = with pkgs; [
          libGL
          xorg.libX11
          xorg.libXrandr
          xorg.libXinerama
          xorg.libXcursor
          xorg.libXi
          xorg.libXdmcp
          libpulseaudio
        ];
      in
      {
        devShell = pkgs.mkShell {
          hardeningDisable = [ "all" ];

          packages = with pkgs;
            [
              # = build tools =
              cmake
              ccache
              pkg-config
              pkgs-unstable.emscripten
              ninja

              # = formatting =
              clang-tools

              # = docs =
              doxygen

              (python3.withPackages (ps: [
                ps.jinja2
                ps.pygments
              ]))

              # = libs =
              glfw
              glm
              doctest

              # = debug =
              gdb
            ]
            ++ sysLibs;

          shellHook = ''
            export EMSCRIPTEN=${pkgs-unstable.emscripten}/share/emscripten
            export EM_CACHE=$(git rev-parse --show-toplevel)/.em_cache
            mkdir -p $EM_CACHE
            cp -r $EMSCRIPTEN/cache/* $EM_CACHE
            chmod u+rwx -R $EM_CACHE

            if [ -n "$WAYLAND_DISPLAY" ]; then
              LD_LIBRARY_PATH="$LD_LIBRARY_PATH:$(nix-build '<nixpkgs>' -A wayland --no-out-link)/lib"
            fi
          '';

          LD_LIBRARY_PATH = "$LD_LIBRARY_PATH:${pkgs.lib.makeLibraryPath sysLibs}";
        };

        formatter = pkgs.alejandra;
      });
}