hydra-banner/flake.nix at main · MiniHarinn/hydra-banner · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, rust-overlay }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems f;
    in {
      packages = forAllSystems (system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ rust-overlay.overlays.default ];
          };
          toolchain = pkgs.rust-bin.stable.latest.default;
          rustPlatform = pkgs.makeRustPlatform { cargo = toolchain; rustc = toolchain; };
        in {
          default = rustPlatform.buildRustPackage {
            pname = "hydra-banner";
            version = "0";
            src = ./.;
            cargoLock.lockFile = ./Cargo.lock;
          };
          getmd = pkgs.stdenvNoCC.mkDerivation {
            name = "getmd";
            src = ./scripts/getmd;
            dontUnpack = true;
            installPhase = "install -D $src $out/bin/getmd";
          };
          glb = pkgs.writeShellApplication {
            name = "glb";
            runtimeInputs = [ pkgs.hydra-check pkgs.jq ];
            text = builtins.readFile ./scripts/glb;
          };
          docker = pkgs.dockerTools.buildImage {
            name = "ghcr.io/miniharinn/hydra-banner";
            tag = "latest";
            copyToRoot = [ self.packages.${system}.default ];
            config = {
              Cmd = [ "${self.packages.${system}.default}/bin/hydra-banner" ];
              Env = [ "PORT=3000" ];
              ExposedPorts."3000/tcp" = { };
            };
          };
        }
      );

      apps = forAllSystems (system:
        let pkg = name: { type = "app"; program = "${self.packages.${system}.${name}}/bin/${name}"; };
        in {
          getmd = pkg "getmd";
          glb = pkg "glb";
        }
      );

      devShells = forAllSystems (system:
        let
          pkgs = import nixpkgs {
            inherit system;
            overlays = [ rust-overlay.overlays.default ];
          };
          toolchain = pkgs.rust-bin.stable.latest.default.override {
            extensions = [ "rust-src" "rust-analyzer" "clippy" "rustfmt" ];
          };
        in {
          default = pkgs.mkShell {
            nativeBuildInputs = [ toolchain pkgs.watchexec ];
            RUST_LOG = "hydra_banner=debug,tower_http=debug";
            shellHook = ''echo "dev server: ./scripts/dev"'';
          };
        }
      );
    };
}