VTF: Add support RGBA, ABGR, I, IA formats

Author: H2xDev

addons/godotvmf/godotvmt/formats/vtf_dxt.gd

@@ -0,0 +1,33 @@
+class_name VTFDXT extends VTFFrameReader
+
+static func read(vtf: VTFLoader, frame: int, srgb_conversion_method: VTFLoader.SRGBConversionMethod) -> ImageTexture:
+	var data = PackedByteArray();
+	var bytes_read := 0;
+	var is_dxt_1 := vtf.hires_image_format == vtf.ImageFormat.DXT1;
+	var multiplier = 8 if is_dxt_1 else 16;
+	var format := vtf.format_map[str(vtf.hires_image_format)] as Image.Format;
+	var use_mipmaps := not (vtf.flags & vtf.Flags.TEXTUREFLAGS_NOMIP);
+
+	frame = vtf.frames - 1 - frame;
+
+	for i in range(vtf.mipmap_count):
+		var mipWidth = max(1, vtf.width >> i);
+		var mipHeight = max(1, vtf.height >> i);
+
+		var mip_size = max(1, mipWidth / 4) * max(1, mipHeight / 4) * multiplier;
+
+		vtf.file.seek(vtf.file.get_length() - bytes_read - mip_size - mip_size * frame);
+		data += vtf.file.get_buffer(mip_size);
+
+		bytes_read += mip_size + mip_size * (vtf.frames - 1);
+
+	var img := Image.create_from_data(vtf.width, vtf.height, use_mipmaps, format, data);
+	if not img: return null;
+	
+	if srgb_conversion_method == vtf.SRGBConversionMethod.DURING_IMPORT:
+		img.decompress();
+		img.compress(Image.COMPRESS_S3TC);
+
+	vtf.alpha = vtf.flags & vtf.Flags.TEXTUREFLAGS_ONEBITALPHA or vtf.flags & vtf.Flags.TEXTUREFLAGS_EIGHTBITALPHA;
+
+	return ImageTexture.create_from_image(img);

addons/godotvmf/godotvmt/formats/vtf_frame_reader.gd

@@ -0,0 +1,6 @@
+class_name VTFFrameReader extends RefCounted
+
+
+## Base class for reading frames from a VTF file. Each image format should have its own implementation of this class.
+static func read(vtf: VTFLoader, frame: int, srgb_conversion_method: VTFLoader.SRGBConversionMethod) -> ImageTexture:
+	return null;

addons/godotvmf/godotvmt/formats/vtf_i8.gd

@@ -0,0 +1,27 @@
+class_name VTFI8 extends VTFFrameReader
+
+static func read(vtf: VTFLoader, frame: int, srgb_conversion_method: VTFLoader.SRGBConversionMethod) -> ImageTexture:
+	var data := PackedByteArray(); 
+	var bytes_read := 0;
+	var use_mipmaps := not (vtf.flags & vtf.Flags.TEXTUREFLAGS_NOMIP);
+	var multiplier := 1 if vtf.hires_image_format == vtf.ImageFormat.I8 else 2;
+	var output_format := Image.FORMAT_L8 if vtf.hires_image_format == vtf.ImageFormat.I8 else Image.FORMAT_LA8;
+	
+	frame = vtf.frames - 1 - frame;
+
+	for i in range(vtf.mipmap_count):
+		var mip_width = max(1, vtf.width >> i);
+		var mip_height = max(1, vtf.height >> i);
+		var mip_size = mip_width * mip_height * multiplier; # I8 has 1 byte per pixel
+
+		vtf.file.seek(vtf.file.get_length() - bytes_read - mip_size - mip_size * frame);
+		var chunk := vtf.file.get_buffer(mip_size);
+
+		data += chunk;
+		bytes_read += mip_size + mip_size * (vtf.frames - 1);
+
+	var img := Image.create_from_data(vtf.width, vtf.height, use_mipmaps, output_format, data);
+
+	if not img: return null;
+
+	return ImageTexture.create_from_image(img);

addons/godotvmf/godotvmt/formats/vtf_rgba.gd

@@ -0,0 +1,36 @@
+class_name VTFRGBA extends VTFFrameReader
+
+static func read(vtf: VTFLoader, frame: int, srgb_conversion_method: VTFLoader.SRGBConversionMethod) -> ImageTexture:
+	var data := PackedByteArray(); 
+	var bytes_read := 0;
+	var use_mipmaps := not (vtf.flags & vtf.Flags.TEXTUREFLAGS_NOMIP);
+	var is_abgr := vtf.hires_image_format == vtf.ImageFormat.ABGR8888 || vtf.hires_image_format == vtf.ImageFormat.BGR888;
+	var is_no_alpha := vtf.hires_image_format >= vtf.ImageFormat.RGB888;
+	var channels_count := 3 if is_no_alpha else 4;
+	var output_format := Image.FORMAT_RGB8 if is_no_alpha else Image.FORMAT_RGBA8;
+
+
+	frame = vtf.frames - 1 - frame;
+
+	for i in range(vtf.mipmap_count):
+		var mip_width = max(1, vtf.width >> i);
+		var mip_height = max(1, vtf.height >> i);
+		var mip_size = mip_width * mip_height * channels_count; # RGBA8888 has 4 bytes per pixel
+
+		vtf.file.seek(vtf.file.get_length() - bytes_read - mip_size - mip_size * frame);
+		var chunk := vtf.file.get_buffer(mip_size);
+
+		if is_abgr: chunk.reverse();
+
+		data += chunk;
+		bytes_read += mip_size + mip_size * (vtf.frames - 1);
+
+	var img := Image.create_from_data(vtf.width, vtf.height, use_mipmaps, output_format, data);
+
+	if is_abgr:
+		img.flip_x();
+		img.flip_y();
+
+	if not img: return null;
+
+	return ImageTexture.create_from_image(img);