feat: account migration (#34)

* feat: migrator bot prototype

* feat: migrator bot can migrate between pools

* feat: migrator bot rc

* feat: separate account migrator preview logic

* fix: additional checks in migrator bot + custom pt deposits / withdrawals removed

* feat: account migration now more robustly validates transferred amounts

* fix: fix validation for 3.0 credit managers

* feat: migrator bot tests + fixes

* test: fix cursor artifacts in tests

* fix: fix metadata fields and compiler warnings

* fix: audit fixes

---------

Co-authored-by: Van0k <ivkamakin@gmail.com>

Author: lekhovitsky

contracts/interfaces/IAccountMigratorBot.sol

@@ -0,0 +1,34 @@
+// SPDX-License-Identifier: MIT
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2025.
+pragma solidity ^0.8.23;
+
+import {IVersion} from "@gearbox-protocol/core-v3/contracts/interfaces/base/IVersion.sol";
+import {IStateSerializer} from "@gearbox-protocol/core-v3/contracts/interfaces/base/IStateSerializer.sol";
+import {IBot} from "@gearbox-protocol/core-v3/contracts/interfaces/base/IBot.sol";
+import {IAdapter} from "@gearbox-protocol/core-v3/contracts/interfaces/base/IAdapter.sol";
+
+import {PriceUpdate} from "@gearbox-protocol/core-v3/contracts/interfaces/base/IPriceFeedStore.sol";
+import {MigrationParams, PreviewMigrationResult, PhantomTokenOverride} from "../types/AccountMigrationTypes.sol";
+
+interface IAccountMigratorPreviewer is IVersion, IStateSerializer {
+    function previewMigration(
+        address sourceCreditAccount,
+        address targetCreditManager,
+        PriceUpdate[] memory priceUpdates
+    ) external returns (PreviewMigrationResult memory result);
+}
+
+interface IAccountMigratorBot is IBot {
+    function migrateCreditAccount(MigrationParams memory params, PriceUpdate[] memory priceUpdates) external;
+
+    function migrate(MigrationParams memory params) external;
+
+    function phantomTokenOverrides(address phantomToken) external view returns (PhantomTokenOverride memory);
+}
+
+interface IAccountMigratorAdapter is IAdapter {
+    function unlock() external;
+    function lock() external;
+    function migrate(MigrationParams memory params) external;
+}

contracts/interfaces/external/IGearboxRouter.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: MIT
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2025.
+pragma solidity ^0.8.23;
+
+import {MultiCall} from "@gearbox-protocol/core-v3/contracts/interfaces/ICreditFacadeV3.sol";
+
+struct TokenData {
+    address token;
+    uint256 balance;
+    uint256 leftoverBalance;
+    uint256 numSplits;
+    bool claimRewards;
+}
+
+struct RouterResult {
+    uint256 amount;
+    uint256 minAmount;
+    MultiCall[] calls;
+}
+
+interface IGearboxRouter {
+    function routeOpenManyToOne(address creditManager, address target, uint256 slippage, TokenData[] calldata tData)
+        external
+        returns (RouterResult memory);
+}

contracts/migration/AccountMigratorAdapter.sol

@@ -0,0 +1,69 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2025.
+pragma solidity ^0.8.23;
+
+import {AbstractAdapter} from "@gearbox-protocol/integrations-v3/contracts/adapters/AbstractAdapter.sol";
+import {IAccountMigratorAdapter} from "../interfaces/IAccountMigratorBot.sol";
+import {MigrationParams, MigratedCollateral} from "../types/AccountMigrationTypes.sol";
+
+abstract contract AccountMigratorAdapter is AbstractAdapter {
+    /// @dev Whether tha adapter is locked. The adapter should only be interactable when unlocked from the migrator bot,
+    ///      as the `migrate` function is fairly dangerous.
+    bool public locked = true;
+
+    modifier onlyMigratorBot() {
+        if (msg.sender != targetContract) {
+            revert("MigratorAdapter: caller is not the migrator bot");
+        }
+        _;
+    }
+
+    modifier whenUnlocked() {
+        if (locked) {
+            revert("MigratorAdapter: adapter is locked");
+        }
+        _;
+    }
+
+    constructor(address _creditManager, address _migratorBot) AbstractAdapter(_creditManager, _migratorBot) {}
+
+    /// @dev Internal function to migrate collaterals to a new credit account
+    function _migrate(MigrationParams memory params) internal {
+        _approveTokens(params.migratedCollaterals, type(uint256).max);
+        _execute(msg.data);
+        _approveTokens(params.migratedCollaterals, 0);
+    }
+
+    function _approveTokens(MigratedCollateral[] memory tokens, uint256 amount) internal {
+        uint256 len = tokens.length;
+
+        for (uint256 i = 0; i < len; i++) {
+            address token = tokens[i].phantomTokenParams.isPhantomToken
+                ? tokens[i].phantomTokenParams.underlying
+                : tokens[i].collateral;
+            _approveToken(token, amount);
+        }
+    }
+
+    function lock() external onlyMigratorBot {
+        if (locked) {
+            revert("MigratorAdapter: adapter is already locked");
+        }
+
+        locked = true;
+    }
+
+    function unlock() external onlyMigratorBot {
+        if (!locked) {
+            revert("MigratorAdapter: adapter is not locked");
+        }
+
+        locked = false;
+    }
+
+    /// @notice Serialized adapter parameters
+    function serialize() external view returns (bytes memory serializedData) {
+        serializedData = abi.encode(creditManager, targetContract);
+    }
+}

contracts/migration/AccountMigratorAdapterV30.sol

@@ -0,0 +1,39 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2025.
+pragma solidity ^0.8.23;
+
+import {NotImplementedException} from "@gearbox-protocol/core-v3/contracts/interfaces/IExceptions.sol";
+import {AccountMigratorAdapter} from "./AccountMigratorAdapter.sol";
+import {MigrationParams} from "../types/AccountMigrationTypes.sol";
+
+contract AccountMigratorAdapterV30 is AccountMigratorAdapter {
+    /// @dev Legacy adapter type for compatibility with 3.0 contracts
+    uint8 public constant _gearboxAdapterType = 0;
+
+    /// @dev Legacy adapter version for compatibility with 3.0 contracts
+    uint16 public constant _gearboxAdapterVersion = 3_00;
+
+    constructor(address _creditManager, address _targetContract)
+        AccountMigratorAdapter(_creditManager, _targetContract)
+    {}
+
+    function contractType() external pure returns (bytes32) {
+        revert NotImplementedException();
+    }
+
+    function version() external pure returns (uint256) {
+        revert NotImplementedException();
+    }
+
+    /// @notice Migrates collaterals to a new credit account, using the migrator bot as a target contract.
+    function migrate(MigrationParams memory params)
+        external
+        whenUnlocked
+        creditFacadeOnly
+        returns (uint256 tokensToEnable, uint256 tokensToDisable)
+    {
+        _migrate(params);
+        return (0, type(uint256).max);
+    }
+}

contracts/migration/AccountMigratorAdapterV31.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: GPL-2.0-or-later
+// Gearbox Protocol. Generalized leverage for DeFi protocols
+// (c) Gearbox Foundation, 2025.
+pragma solidity ^0.8.23;
+
+import {AccountMigratorAdapter} from "./AccountMigratorAdapter.sol";
+
+import {MigrationParams} from "../types/AccountMigrationTypes.sol";
+
+contract AccountMigratorAdapterV31 is AccountMigratorAdapter {
+    bytes32 public constant override contractType = "ADAPTER::ACCOUNT_MIGRATOR";
+    uint256 public constant override version = 3_10;
+
+    constructor(address _creditManager, address _targetContract)
+        AccountMigratorAdapter(_creditManager, _targetContract)
+    {}
+
+    /// @notice Migrates collaterals to a new credit account, using the migrator bot as a target contract.
+    function migrate(MigrationParams memory params) external whenUnlocked creditFacadeOnly returns (bool) {
+        _migrate(params);
+        return false;
+    }
+}