feat: nix packaging

Author: fxzzi

.gitignore

@@ -1,3 +1,5 @@
 /target
 **/*.rs.bk
 .vscode
+# nix build artifacts
+result/

flake.lock

@@ -0,0 +1,22 @@
+{
+  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+
+  outputs = {
+    self,
+    nixpkgs,
+  }: let
+    systems = ["x86_64-linux" "aarch64-linux"];
+    forEachSystem = nixpkgs.lib.genAttrs systems;
+    pkgsForEach = nixpkgs.legacyPackages;
+  in {
+    packages = forEachSystem (system: {
+      default = pkgsForEach.${system}.callPackage ./nix/package.nix {};
+    });
+
+    devShells = forEachSystem (system: {
+      default = pkgsForEach.${system}.callPackage ./nix/shell.nix {};
+    });
+
+    hydraJobs = self.packages;
+  };
+}

flake.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  rustPlatform,
+  pkg-config,
+  openssl,
+}: let
+  fs = lib.fileset;
+in
+  rustPlatform.buildRustPackage (finalAttrs: {
+    pname = "mpd-discord-rpc";
+    version = (builtins.fromTOML (builtins.readFile ../Cargo.toml)).package.version;
+
+    src = fs.toSource {
+      root = ../.;
+      fileset = fs.unions [
+        (fs.fileFilter (file: builtins.any file.hasExt ["rs"]) ../src)
+        ../Cargo.lock
+        ../Cargo.toml
+      ];
+    };
+
+    nativeBuildInputs = [pkg-config];
+    buildInputs = [openssl];
+
+    cargoLock.lockFile = "${finalAttrs.src}/Cargo.lock";
+    enableParallelBuilding = true;
+
+    meta = {
+      description = "Displays your currently playing song / album / artist from MPD in Discord";
+      homepage = "https://github.com/JakeStanger/mpd-discord-rpc";
+      license = lib.licenses.mit;
+      platforms = lib.platforms.linux;
+      maintainers = with lib.maintainers; [
+        JakeStanger
+        fazzi
+      ];
+      mainProgram = "mpd-discord-rpc";
+    };
+  })

nix/package.nix

@@ -0,0 +1,21 @@
+{
+  mkShell,
+  rust-analyzer,
+  rustfmt,
+  rustc,
+  clippy,
+  cargo,
+  rustPlatform,
+}:
+mkShell {
+  name = "rust";
+  packages = [
+    rust-analyzer
+    rustfmt
+    clippy
+    cargo
+    rustc
+  ];
+
+  RUST_SRC_PATH = "${rustPlatform.rustLibSrc}";
+}