KeywordHanaro_BE/build.gradle at main · KeywordHanaro/KeywordHanaro_BE · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
plugins {
    id 'java'
    id 'jacoco'
    id 'org.springframework.boot' version '3.3.6'
    id 'io.spring.dependency-management' version '1.1.6'
}

group = 'com.hana4'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter:3.0.4'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.6.0'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    runtimeOnly 'com.mysql:mysql-connector-j'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter-test:3.0.4'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

tasks.named('test') {
    useJUnitPlatform()
}

jar {
    enabled = false
}

test {
    finalizedBy jacocoTestReport
}

jacocoTestReport {
    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, include: [
                    "com/hana4/keywordhanaro/controller/**",
                    "com/hana4/keywordhanaro/service/**",
                    "com/hana4/keywordhanaro/model/**"
            ], exclude: [
                    "com/hana4/keywordhanaro/controller/AuthController.class",
                    "com/hana4/keywordhanaro/controller/ErrorController.class",
                    "com/hana4/keywordhanaro/controller/LLMController.class",
                    "com/hana4/keywordhanaro/service/KakaoAuthServiceImpl.class",
                    "com/hana4/keywordhanaro/service/BranchServiceImpl.class",
                    "com/hana4/keywordhanaro/service/LLMServiceImpl.class",
                    "com/hana4/keywordhanaro/model/mapper/**"
            ])
        }))
    }
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            element = 'CLASS'
            includes = [
                    'com.hana4.keywordhanaro.controller.*',
                    'com.hana4.keywordhanaro.service.*',
                    'com.hana4.keywordhanaro.model.*'
            ]
            excludes = [
                    'com.hana4.keywordhanaro.controller.AuthController',
                    'com.hana4.keywordhanaro.controller.ErrorController',
                    'com.hana4.keywordhanaro.controller.LLMController',
                    'com.hana4.keywordhanaro.service.KakaoAuthServiceImpl',
                    'com.hana4.keywordhanaro.service.BranchServiceImpl',
                    'com.hana4.keywordhanaro.service.LLMServiceImpl',
                    'com.hana4.keywordhanaro.model.mapper.*'
            ]
            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.80
            }
        }
    }
}