|
| 1 | +#============================================================================= |
| 2 | +# Copyright (c) 2021-2023, NVIDIA CORPORATION. |
| 3 | +# |
| 4 | +# Licensed under the Apache License, Version 2.0 (the "License"); |
| 5 | +# you may not use this file except in compliance with the License. |
| 6 | +# You may obtain a copy of the License at |
| 7 | +# |
| 8 | +# http://www.apache.org/licenses/LICENSE-2.0 |
| 9 | +# |
| 10 | +# Unless required by applicable law or agreed to in writing, software |
| 11 | +# distributed under the License is distributed on an "AS IS" BASIS, |
| 12 | +# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. |
| 13 | +# See the License for the specific language governing permissions and |
| 14 | +# limitations under the License. |
| 15 | +#============================================================================= |
| 16 | +# |
| 17 | +# This is the preferred entry point for projects using rapids-cmake |
| 18 | +# |
| 19 | + |
| 20 | +# Allow users to control which version is used |
| 21 | +if(NOT rapids-cmake-version) |
| 22 | + # Define a default version if the user doesn't set one |
| 23 | + set(rapids-cmake-version 24.02) |
| 24 | +endif() |
| 25 | + |
| 26 | +# Allow users to control which GitHub repo is fetched |
| 27 | +if(NOT rapids-cmake-repo) |
| 28 | + # Define a default repo if the user doesn't set one |
| 29 | + set(rapids-cmake-repo rapidsai/rapids-cmake) |
| 30 | +endif() |
| 31 | + |
| 32 | +# Allow users to control which branch is fetched |
| 33 | +if(NOT rapids-cmake-branch) |
| 34 | + # Define a default branch if the user doesn't set one |
| 35 | + set(rapids-cmake-branch "branch-${rapids-cmake-version}") |
| 36 | +endif() |
| 37 | + |
| 38 | +# Allow users to control the exact URL passed to FetchContent |
| 39 | +if(NOT rapids-cmake-url) |
| 40 | + # Construct a default URL if the user doesn't set one |
| 41 | + set(rapids-cmake-url "https://github.com/${rapids-cmake-repo}/") |
| 42 | + # In order of specificity |
| 43 | + if(rapids-cmake-sha) |
| 44 | + # An exact git SHA takes precedence over anything |
| 45 | + string(APPEND rapids-cmake-url "archive/${rapids-cmake-sha}.zip") |
| 46 | + elseif(rapids-cmake-tag) |
| 47 | + # Followed by a git tag name |
| 48 | + string(APPEND rapids-cmake-url "archive/refs/tags/${rapids-cmake-tag}.zip") |
| 49 | + else() |
| 50 | + # Or if neither of the above two were defined, use a branch |
| 51 | + string(APPEND rapids-cmake-url "archive/refs/heads/${rapids-cmake-branch}.zip") |
| 52 | + endif() |
| 53 | +endif() |
| 54 | + |
| 55 | +if(POLICY CMP0135) |
| 56 | + cmake_policy(PUSH) |
| 57 | + cmake_policy(SET CMP0135 NEW) |
| 58 | +endif() |
| 59 | +include(FetchContent) |
| 60 | +FetchContent_Declare(rapids-cmake URL "${rapids-cmake-url}") |
| 61 | +if(POLICY CMP0135) |
| 62 | + cmake_policy(POP) |
| 63 | +endif() |
| 64 | +FetchContent_GetProperties(rapids-cmake) |
| 65 | +if(rapids-cmake_POPULATED) |
| 66 | + # Something else has already populated rapids-cmake, only thing |
| 67 | + # we need to do is setup the CMAKE_MODULE_PATH |
| 68 | + if(NOT "${rapids-cmake-dir}" IN_LIST CMAKE_MODULE_PATH) |
| 69 | + list(APPEND CMAKE_MODULE_PATH "${rapids-cmake-dir}") |
| 70 | + endif() |
| 71 | +else() |
| 72 | + FetchContent_MakeAvailable(rapids-cmake) |
| 73 | +endif() |
0 commit comments