syntaqlite/flake.nix at main · LalitMaganti/syntaqlite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
{
  description = "Fast, accurate SQLite SQL formatter, validator, and language server";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  };

  outputs =
    { self, nixpkgs }:
    let
      inherit (nixpkgs) lib;

      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forAllSystems = lib.genAttrs systems;

      cliManifest = lib.importTOML ./syntaqlite-cli/Cargo.toml;
      workspaceManifest = lib.importTOML ./Cargo.toml;
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.rustPlatform.buildRustPackage {
            pname = "syntaqlite";
            version = cliManifest.package.version;

            src = self;

            cargoLock.lockFile = ./Cargo.lock;

            cargoBuildFlags = [
              "--package"
              cliManifest.package.name
            ];

            cargoTestFlags = [
              "--package"
              cliManifest.package.name
            ];

            meta = {
              description = cliManifest.package.description;
              homepage = workspaceManifest.workspace.package.homepage;
              license = lib.licenses.asl20;
              mainProgram = "syntaqlite";
              platforms = lib.platforms.unix;
            };
          };
        }
      );

      checks = forAllSystems (system: {
        default = self.packages.${system}.default;
      });

      overlays.default = final: _prev: {
        syntaqlite = self.packages.${final.stdenv.hostPlatform.system}.default;
      };
    };
}