Kommando/build.gradle.kts at master · LanternPowered/Kommando · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
plugins {
    kotlin("multiplatform") version "1.3.61"
    id("net.minecrell.licenser") version "0.4.1"
}

allprojects {
  group = "org.lanternpowered"
  version = "1.0-SNAPSHOT"

  repositories {
    mavenCentral()
  }
}

subprojects {
  apply(plugin = "org.jetbrains.kotlin.multiplatform")
  apply(plugin = "net.minecrell.licenser")

  kotlin {
    jvm()
    js()
    // TODO: Figure out why native fails now and report a bug,
    //  did the classes inheritance structure become too complex?
    // mingwX64()

    sourceSets {
      val commonMain by getting {
        dependencies {
          implementation(kotlin("stdlib-common"))
        }
      }

      val commonTest by getting {
        dependencies {
          implementation(kotlin("test-common"))
          implementation(kotlin("test-annotations-common"))
        }
      }

      val jvmMain by getting {
        dependencies {
          implementation(kotlin("stdlib"))
        }
      }

      val jvmTest by getting {
        dependencies {
          implementation(kotlin("test-junit"))
        }
      }

      val jsMain by getting {
        dependencies {
          implementation(kotlin("stdlib-js"))
        }
      }

      val jsTest by getting {
        dependencies {
          implementation(kotlin("test-js"))
        }
      }

      all {
        languageSettings.apply {
          languageVersion = "1.3"
          apiVersion = "1.3"
          progressiveMode = true

          enableLanguageFeature("InlineClasses")
          enableLanguageFeature("NewInference")
          enableLanguageFeature("NonParenthesizedAnnotationsOnFunctionalTypes")

          useExperimentalAnnotation("kotlin.ExperimentalUnsignedTypes")
          useExperimentalAnnotation("kotlin.contracts.ExperimentalContracts")
          useExperimentalAnnotation("kotlin.ExperimentalStdlibApi")
          useExperimentalAnnotation("kotlin.experimental.ExperimentalTypeInference")
        }
      }
    }
  }

  license {
    header = rootProject.file("HEADER.txt")
    newLine = false
    ignoreFailures = false

    // Map the kotlin source sets to normal source sets
    // so that they work in the license plugin.
    sourceSets {
      for ((name, kotlinSourceSet) in kotlin.sourceSets.asMap) {
        create(project.name + "_" + name) {
          allSource.source(kotlinSourceSet.kotlin)
        }
      }
    }

    include("**/*.kt")

    ext {
      set("name", rootProject.name)
      set("url", "https://www.lanternpowered.org")
      set("organization", "LanternPowered")
    }
  }
}