fastsse/flake.nix at main · MatesEngineer/fastsse · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{
  description = "fastsse development shell";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = { nixpkgs, rust-overlay, ... }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = f:
        nixpkgs.lib.genAttrs systems (system:
          f {
            pkgs = import nixpkgs {
              inherit system;
              overlays = [(import rust-overlay)];
            };
          });
    in
    {
      devShells = forAllSystems ({ pkgs }:
        let
          rustExtensions = ["clippy" "rustfmt"];
          rustTargets = ["wasm32-unknown-unknown"];
          mkRust = channel: channel.default.override {
            extensions = rustExtensions;
            targets = rustTargets;
          };
          rustLatest = mkRust pkgs.rust-bin.stable.latest;
          rustMsrv = mkRust pkgs.rust-bin.stable."1.88.0";
          mkShell = rust: pkgs.mkShell {
            packages = with pkgs; [
              binaryen
              cargo-deny
              nodejs_24
              pnpm
              rust
              wasm-pack
            ];

            shellHook = ''
              export PATH="$PWD/node_modules/.bin:$PATH"
            '';
          };
        in
        {
          default = mkShell rustLatest;
          msrv = mkShell rustMsrv;
        });

      formatter = forAllSystems ({ pkgs }: pkgs.nixpkgs-fmt);
    };
}