false positive unbound type parameter in constructor

[tpapp]

MWE

module Foo

using StaticArrays

struct Tangent{T}
    location::T
    slope::T
end

struct ScaledProblem{N,TA<:Real,TE<:Real}
    a::SVector{N,TA}
    ϵ::SVector{N,TE}
end

Base.@kwdef struct PrecalculatedProblem{N,M,TA<:Real,TE<:Real,TT<:Real}
    P::ScaledProblem{N,TA,TE}
    tangents::NTuple{M,Tangent{TT}}
end

end

using Aqua
Aqua.test_unbound_args(Foo)

error

Unbound type parameters detected:
[1] Main.Foo.PrecalculatedProblem(P::Main.Foo.ScaledProblem{N, TA, TE}, tangents::NTuple{M, Main.Foo.Tangent{TT}}) where {N, M, TA<:Real, TE<:Real, TT<:Real} @ Main.Foo /tmp/tmp.jl:16
Test Failed at /home/tamas/.julia/packages/Aqua/epbUr/src/unbound_args.jl:37
  Expression: isempty(unbounds)
   Evaluated: isempty(Method[Main.Foo.PrecalculatedProblem(P::Main.Foo.ScaledProblem{N, TA, TE}, tangents::NTuple{M, Main.Foo.Tangent{TT}}) where {N, M, TA<:Real, TE<:Real, TT<:Real} @ Main.Foo /tmp/tmp.jl:16])

versions

Status `~/code/julia/NonhomotheticCES/test/Project.toml`
  [4c88cf16] Aqua v0.8.11
  [90137ffa] StaticArrays v1.9.12

julia> VERSION
v"1.11.3"

[lgoettgens]

This is acutally not a false behavior on Aqua's side here.
If you call PrecalculatedProblem with some ScaledProblem{N, TA, TE} and tangents=() (an empty NTuple), then TT is not specified.

[tpapp]

Thanks for the explanation, this makes sense and indeed it is not an Aqua issue so I am closing.

(if anyone runs into this while searching, I also found that I can refactor as

Base.@kwdef struct PrecalculatedProblem{N,M,TA<:Real,TE<:Real,TT<:NTuple{M}}
    P::ScaledProblem{N,TA,TE}
    tangents::TT
end

and this avoid the ambiguity yet keep the M as a type parameter.)