Dropping AT weapon when knocked unconscious?

[sagjangi]

Is it possible to make players drop their AT weapon when they go unconscious? I cannot count the number of times I've been spotting for an AT gunner when they are hit and I cannot pick up the AT weapon to finish the job.

[PabstMirror]

https://www.youtube.com/watch?v=MT48gsbtfcA

Problem is similar to #254, in that ARMA is really missing a addSecondaryMagazine command (http://feedback.arma3.com/view.php?id=20582). So I can't just add the launcher directly to guy trying to picking it up.

This code just dumps the current weapon unloaded and the current mag into an empty groundContainer. So you still have to manualy reload the weapon you pick it up.

The problem is attachments, there are classnames like rhs_weap_rpg7_pgo which have "LinkedItems" that get added automatically; ignoring the actual attachments on the weapon.

Is there a good way to get the clean base-class of a "LinkedItems" type weapon?

I'll think about it, here's the quick script version for now:

DROPIT = {
    _unit = _this select 0;

    _dropPos = _unit modelToWorld [-0.25, -0.5, 1];
    _holder = createVehicle ["WeaponHolderSimulated", _dropPos, [], 0, "CAN_COLLIDE"];

    _weaponToAdd = secondaryWeapon _unit;
    _mags = magazinesAmmoFull _unit;
    _attachments = secondaryWeaponItems _unit;  //???

    _holder addWeaponCargoGlobal [_weaponToAdd, 1];
    _unit removeWeapon _weaponToAdd;

    _launcherMuzzles = getArray (configFile >> "CfgWeapons" >> _weaponToAdd >> "muzzles");
    if (_launcherMuzzles isEqualTo ["this"]) then { _launcherMuzzles = [_weaponToAdd];};

    {
        _magClassname = _x select 0;
        _magAmmo = _x select 1;
        _magLocation = _x select 4;

        if (_magLocation in _launcherMuzzles) then {
            _holder addMagazineAmmoCargo [_magClassname, 1, _magAmmo];
        };
    } forEach _mags;
};

{
    _x setVariable ["AGM_allowUnconscious", true];
    [_x] spawn {
        waitUntil {(_this select 0) getVariable ["AGM_isUnconscious", false]};
        hint format ["drop: %1", _this];
        _this call DROPIT;
    };
} forEach allUnits;

[commy2]

This will require http://feedback.arma3.com/view.php?id=22000 to be added first.

Is there a good way to get the clean base-class of a "LinkedItems" type weapon?

There is BIS_fnc_weaponComponents, but it has many issues.

E.g.:

"agm_vector" call BIS_fnc_weaponComponents;
-> ["binocular"]

or

"arifle_MX_black_F" call BIS_fnc_weaponComponents
-> ["arifle_mx_f"]

I rewrote that function already, but if the mod creator has no clean version of the weapon as base class, it can't give you one (obviously).

#1621

[sagjangi]

That's a great work around Pabst, thanks.

[PabstMirror]

DROPIT = {
    _unit = _this select 0;
    if (!local _unit) exitWith {};
    waitUntil {(animationState _unit) == "unconscious"};
    sleep 0.1;
    _orginalMagazines = magazinesAmmo _unit;
    _dropPos = _unit modelToWorld [-0.75, 0.6, 0.4];
    _holder = createVehicle ["WeaponHolderSimulated", _dropPos, [], 0, "CAN_COLLIDE"];
    _holder addMagazineCargoGlobal ["Chemlight_green", 1];
    _unit action ["PutWeapon", _holder, (secondaryWeapon _unit)];
    waitUntil {(secondaryWeapon _unit) == ""};
    {  //Normaly _unit will dump all launcher mags into the holder, so add them back to the _unit
        _unit addMagazine _x;
    } forEach (_orginalMagazines - (magazinesAmmo _unit));

    clearMagazineCargoGlobal _holder;
};

Using action is working pretty good. It drops the launcher with the correct ammo loaded and attachments setup. Only problem is it dumps all the ammo for the launcher into the holder, but we can just re-add them to the player.

[nicolasbadano]

I thought that action was linked to an animation and not very reliable. But if it works reliably then we can probably use it for #1621 too.

[commy2]

Related: #1717