Create load balancers

Author: alex-hunt-materialize

examples/simple/main.tf

@@ -127,6 +127,11 @@ output "connection_strings" {
   sensitive   = true
 }
 
+output "load_balancer_details" {
+  description = "Details of the Materialize instance load balancers."
+  value       = module.materialize.load_balancer_details
+}
+
 variable "operator_version" {
   description = "Version of the Materialize operator to install"
   type        = string
@@ -151,6 +156,8 @@ variable "materialize_instances" {
     namespace               = optional(string)
     database_name           = string
     create_database         = optional(bool, true)
+    create_load_balancer    = optional(bool, true)
+    internal_load_balancer  = optional(bool, true)
     environmentd_version    = optional(string)
     cpu_request             = optional(string, "1")
     memory_request          = optional(string, "1Gi")

main.tf

@@ -119,6 +119,22 @@ module "operator" {
   }
 }
 
+module "load_balancers" {
+  source = "./modules/load_balancers"
+
+  for_each = { for idx, instance in local.instances : instance.name => instance if lookup(instance, "create_load_balancer", false) }
+
+  instance_name = each.value.name
+  namespace     = module.operator[0].materialize_instances[each.value.name].namespace
+  resource_id   = module.operator[0].materialize_instance_resource_ids[each.value.name]
+  internal      = each.value.internal_load_balancer
+
+  depends_on = [
+    module.operator,
+    module.gke,
+  ]
+}
+
 locals {
   default_helm_values = {
     observability = {
@@ -176,11 +192,13 @@ locals {
 locals {
   instances = [
     for instance in var.materialize_instances : {
-      name                 = instance.name
-      namespace            = instance.namespace
-      database_name        = instance.database_name
-      create_database      = instance.create_database
-      environmentd_version = instance.environmentd_version
+      name                   = instance.name
+      namespace              = instance.namespace
+      database_name          = instance.database_name
+      create_database        = instance.create_database
+      create_load_balancer   = instance.create_load_balancer
+      internal_load_balancer = instance.internal_load_balancer
+      environmentd_version   = instance.environmentd_version
 
       metadata_backend_url = format(
         "postgres://%s:%s@%s:5432/%s?sslmode=disable",

modules/load_balancers/main.tf

@@ -0,0 +1,67 @@
+resource "kubernetes_service" "console_load_balancer" {
+  metadata {
+    name      = "mz${var.resource_id}-console-lb"
+    namespace = var.namespace
+    annotations = {
+      "networking.gke.io/load-balancer-type" = var.internal ? "Internal" : "External"
+    }
+  }
+
+  spec {
+    type                    = "LoadBalancer"
+    external_traffic_policy = "Local"
+    selector = {
+      "materialize.cloud/name" = "mz${var.resource_id}-console"
+    }
+    port {
+      name        = "http"
+      port        = 8080
+      target_port = 8080
+      protocol    = "TCP"
+    }
+  }
+
+  lifecycle {
+    ignore_changes = [
+      metadata[0].annotations["cloud.google.com/neg"]
+    ]
+  }
+  wait_for_load_balancer = true
+}
+
+resource "kubernetes_service" "balancerd_load_balancer" {
+  metadata {
+    name      = "mz${var.resource_id}-balancerd-lb"
+    namespace = var.namespace
+    annotations = {
+      "networking.gke.io/load-balancer-type" = var.internal ? "Internal" : "External"
+    }
+  }
+
+  spec {
+    type                    = "LoadBalancer"
+    external_traffic_policy = "Local"
+    selector = {
+      "materialize.cloud/name" = "mz${var.resource_id}-balancerd"
+    }
+    port {
+      name        = "sql"
+      port        = 6875
+      target_port = 6875
+      protocol    = "TCP"
+    }
+    port {
+      name        = "https"
+      port        = 6876
+      target_port = 6876
+      protocol    = "TCP"
+    }
+  }
+
+  lifecycle {
+    ignore_changes = [
+      metadata[0].annotations["cloud.google.com/neg"]
+    ]
+  }
+  wait_for_load_balancer = true
+}

modules/load_balancers/outputs.tf

@@ -0,0 +1,14 @@
+output "instance_name" {
+  description = "The name of the Materialize instance."
+  value       = var.instance_name
+}
+
+output "console_load_balancer_ip" {
+  description = "IP address of load balancer pointing at the web console."
+  value       = kubernetes_service.console_load_balancer.status[0].load_balancer[0].ingress[0].ip
+}
+
+output "balancerd_load_balancer_ip" {
+  description = "IP address of load balancer pointing at balancerd."
+  value       = kubernetes_service.balancerd_load_balancer.status[0].load_balancer[0].ingress[0].ip
+}

modules/load_balancers/variables.tf

@@ -0,0 +1,19 @@
+variable "instance_name" {
+  description = "The name of the Materialize instance."
+  type        = string
+}
+
+variable "namespace" {
+  description = "The kubernetes namespace to create the LoadBalancer Service in."
+  type        = string
+}
+
+variable "resource_id" {
+  description = "The resource_id in the Materialize status."
+  type        = string
+}
+
+variable "internal" {
+  description = "Whether the load balancer is internal to the VPC."
+  type        = bool
+}

modules/load_balancers/versions.tf

@@ -0,0 +1,18 @@
+terraform {
+  required_version = ">= 1.0"
+
+  required_providers {
+    google = {
+      source  = "hashicorp/google"
+      version = ">= 6.0"
+    }
+    kubernetes = {
+      source  = "hashicorp/kubernetes"
+      version = "~> 2.0"
+    }
+    helm = {
+      source  = "hashicorp/helm"
+      version = "~> 2.0"
+    }
+  }
+}

outputs.tf

@@ -85,3 +85,13 @@ output "operator" {
     instances      = module.operator[0].materialize_instances
   } : null
 }
+
+output "load_balancer_details" {
+  description = "Details of the Materialize instance load balancers."
+  value = {
+    for load_balancer in module.load_balancers : load_balancer.instance_name => {
+      console_load_balancer_ip   = load_balancer.console_load_balancer_ip
+      balancerd_load_balancer_ip = load_balancer.balancerd_load_balancer_ip
+    }
+  }
+}

variables.tf

@@ -108,6 +108,8 @@ variable "materialize_instances" {
     namespace               = optional(string)
     database_name           = string
     create_database         = optional(bool, true)
+    create_load_balancer    = optional(bool, true)
+    internal_load_balancer  = optional(bool, true)
     environmentd_version    = optional(string)
     cpu_request             = optional(string, "1")
     memory_request          = optional(string, "1Gi")