fix: Guard install rules behind option

Add LIZARDBYTE_COMMON_INSTALL option (defaults to top-level only) to gate all install() calls and package config generation, preventing install rule conflicts when consumed as a subdirectory.

Author: ReenigneArcher

CMakeLists.txt

@@ -33,6 +33,9 @@ option(BUILD_TESTS "Build tests" ${LIZARDBYTE_COMMON_IS_TOP_LEVEL})
 option(BUILD_DOCS "Build documentation" ${LIZARDBYTE_COMMON_IS_TOP_LEVEL})
 option(LIZARDBYTE_COMMON_BUILD_TEST_SUPPORT "Build GoogleTest support helpers"
        ${BUILD_TESTS})
+option(LIZARDBYTE_COMMON_INSTALL
+       "Install lizardbyte-common targets and package configuration"
+       ${LIZARDBYTE_COMMON_IS_TOP_LEVEL})
 option(LIZARDBYTE_COMMON_WARNINGS_AS_ERRORS
        "Treat lizardbyte-common warnings as errors"
        ${LIZARDBYTE_COMMON_IS_TOP_LEVEL})
@@ -95,17 +98,19 @@ endif()
 #
 # Package config
 #
-configure_package_config_file(
-  "${CMAKE_CURRENT_SOURCE_DIR}/cmake/lizardbyte-common-config.cmake.in"
-  "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config.cmake"
-  INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
-
-write_basic_package_version_file(
-  "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config-version.cmake"
-  VERSION ${PROJECT_VERSION}
-  COMPATIBILITY SameMajorVersion)
-
-install(
-  FILES "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config.cmake"
-        "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config-version.cmake"
-  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
+if(LIZARDBYTE_COMMON_INSTALL)
+    configure_package_config_file(
+      "${CMAKE_CURRENT_SOURCE_DIR}/cmake/lizardbyte-common-config.cmake.in"
+      "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config.cmake"
+      INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
+
+    write_basic_package_version_file(
+      "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config-version.cmake"
+      VERSION ${PROJECT_VERSION}
+      COMPATIBILITY SameMajorVersion)
+
+    install(
+      FILES "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config.cmake"
+            "${CMAKE_CURRENT_BINARY_DIR}/lizardbyte-common-config-version.cmake"
+      DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
+endif()

src/CMakeLists.txt

@@ -24,17 +24,19 @@ else()
     endif()
 endif()
 
-install(
-  TARGETS lizardbyte_common
-  EXPORT lizardbyte-common-targets
-  ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
-  LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
-  RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
+if(LIZARDBYTE_COMMON_INSTALL)
+    install(
+      TARGETS lizardbyte_common
+      EXPORT lizardbyte-common-targets
+      ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+      LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+      RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}")
 
-install(DIRECTORY "${PROJECT_SOURCE_DIR}/src/include/"
-        DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
+    install(DIRECTORY "${PROJECT_SOURCE_DIR}/src/include/"
+            DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}")
 
-install(
-  EXPORT lizardbyte-common-targets
-  NAMESPACE lizardbyte::
-  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
+    install(
+      EXPORT lizardbyte-common-targets
+      NAMESPACE lizardbyte::
+      DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/lizardbyte-common")
+endif()