Use system queries instead of CMAKE_HOST_SYSTEM_NAME to select alternatives

Fixes #28

Author: LegalizeAdulthood

config/CMakeLists.txt

@@ -12,12 +12,12 @@ add_library(config
     include/config/user_id.h
     cmake/config.h.in
     cmake/configure_trn.cmake
-    cmake/fdio.Linux.h.in
-    cmake/fdio.Windows.h.in
-    cmake/pipe_io.Linux.h.in
-    cmake/pipe_io.Windows.h.in
-    cmake/string_case_compare.Linux.h.in
-    cmake/string_case_compare.Windows.h.in
+    cmake/fdio.fcntl.h.in
+    cmake/fdio.io.h.in
+    cmake/pipe_io.standard.h.in
+    cmake/pipe_io.underscore.h.in
+    cmake/string_case_compare.strings.h.in
+    cmake/string_case_compare.manual.h.in
     "${CMAKE_CURRENT_BINARY_DIR}/include/config/config.h"
     "${CMAKE_CURRENT_BINARY_DIR}/include/config/fdio.h"
     "${CMAKE_CURRENT_BINARY_DIR}/include/config/pipe_io.h"

config/cmake/configure_trn.cmake

@@ -1,16 +1,18 @@
 include(CheckIncludeFile)
 include(CheckSymbolExists)
 
-function(configure_system_header name)
+function(configure_flavor_header name flavor)
     configure_file(
-        "${CMAKE_CURRENT_FUNCTION_LIST_DIR}/${name}.${CMAKE_HOST_SYSTEM_NAME}.h.in"
+        "${CMAKE_CURRENT_FUNCTION_LIST_DIR}/${name}.${flavor}.h.in"
         "include/config/${name}.h")
 endfunction()
 
 function(configure_trn)
     #
     # Perform inspections of the system and configure accordingly.
     #
+    check_include_file(fcntl.h      I_FCNTL)
+    check_include_file(io.h         I_IO)
     check_include_file(pwd.h        I_PWD)
     check_include_file(sgtty.h      I_SGTTY)
     check_include_file(strings.h    I_STRINGS)
@@ -24,11 +26,52 @@ function(configure_trn)
     check_include_file(unistd.h     I_UNISTD)
     check_include_file(utime.h      I_UTIME)
     check_include_file(vfork.h      I_VFORK)
-    if(I_PWD)
-        check_symbol_exists(getpwent "pwd.h" HAS_GETPWENT)
+
+    # Determine method used for file descriptor I/O
+    if(I_FCNTL)
+        check_symbol_exists(open "fcntl.h" HAS_FCNTL_OPEN)
+        if(HAS_FCNTL_OPEN)
+            set(FDIO_FLAVOR "fcntl")
+        endif()
+    endif()
+    if(NOT FDIO_FLAVOR AND I_IO)
+        check_symbol_exists(open "io.h" HAS_IO_OPEN)
+        if(HAS_IO_OPEN)
+            set(FDIO_FLAVOR "io")
+        endif()
+    endif()
+    if(NOT FDIO_FLAVOR)
+        message(FATAL_ERROR "Couldn't find open() in <fcntl.h> or <io.h>; file descriptor I/O not found.")
+    endif()
+
+    # Pipe open/close functions
+    check_symbol_exists(_popen "stdio.h" HAS_UNDERSCORE_POPEN)
+    if(HAS_UNDERSCORE_POPEN)
+        set(PIPE_IO_FLAVOR "underscore")
+    endif()
+    if(NOT PIPE_IO_FLAVOR)
+        check_symbol_exists(popen "stdio.h" HAS_STANDARD_POPEN)
+        if(HAS_STANDARD_POPEN)
+            set(PIPE_IO_FLAVOR "standard")
+        endif()
+    endif()
+    if(NOT PIPE_IO_FLAVOR)
+        message(FATAL_ERROR "Couldn't determine functions for pipe open/close.")
     endif()
+
+    # String case-insensitive compare functions
     if(I_STRINGS)
         check_symbol_exists(strcasecmp "strings.h" HAS_STRCASECMP)
+        if(HAS_STRCASECMP)
+            set(STRING_CASE_COMPARE_FLAVOR "strings")
+        endif()
+    endif()
+    if(NOT STRING_CASE_COMPARE_FLAVOR)
+        set(STRING_CASE_COMPARE_FLAVOR "manual")
+    endif()
+
+    if(I_PWD)
+        check_symbol_exists(getpwent "pwd.h" HAS_GETPWENT)
     endif()
     if(I_UNISTD)
         check_symbol_exists(getdomainname "unistd.h" HAS_GETDOMAINNAME)
@@ -129,15 +172,13 @@ function(configure_trn)
     set(SUPPORT_XTHREAD ON)
 
     configure_file("${CMAKE_CURRENT_FUNCTION_LIST_DIR}/config.h.in" include/config/config.h)
-    set(STRING_CASE_COMPARE_SOURCES "")
-    if(NOT HAS_STRCASECMP)
-        set(STRING_CASE_COMPARE_SOURCES "string_case_compare.cpp")
-    endif()
+    set(STRING_CASE_COMPARE_SOURCES_strings "")
+    set(STRING_CASE_COMPARE_SOURCES_manual "string_case_compare.cpp")
+    set(STRING_CASE_COMPARE_SOURCES ${STRING_CASE_COMPARE_SOURCES_${STRING_CASE_COMPARE_FLAVOR}} PARENT_SCOPE)
     if((NOT CMAKE_HOST_SYSTEM_NAME STREQUAL "Linux") AND (NOT CMAKE_HOST_SYSTEM_NAME STREQUAL "Windows"))
         message(FATAL_ERROR "Unknown system ${CMAKE_HOST_SYSTEM_NAME}; expected 'Linux' or 'Windows'")
     endif()
-    configure_system_header("fdio")
-    configure_system_header("pipe_io")
-    configure_system_header("string_case_compare")
-    set(STRING_CASE_COMPARE_SOURCES "${STRING_CASE_COMPARE_SOURCES}" PARENT_SCOPE)
+    configure_flavor_header("fdio" "${FDIO_FLAVOR}")
+    configure_flavor_header("pipe_io" "${PIPE_IO_FLAVOR}")
+    configure_flavor_header("string_case_compare" "${STRING_CASE_COMPARE_FLAVOR}")
 endfunction()