informative-annotations/build.gradle.kts at fdc64811099ac3028c5b2948b8e35fc9723b15bd · IntellectualSites/informative-annotations · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
import java.net.URI
import com.diffplug.gradle.spotless.SpotlessPlugin
import com.vanniktech.maven.publish.SonatypeHost

plugins {
    java
    `java-library`
    signing

    id("com.diffplug.spotless") version "8.9.0"
    id("com.vanniktech.maven.publish") version "0.37.0"

    idea
    eclipse
}

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(17))
}

version = "1.7-SNAPSHOT"
group = "com.intellectualsites.informative-annotations"

repositories {
    mavenCentral()
}

spotless {
    java {
        licenseHeaderFile(rootProject.file("LICENSE"))
        target("**/*.java")
    }
}

tasks {

    javadoc {
        val opt = options as StandardJavadocDocletOptions
        opt.noTimestamp()
    }

    withType<AbstractArchiveTask>().configureEach {
        isPreserveFileTimestamps = false
        isReproducibleFileOrder = true
    }
}

signing {
    if (!project.hasProperty("skip.signing") && !version.toString().endsWith("-SNAPSHOT")) {
        val signingKey: String? by project
        val signingPassword: String? by project
        useInMemoryPgpKeys(signingKey, signingPassword)
        signing.isRequired
        sign(publishing.publications)
    }
}

mavenPublishing {

    coordinates(
        groupId = "$group",
        artifactId = project.name,
        version = "${project.version}",
    )

    pom {
        name.set(project.name)
        description.set("An informative annotation library.")
        url.set("https://github.com/IntellectualSites/informative-annotations")

        licenses {
            license {
                name.set("The MIT License")
                url.set("https://opensource.org/licenses/MIT")
                distribution.set("repo")
            }
        }

        developers {
            developer {
                id.set("NotMyFault")
                name.set("Alexander Brandes")
                organization.set("IntellectualSites")
                organizationUrl.set("https://github.com/IntellectualSites/")
                email.set("contact(at)notmyfault.dev")
            }
        }

        scm {
            url.set("https://github.com/IntellectualSites/informative-annotations")
            connection.set("scm:git:https://github.com/IntellectualSites/informative-annotations.git")
            developerConnection.set("scm:git:git@github.com:IntellectualSites/informative-annotations.git")
            tag.set("${project.version}")
        }

        issueManagement {
            system.set("GitHub")
            url.set("https://github.com/IntellectualSites/informative-annotations/issues")
        }

        publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)
    }
}