build.gradle

import java.text.SimpleDateFormat

buildscript {
    repositories {
        // These repositories are only for Gradle plugins, put any other repositories in the repository block further below
        maven { url = 'https://maven.minecraftforge.net'}
        maven { url = 'https://maven.parchmentmc.org' }
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath 'org.parchmentmc:librarian:1.+'
        classpath "org.spongepowered:mixingradle:${mixingradle_version}"
    }
}
// Only edit below this line, the above code adds and enables the necessary things for Forge to be setup.
plugins {
    id 'eclipse'
    id 'maven-publish'
    // id 'com.github.johnrengelman.shadow' version '7.1.+'
    id("com.github.johnrengelman.shadow")
}
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'org.parchmentmc.librarian.forgegradle'
apply plugin: 'org.spongepowered.mixin'

configurations {
    shadedLib
    macOSDependency
    commonDependency
}

Properties localProperties = new Properties()
File localPropertiesFile = rootProject.file('local.properties')
if (localPropertiesFile.exists()) {
    localPropertiesFile.withInputStream { stream ->
        localProperties.load(stream)
    }
}

channel = localProperties.getProperty("channel") ?: channel
snapshot_serial = localProperties.getProperty("snapshot_serial") ?: snapshot_serial
internal_code = localProperties.getProperty("internal_code") ?: internal_code

def mod_full_version
def repository_channel = "releases"
def repository_version = "${minecraft_version}"
version = "${minecraft_version}-${mod_version}"

if(type == "create") {
    version = "${version}-create"
    repository_version = "${repository_version}-create"
}

def pomEntries = project.objects.mapProperty(String, String)

switch (channel) {
    case "nightly":
        repository_channel = "nightly"
        if(!project.findProperty("git_version"))
            throw new GradleException("You must specify the git_version property by using -Pgit_version=..... for nightly builds.")
        version = "${version}-nightly-${project.property("git_version")}+" + (new SimpleDateFormat("yyMMddHHmm").format(new Date()))
        pomEntries.put("git_version", project.findProperty("git_version_full") ?: project.property("git_version"))
        break;
    case "alpha":
    case "beta":
    case "rc":
        repository_channel = "snapshots"
        if(!project.findProperty("snapshot_serial"))
            throw new GradleException("You must specify the snapshot serial in gradle.properties!")
        version = "${version}-${channel}.${snapshot_serial}"
        break;
    case "internal":
        repository_channel = "internals"
        if(!project.findProperty("internal_code"))
            throw new GradleException("You must specify the internal code in gradle.properties!")
        version = "${version}-internal-${internal_code}-" + (new SimpleDateFormat("yyMMddHHmmss").format(new Date()))
        break;
    case "release":
        break;
    default:
        throw new GradleException("Unknown channel: ${channel}. Please use one of the following channels: nightly, alpha, beta, rc, internal, release.");
}

pomEntries.put("channel", channel)

pomEntries.put("builder_name", project.findProperty("builder_name") ?: "unknown");

def ci_type = project.findProperty("ci_type")

def ci_url = project.findProperty("ci_url")

System.out.println("Building KasugaLib for channel: ${repository_channel}, version: ${version} (${minecraft_version})")
mod_full_version = version


group = 'kasuga.lib' // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = 'kasuga_lib'

// Mojang ships Java 17 to end users in 1.18+, so your mod should target Java 17.
java.toolchain.languageVersion = JavaLanguageVersion.of(17)

jarJar.enable();

