Add test for labeled tuple types encoding

Author: Nathan Rebours

.ocamlformat-ignore

@@ -46,6 +46,7 @@ test/driver/non-compressible-suffix/test.ml
 test/driver/transformations/test.ml
 test/driver/transformations/test_412.ml
 test/driver/transformations/test_510.ml
+test/encoding/504/api/test.ml
 test/expand-header-and-footer/test.ml
 test/expansion_helpers/mangle/test.ml
 test/expansion_inside_payloads/test.ml

test/encoding/504/api/dune

@@ -0,0 +1,14 @@
+(rule
+ (package ppxlib)
+ (alias runtest)
+ (enabled_if
+  (>= %{ocaml_version} 5.4))
+ (deps
+  (:test test.ml)
+  (package ppxlib))
+ (action
+  (chdir
+   %{project_root}
+   (progn
+    (run expect-test %{test})
+    (diff? %{test} %{test}.corrected)))))

test/encoding/504/api/test.ml

@@ -0,0 +1,59 @@
+open Ppxlib_ast
+
+module To_ocaml = Convert (Js) (Compiler_version)
+module From_ocaml = Convert (Compiler_version) (Js)
+
+open Ppxlib
+
+#install_printer Pprintast.core_type;;
+
+module Builder = Ast_builder.Make(struct let loc = Location.none end)
+
+let ptyp_int = Builder.(ptyp_constr (Located.mk (Longident.parse "int")) [])
+let ptyp_string =
+  Builder.(ptyp_constr (Located.mk (Longident.parse "string")) []);;
+[%%ignore]
+
+(* Generate an encoded labeled tuple type *)
+let encoded_labeled_tuple_type =
+  Builder.ptyp_labeled_tuple
+    [ Some "a", ptyp_int
+    ; Some "b", ptyp_int
+    ; None, ptyp_string
+    ]
+
+(* Migrate it to the current compiler (>= 5.4, as per dune rules) *)
+let labeled_tuple_type = To_ocaml.copy_core_type encoded_labeled_tuple_type;;
+[%%ignore]
+
+let as_source =
+  Format.asprintf "%a" Astlib.Compiler_pprintast.core_type labeled_tuple_type;;
+[%%expect{|
+val as_source : string = "(a:int * b:int * string)"
+|}]
+
+(* Migrate back to ppxlib's AST *)
+let encoded_by_migration = From_ocaml.copy_core_type labeled_tuple_type
+
+let pattern = Ast_pattern.(ptyp_labeled_tuple __);;
+[%%ignore]
+
+
+(* Destruct both the migration and Ast_builder generated encodings with
+   the Ast_pattern function. *)
+let destruct_from_migration =
+  Ast_pattern.parse_res pattern Location.none encoded_by_migration (fun x -> x);;
+[%%expect{|
+val destruct_from_migration :
+  ((string option * core_type) list, Location.Error.t Stdppx.NonEmptyList.t)
+  result = Ok [(Some "a", int); (Some "b", int); (None, string)]
+|}]
+
+let destruct =
+  Ast_pattern.parse_res pattern Location.none
+    encoded_labeled_tuple_type (fun x -> x);;
+[%%expect{|
+val destruct :
+  ((string option * core_type) list, Location.Error.t Stdppx.NonEmptyList.t)
+  result = Ok [(Some "a", int); (Some "b", int); (None, string)]
+|}]

test/encoding/504/migrations/dune

@@ -0,0 +1,10 @@
+(executable
+ (name id_driver)
+ (modules id_driver)
+ (libraries ppxlib))
+
+(cram
+ (package ppxlib)
+ (enabled_if
+  (>= %{ocaml_version} 5.4))
+ (deps id_driver.exe))

test/encoding/504/migrations/id_driver.ml

@@ -0,0 +1 @@
+let () = Ppxlib.Driver.standalone ()

test/encoding/504/migrations/labeled_tuple_type.t

@@ -0,0 +1,16 @@
+This test checks that labeled tuple types are correctly encoded
+when migrated down to our 5.2 AST
+
+  $ cat > test.ml << EOF
+  > type t = (a: int * b: int * string)
+  > EOF
+
+  $ ./id_driver.exe test.ml
+  type t =
+    [%ppxlib.migration.ptyp_labeled_tuple_504 :
+      (('a * int) * ('b * int) * (_ * string))]
+
+And that it is correctly decoded when migrated back up to 5.4+ ASTS:
+
+  $ ./id_driver.exe test.ml --use-compiler-pp
+  type t = (a:int * b:int * string)