Add StructArrays support (#3)

This requires more modern versions of Julia, support just 1.6+.

Author: timholy

.github/workflows/CI.yml

@@ -18,8 +18,8 @@ jobs:
       fail-fast: false
       matrix:
         version:
-          - '1.0'
           - '1.6'
+          - '1'
           - 'nightly'
         os:
           - ubuntu-latest

Project.toml

@@ -10,6 +10,7 @@ Colors = "5ae59095-9a9b-59fe-a467-6f913c188581"
 Compat = "34da2185-b29b-5c13-b0c7-acf172513d20"
 FixedPointNumbers = "53c48c17-4a7d-5ca2-90c5-79b7896eea93"
 Reexport = "189a3867-3050-52da-a836-e630ba90ab69"
+Requires = "ae029012-a4dd-5104-9daa-d747884805df"
 
 [compat]
 ColorTypes = "0.11"
@@ -18,10 +19,12 @@ Colors = "0.12"
 Compat = "3.36"
 FixedPointNumbers = "0.8"
 Reexport = "1"
-julia = "1"
+Requires = "1"
+julia = "1.6"
 
 [extras]
+StructArrays = "09ab397b-f2b6-538f-b94a-2f83cf4a842a"
 Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
 
 [targets]
-test = ["Test"]
+test = ["StructArrays", "Test"]

src/FluorophoreColors.jl

@@ -7,10 +7,16 @@ using Reexport
 @reexport using ColorTypes
 using Colors
 using ColorVectorSpace
+using Requires
 
 export fluorophore_rgb, @fluorophore_rgb_str, ColorMixture
 
 include("types.jl")
 include("fluorophores.jl")
+include("utils.jl")
+
+function __init__()
+    @require StructArrays = "09ab397b-f2b6-538f-b94a-2f83cf4a842a" include("structarrays.jl")
+end
 
 end

src/structarrays.jl

@@ -0,0 +1,31 @@
+channelname(N::Int, i::Int) = Symbol("channel" * lpad(string(i), ndigits(N), '0'))
+
+function StructArrays.staticschema(::Type{ColorMixture{T,N,Cs}}) where {T, N, Cs}
+    # Define the desired names and eltypes of the "fields"
+    names = ntuple(i -> channelname(N, i), N)
+    types = Tuple{ntuple(i -> T, N)...}
+    return NamedTuple{names, types}
+end
+
+# Extract components
+@noinline throw_channelerror(key::Symbol) = error("channel $key not available")
+StructArrays.component(c::ColorMixture{T,1}, key::Symbol) where T = key == :channel1 ? c.channels[1] : throw_channelerror(key)
+StructArrays.component(c::ColorMixture{T,2}, key::Symbol) where T = key == :channel1 ? c.channels[1] :
+                                                                    key == :channel2 ? c.channels[2] : throw_channelerror(key)
+StructArrays.component(c::ColorMixture{T,3}, key::Symbol) where T = key == :channel1 ? c.channels[1] :
+                                                                    key == :channel2 ? c.channels[2] :
+                                                                    key == :channel3 ? c.channels[3] : throw_channelerror(key)
+
+@generated function StructArrays.component(c::ColorMixture{T,N}, key::Symbol) where {T,N}
+    ex0 = ex = Expr(:if, :(key == $(QuoteNode(channelname(N, 1)))), :(return c.channels[1]))
+    for i = 2:N
+        push!(ex.args, Expr(:elseif, :(key == $(QuoteNode(channelname(N, i)))), :(return c.channels[$i])))
+        ex = ex.args[end]
+    end
+    push!(ex.args, :(throw_channelerror(key)))
+    return ex0
+end
+
+function StructArrays.createinstance(::Type{ColorMixture{T,N,Cs}}, args...) where {T, N, Cs}
+    return ColorMixture{T,N,Cs}(args)
+end

src/types.jl

@@ -4,8 +4,6 @@
 # Making the main representation by RGB means we can do the latter efficiently without requiring
 # world-age violations.
 
-const subscript = ('₁', '₂', '₃', '₄', '₅', '₆', '₇', '₈', '₉')
-
 """
     ColorMixture((rgb₁, rgb₂), (i₁, i₂))          # store intensities
     ColorMixture{T}((rgb₁, rgb₂), (i₁, i₂))       # same, but coerce to element type T for colors and intensities
@@ -99,7 +97,8 @@ function Base.show(io::IO, c::ColorMixture)
     print(io, '(')
     for (j, intensity) in enumerate(c.channels)
         j > 1 && print(io, ", ")
-        print(io, intensity, subscript[j])
+        print(io, intensity)
+        print_subscript(io, length(c), j)
     end
     print(io, ')')
 end

src/utils.jl

@@ -0,0 +1,13 @@
+const subscripts = ('₀', '₁', '₂', '₃', '₄', '₅', '₆', '₇', '₈', '₉')
+function print_subscript(io::IO, N::Int, i::Int)
+    nd = ndigits(N)
+    base = 10^(nd-1)
+    while nd > 1
+        id, i = divrem(i, base)
+        print(io, subscripts[id+1])
+        nd -= 1
+        base ÷= 10
+    end
+    print(io, subscripts[i+1])
+    return nothing
+end

test/runtests.jl

@@ -1,6 +1,9 @@
 using FluorophoreColors
 using Test
 
+# interacts via @require
+using StructArrays
+
 @testset "FluorophoreColors.jl" begin
     @test isempty(detect_ambiguities(FluorophoreColors))
 
@@ -27,6 +30,7 @@ using Test
         @test c.channels[1] == c.channels[2] == 0.5
         @test convert(RGB, c) ≈ 0.5*channels[1] + 0.5*channels[2]
 
+        # Macro syntax & inferrability
         f_infer(i1, i2) = ColorMixture{N0f8}((fluorophore_rgb"EGFP", fluorophore_rgb"tdTomato"), (i1, i2))
         f_noinfer(i1, i2) = ColorMixture((fluorophore_rgb["EGFP"], fluorophore_rgb["tdTomato"]), (i1, i2))
         @test f_infer(1, 0) == f_noinfer(1, 0)
@@ -38,13 +42,45 @@ using Test
         f_infer16(i1, i2) = ColorMixture{N0f16}((fluorophore_rgb"EGFP", fluorophore_rgb"tdTomato"), (i1, i2))
         @test_broken @inferred f_infer16(1, 0)
 
+        # Inferrability from a template
         ctmpl = ColorMixture(channels)
         @test @inferred(ctmpl(1, 0)) === ColorMixture{N0f8}(channels, (1, 0))
     end
 
+    @testset "StructArrays" begin
+        channels = (fluorophore_rgb["EGFP"], fluorophore_rgb["tdTomato"])
+        ctemplate = ColorMixture(channels)
+        green, red = N0f8[0.2, 0.4], N0f8[0.8, 0.6]
+        soa = StructArray{typeof(ctemplate)}((green, red))
+        @test soa[1] === ctemplate(green[1], red[1])
+        @test soa[2] === ctemplate(green[2], red[2])
+        soa[1] = ctemplate((0.5, 0.0))
+        @test green[1] === 0.5N0f8
+        @test red[1] === 0.0N0f8
+
+        # Hyperspectral
+        cols = FluorophoreColors.Colors.distinguishable_colors(16, [RGB(0,0,0)]; dropseed=true)
+        ctemplate = ColorMixture{Float32}((cols...,))
+        comps = collect(reshape((0:31)/32f0, 16, 2))
+        compsr = reinterpret(reshape, typeof(ctemplate), comps)
+        soa = StructArray{typeof(ctemplate)}(comps; dims=1)
+        @test soa == compsr
+        @test size(soa) == (2,)
+        @test soa[1] == ctemplate(ntuple(i->(i-1)/32, 16))
+        compst = collect(transpose(comps))
+        soa = StructArray{typeof(ctemplate)}(compst; dims=2)
+        @test soa[1] == ctemplate(ntuple(i->(i-1)/32, 16))
+    end
+
     @testset "IO" begin
         channels = (fluorophore_rgb["EGFP"], fluorophore_rgb["tdTomato"])
         c = ColorMixture(channels, (1, 0))
         @test sprint(show, c) == "(1.0₁, 0.0₂)"
+
+        # Hyperspectral
+        cols = FluorophoreColors.Colors.distinguishable_colors(16, [RGB(0,0,0)]; dropseed=true)
+        ctemplate = ColorMixture{Float32}((cols...,))
+        c = ctemplate([i/16 for i = 0:15]...)
+        @test sprint(show, c) == "(0.0₀₁, 0.0625₀₂, 0.125₀₃, 0.1875₀₄, 0.25₀₅, 0.3125₀₆, 0.375₀₇, 0.4375₀₈, 0.5₀₉, 0.5625₁₀, 0.625₁₁, 0.6875₁₂, 0.75₁₃, 0.8125₁₄, 0.875₁₅, 0.9375₁₆)"
     end
 end