tasks.named('jarJar') {
    archiveClassifier.set('jarjar');
}

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"
minecraft {

    mappings channel: 'parchment', version: '2022.09.18-1.19.2'
    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg') // Currently, this location cannot be changed from the default.

    runs {
        client {
            workingDirectory project.file('run')
            arg '-mixin.config=kasuga.mixins.json'
            // Recommended logging data for a userdev environment
            // The markers can be added/remove as needed separated by commas.
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            property 'forge.logging.markers', 'REGISTRIES'

            // Recommended logging level for the console
            // You can set various levels here.
            // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
            property 'forge.logging.console.level', 'debug'

            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            property 'forge.enabledGameTestNamespaces', 'kasuga_lib'
            property 'mixin.env.remapRefMap', 'true'
            property 'mixin.env.refMapRemappingFile', "${buildDir}/createSrgToMcp/output.srg"
            mods {
                kasuga_lib {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'

            property 'forge.logging.console.level', 'debug'
            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            property 'forge.enabledGameTestNamespaces', 'kasuga_lib'
            property 'mixin.env.remapRefMap', 'true'
            property 'mixin.env.refMapRemappingFile', "${buildDir}/createSrgToMcp/output.srg"
            mods {
                kasuga_lib {
                    source sourceSets.main
                }
            }
        }

        // This run config launches GameTestServer and runs all registered gametests, then exits.
        // By default, the server will crash when no gametests are provided.
        // The gametest system is also enabled by default for other run configs under the /test command.
        gameTestServer {
            workingDirectory project.file('run')

            // Recommended logging data for a userdev environment
            // The markers can be added/remove as needed separated by commas.
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            property 'forge.logging.markers', 'REGISTRIES'

            // Recommended logging level for the console
            // You can set various levels here.
            // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
            property 'forge.logging.console.level', 'debug'

            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            property 'forge.enabledGameTestNamespaces', 'kasuga_lib'

            property 'mixin.env.remapRefMap', 'true'
            property 'mixin.env.refMapRemappingFile', "${buildDir}/createSrgToMcp/output.srg"
            mods {
                kasuga_lib {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'

            property 'forge.logging.console.level', 'debug'

            // Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
            args '--mod', 'kasuga_lib', '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')

            mods {
                kasuga_lib {
                    source sourceSets.main
                }
            }
        }
    }
}

// Include resources generated by data generators.
sourceSets.main.resources {
    srcDir 'src/generated/resources'
    exclude '.cache'
}

repositories {
    // Put repositories for dependencies here
    // ForgeGradle automatically adds the Forge maven and Maven Central for you

    // If you have mod jar dependencies in ./libs, you can declare them as a repository like so:
    // flatDir {
    //     dir 'libs'
    // }
    mavenCentral()
    maven {
        name = 'tterrag maven'
        url = 'https://maven.tterrag.com/'
    }
//    maven {
//        // location of the maven that hosts JEI files
//        name = "Progwml6 maven"
//        url = "https://dvs1.progwml6.com/files/maven/"
//    }
    maven {
        // location of a maven mirror for JEI files, as a fallback
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
    maven {
        url = "https://maven.theillusivec4.top/"
    }
    maven {
         url "https://cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
    maven {
        name = 'mali'
        url = "https://raw.github.com/MegumiKasuga/kasuga-maven/mali_1.1.0/"
    }

    mavenLocal()
    flatDir {
        dir('libs')
    }
}

dependencies {
    // Specify the version of Minecraft to use. If this is any group other than 'net.minecraft', it is assumed
    // that the dep is a ForgeGradle 'patcher' dependency, and its patches will be applied.
    // The userdev artifact is a special name and will get all sorts of transformations applied to it.
    minecraft 'net.minecraftforge:forge:1.19.2-43.3.2'
    // implementation fg.deobf("com.simibubi.create:create-${create_minecraft_version}:${create_version}:slim") { transitive = false }
    // implementation fg.deobf("com.jozufozu.flywheel:flywheel-forge-${flywheel_minecraft_version}:${flywheel_version}")
    implementation fg.deobf("com.tterrag.registrate:Registrate:${registrate_version}")
    //implementation fg.deobf("curse.maven:create-steam-n-rails-688231:4726383")

    compileOnly fg.deobf("mezz.jei:jei-${jei_minecraft_version}-common-api:${jei_version}")
    compileOnly fg.deobf("mezz.jei:jei-${jei_minecraft_version}-forge-api:${jei_version}")
    runtimeOnly fg.deobf("mezz.jei:jei-${jei_minecraft_version}-forge:${jei_version}")

    implementation fg.deobf("curse.maven:worldedit-225608:3922622")
    implementation fg.deobf("curse.maven:oculus-581495:6020961")

    implementation "org.spongepowered:mixin:${mixin_version}"
    annotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"
    testAnnotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"

    implementation "org.projectlombok:lombok:1.18.34"
    annotationProcessor "org.projectlombok:lombok:1.18.34"

    // implementation files('libs/Mixed-Arithmetic-Logic-Interpreter-1.0.0.jar')

    minecraftLibrary ('org.lwjgl:lwjgl-yoga:3.3.1') {
        exclude group: 'org.lwjgl',module: 'lwjgl'
    };
    shadedLib('org.lwjgl:lwjgl-yoga:3.3.1'){
        exclude group: 'org.lwjgl',module: 'lwjgl'
    };

    implementation('io.netty:netty-codec-http:4.1.77.Final');

    minecraftLibrary ('io.netty:netty-codec-http:4.1.77.Final'){
        exclude group: 'io.netty', module:'netty-handler';
        exclude group: 'io.netty', module:'netty-handler-proxy';
        exclude group: 'io.netty', module:'netty-codec';
        exclude group: 'io.netty', module:'netty-transport';
        exclude group: 'io.netty', module:'netty-buffer';
        exclude group: 'io.netty', module:'netty-resolver';
        exclude group: 'io.netty', module:'netty-common';
    }

    shadedLib ('io.netty:netty-codec-http:4.1.77.Final'){
        exclude group: 'io.netty', module:'netty-handler';
        exclude group: 'io.netty', module:'netty-handler-proxy';
        exclude group: 'io.netty', module:'netty-codec';
        exclude group: 'io.netty', module:'netty-transport';
        exclude group: 'io.netty', module:'netty-buffer';
        exclude group: 'io.netty', module:'netty-resolver';
        exclude group: 'io.netty', module:'netty-common';
    }

    minecraftLibrary ("edu.carole:Mixed-Arithmetic-Logic-Interpreter:1.1.0") {
        exclude group: 'com.google.guava', module: 'guava';
        exclude group: 'com.google.code.gson', module: 'gson';
    }
    shadedLib(group: "edu.carole", name: "Mixed-Arithmetic-Logic-Interpreter", version: "[1.0.0, 2.0.0)") {
        exclude group: 'com.google.guava', module: 'guava';
        exclude group: 'com.google.code.gson', module: 'gson';
    }

    // shadedLib("org.graalvm.polyglot:js-community:23.1.0");
    // implementation("org.graalvm.sdk:graal-sdk:22.0.2");
    minecraftLibrary 'com.caoccao.javet:javet-core:4.0.0' // Must-have
    minecraftLibrary 'com.caoccao.javet:javet-v8-linux-arm64:4.0.0'
    minecraftLibrary 'com.caoccao.javet:javet-v8-linux-x86_64:4.0.0'
    minecraftLibrary 'com.caoccao.javet:javet-v8-macos-arm64:4.0.0'
    minecraftLibrary 'com.caoccao.javet:javet-v8-macos-x86_64:4.0.0'
    minecraftLibrary 'com.caoccao.javet:javet-v8-windows-x86_64:4.0.0'

    shadedLib 'com.caoccao.javet:javet-core:4.0.0' // Must-have


    // commonDependency 'com.caoccao.javet:javet-v8-linux-arm64:4.0.0'
    // commonDependency 'com.caoccao.javet:javet-v8-linux-x86_64:4.0.0'
    // commonDependency 'com.caoccao.javet:javet-v8-windows-x86_64:4.0.0'
    // macOSDependency 'com.caoccao.javet:javet-v8-macos-arm64:4.0.0'
    // macOSDependency 'com.caoccao.javet:javet-v8-macos-x86_64:4.0.0'
    /*
    if ( !javetLibraryExcluding || javetLibraryExcluding == "false" ){
        if( compileTarget == 'macos') {
            System.out.println("Building for MacOS")
        } else {
            System.out.println("Building for Windows & Linux")
             // Currently, we only support Win x86-64 structure in main build
        }
    }*/

    shadedLib 'org.apache.httpcomponents:httpcore:4.4.14'
    shadedLib 'org.apache.httpcomponents:httpclient:4.5.13'


    // testImplementation "edu.carole:Mixed-Arithmetic-Logic-Interpreter:1.0.0"
    // clientAnnotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"
    // apiAnnotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"
    // Real mod deobf dependency examples - these get remapped to your current mappings
    // compileOnly fg.deobf("mezz.jei:jei-${minecraft_version}:${jei_version}:api") // Adds JEI API as a compile dependency
    // runtimeOnly fg.deobf("mezz.jei:jei-${minecraft_version}:${jei_version}") // Adds the full JEI mod as a runtime dependency
    // implementation fg.deobf("com.tterrag.registrate:Registrate:MC${minecraft_version}-${registrate_version}") // Adds registrate as a dependency
    // minecraftLibrary "edu.carole:Mixed-Arithmetic-Logic-Interpreter:1.0.2"
    // shadedLib (group: "edu.carole", name: "Mixed-Arithmetic-Logic-Interpreter", version: "[1.0.0, 2.0.0)")
    // Examples using mod jars from ./libs
    // implementation fg.deobf("blank:coolmod-${minecraft_version}:${coolmod_version}")
    minecraftLibrary("io.javalin:javalin:6.6.0"){
        exclude group: 'org.jetbrains', module:'annotations'
        exclude group: 'j2objc', module: 'annotations'
        exclude group: 'org.slf4j'
        transitive = true
    }

    shadedLib("io.javalin:javalin:6.6.0"){
        exclude group: 'org.slf4j';
    }

    minecraftLibrary 'com.fasterxml.jackson.core:jackson-databind:2.13.2'

    // For more info...
    // http://www.gradle.org/docs/current/userguide/artifact_dependencies_tutorial.html
    // http://www.gradle.org/docs/current/userguide/dependency_management.html
}

// Example for how to get properties into the manifest for reading at runtime.
jar {
    archiveClassifier = 'slim'
    manifest {
        attributes([
                "Specification-Title"     : "kasuga_lib",
                "Specification-Vendor"    : "MegumiKasuga",
                "Specification-Version"   : "20", // We are version 18 of ourselves
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : version,
                "Implementation-Vendor"   : "MegumiKasuga",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'MixinConfigs': 'kasuga.mixins.json'
        ])
    }
}

// Example configuration to allow publishing using the maven-publish plugin
jar.finalizedBy('reobfShadowJar')


shadowJar{
    mergeServiceFiles() // To fix graal issue: https://github.com/oracle/graaljs/issues/125
    configurations = [project.configurations.shadedLib]
    archiveClassifier.set('');
    relocate 'org.graalvm', 'kasuga.lib.vendor_modules.org.graalvm'
    relocate 'com.oracle', 'kasuga.lib.vendor_modules.com.oracle'
    relocate 'com.ibm', 'kasuga.lib.vendor_modules.com.ibm'
    relocate ('io.netty.handler.codec.http', 'kasuga.lib.vendor_modules.io.netty.handler.codec.http');
    relocate ('io.netty.handler.codec.rtsp', 'kasuga.lib.vendor_modules.io.netty.handler.codec.rtsp');
    relocate ('io.netty.handler.codec.spdy', 'kasuga.lib.vendor_modules.io.netty.handler.codec.spdy');
    relocate('interpreter','kasuga.lib.vendor_modules.interpreter');
    relocate('org.apache', 'kasuga.lib.vendor_modules.org.apache');
    // relocate ('com.caoccao.javet', 'kasuga.lib.vendor_modules.com.caoccao.javet');

    relocate "jakarta", "kasuga.lib.vendor_modules.jakarta"
    relocate "javax.servlet", "kasuga.lib.vendor_modules.org.javax.servlet"
    relocate "org.intellij", "kasuga.lib.vendor_modules.org.intellij"
    relocate "org.jetbrains", "kasuga.lib.vendor_modules.org.jetbrains"
    // relocate "org.slf4j", "kasuga.lib.vendor_modules.org.slf4j"
    relocate "org.eclipse", "kasuga.lib.vendor_modules.org.eclipse"
    relocate "kotlin", "kasuga.lib.vendor_modules.kotlin.kotlin"
    relocate "io.javalin", "kasuga.lib.vendor_modules.io.javalin"
    relocate 'org.eclipse.jetty', 'kasuga.lib.vendor_modules.org.eclipse.jetty'

    finalizedBy 'reobfShadowJar'
}

assemble.dependsOn shadowJar

reobf{
    shadowJar {}
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            groupId = "kasuga.lib"
            artifactId = "kasuga_lib-${repository_version}"
            version = "${mod_full_version}"

            artifact shadowJar

            pom {
                properties.putAll(pomEntries);
                if(ci_type) {
                    ciManagement {
                        system = ci_type
                        url = ci_url
                    }
                }
            }
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/mcmodsrepo"
        }
    }

    repositories {
        maven {
            name = "kuayueMaven"
            url = uri("https://maven.kycraft.cn/${repository_channel}/")
            credentials(PasswordCredentials) {
                username = project.findProperty("kuayueMavenUsername") ?: localProperties.getProperty("repository_username")
                password = project.findProperty("kuayueMavenPassword") ?: localProperties.getProperty("repository_password")
            }
            authentication {
                basic(BasicAuthentication)
            }
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

mixin {
    add sourceSets.main, 'kasuga.refmap.json'
    config 'kasuga.mixins.json'
}