cccl/libcudacxx/codegen/CMakeLists.txt at e66cb8098ee57c8ea0e70631b1b0fe7f209d9839 · NVIDIA/cccl · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
## Codegen adds the following build targets
#    libcudacxx.atomics.codegen
#    libcudacxx.atomics.codegen.install
## Test targets:
#    libcudacxx.test.atomics.codegen.diff

add_executable(codegen EXCLUDE_FROM_ALL codegen.cpp)

target_compile_features(codegen PRIVATE cxx_std_20)

set(atomic_generated_output "${libcudacxx_BINARY_DIR}/codegen/cuda_ptx_generated.h")
set(atomic_install_location "${libcudacxx_SOURCE_DIR}/include/cuda/std/__atomic/backends/")

target_link_libraries(codegen PRIVATE fmt)

set_property(TARGET codegen PROPERTY CXX_STANDARD 17)

add_custom_target(
  libcudacxx.atomics.codegen
  COMMAND codegen "${atomic_generated_output}"
  BYPRODUCTS "${atomic_generated_output}"
)

add_custom_target(
  libcudacxx.atomics.codegen.install
  # gersemi: off
  COMMAND
    "${CMAKE_COMMAND}" -E copy
      "${atomic_generated_output}"
      "${atomic_install_location}/cuda_ptx_generated.h"
  # gersemi: on
  DEPENDS libcudacxx.atomics.codegen
  BYPRODUCTS "${atomic_install_location}/cuda_ptx_generated.h"
)

add_test(
  NAME libcudacxx.test.atomics.codegen.diff
  # gersemi: off
  COMMAND
    "${CMAKE_COMMAND}" -E compare_files
      "${atomic_install_location}/cuda_ptx_generated.h"
      "${atomic_generated_output}"
  # gersemi: on
)

set_tests_properties(
  libcudacxx.test.atomics.codegen.diff
  PROPERTIES REQUIRED_FILES "${atomic_generated_output}"
)