build.gradle

buildscript {

    repositories {
        mavenLocal()
        mavenCentral()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url 'https://jitpack.io' }
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.2.2' 
    }
}

allprojects {
    apply plugin: "eclipse"

    version = '1.2.1'
    ext {
        appName = "Feudal Tactics"
        gdxVersion = '1.11.0'
        roboVMVersion = '2.3.16'
        box2DLightsVersion = '1.5'
        ashleyVersion = '1.7.4'
        aiVersion = '1.8.2'
        gdxControllersVersion = '2.2.1'
        
        guavaVersion = '31.1-android'
        daggerVersion = '2.33'
        junitVersion = '5.10.2'
        mockitoVersion = '4.7.0'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        google()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
        maven { url "https://jitpack.io" }
    }
}

project(":desktop") {
    apply plugin: "java-library"


    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        
        api "com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-desktop"
    }
}

project(":android") {
	apply plugin: "com.android.application"

    configurations { natives }

    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-android:$gdxVersion"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-armeabi-v7a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-arm64-v8a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86_64"
        
        api "com.badlogicgames.gdx:gdx-freetype:$gdxVersion"
		natives "com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-armeabi-v7a"
		natives "com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-arm64-v8a"
		natives "com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-x86"
		natives "com.badlogicgames.gdx:gdx-freetype-platform:$gdxVersion:natives-x86_64"
    }
}

project(":core") {
    apply plugin: "java-library"

    dependencies {
    	api "com.badlogicgames.gdx:gdx:$gdxVersion"
    	
    	implementation("com.google.guava:guava:$guavaVersion") {
    	// exclude transitive dependencies mainly to avoid dealing with their licenses
    	// these dependencies are optional https://github.com/google/guava/issues/2824#issuecomment-544171665
    	// failureaccess is apparently needed
    	exclude group:"com.google.guava", module: "listenablefuture"
    	// these dependencies are seemingly only needed at compile time of Guava
    	exclude group:"com.google.code.findbugs", module: "jsr305"
    	exclude group:"org.checkerframework", module: "checker-qual"
    	exclude group:"com.google.errorprone", module: "error_prone_annotations"
    	exclude group:"com.google.j2objc", module: "j2objc-annotations"
    	}
    	implementation "com.google.dagger:dagger:$daggerVersion"
		annotationProcessor "com.google.dagger:dagger-compiler:$daggerVersion"
        
        implementation 'org.slf4j:slf4j-jdk14:2.0.6'
        
        api "com.badlogicgames.gdx:gdx-freetype:$gdxVersion"
        implementation 'com.github.raeleus.stripe:freetype:2.0.0'
        
	    testImplementation "org.junit.jupiter:junit-jupiter-api:$junitVersion"
		testImplementation "org.junit.jupiter:junit-jupiter-params:$junitVersion"
	    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitVersion"
	     	
		testImplementation "org.mockito:mockito-core:$mockitoVersion"
		testImplementation "org.mockito:mockito-junit-jupiter:$mockitoVersion"
    }
    
	test {
	    useJUnitPlatform()
	}

}