|
| 1 | +import std/[options, tables] |
| 2 | +import nimsumtree/[arc, rope] |
| 3 | +import misc/[event, custom_async, delayed_task, jsonex] |
| 4 | +import component, view, config_provider, input_api |
| 5 | + |
| 6 | +export component |
| 7 | + |
| 8 | +const currentSourcePath2 = currentSourcePath() |
| 9 | +include module_base |
| 10 | + |
| 11 | +declareSettings HoverSettings, "hover": |
| 12 | + ## How many milliseconds after hovering a word the lsp hover request is sent. |
| 13 | + declare delay, int, 200 |
| 14 | + |
| 15 | + ## Command to run when hovering something. |
| 16 | + declare command, JsonNodeEx, nil |
| 17 | + |
| 18 | +type |
| 19 | + HoverComponent* = ref object of Component |
| 20 | + settings*: HoverSettings |
| 21 | + hoverView*: View |
| 22 | + showHoverTask: DelayedTask # for showing hover info after a delay |
| 23 | + hideHoverTask: DelayedTask # for hiding hover info after a delay |
| 24 | + currentHoverLocation: Point # the location of the mouse hover |
| 25 | + showHover*: bool # whether to show hover info in ui |
| 26 | + hoverText*: string # the text to show in the hover info |
| 27 | + hoverLocation*: Point # where to show the hover info |
| 28 | + hoverScrollOffset*: float # the scroll offset inside the hover window |
| 29 | + onHoverViewMarkedDirtyHandle: Id |
| 30 | + hoverViewCallbackHandles: Id |
| 31 | + overlayViews*: seq[View] |
| 32 | + mouseHoverLocation*: Point |
| 33 | + mouseHoverMods*: Modifiers |
| 34 | + onModsChangedHandle: Id |
| 35 | + isHovered*: bool |
| 36 | + |
| 37 | +# DLL API |
| 38 | +{.push rtl, gcsafe, raises: [].} |
| 39 | +proc getHoverComponent*(self: ComponentOwner): Option[HoverComponent] |
| 40 | +proc newHoverComponent*(settings: HoverSettings): HoverComponent |
| 41 | + |
| 42 | +proc hoverComponentClearOverlayViews(self: HoverComponent) |
| 43 | +proc hoverComponentClearHoverView(self: HoverComponent) |
| 44 | +proc hoverComponentShowHoverForAsync(self: HoverComponent, cursor: Point): Future[void] {.async.} |
| 45 | +proc hoverComponentHideHover(self: HoverComponent) |
| 46 | +proc hoverComponentShowHoverDelayed(self: HoverComponent) |
| 47 | +proc hoverComponentCancelHover(self: HoverComponent) |
| 48 | +proc hoverComponentShowHoverView(self: HoverComponent, view: View, location: Point) |
| 49 | +{.pop.} |
| 50 | + |
| 51 | +# Nice wrappers |
| 52 | +{.push inline.} |
| 53 | +proc clearHoverView*(self: HoverComponent) = hoverComponentClearHoverView(self) |
| 54 | +proc clearOverlayViews*(self: HoverComponent) = hoverComponentClearOverlayViews(self) |
| 55 | +proc showHoverForAsync*(self: HoverComponent, cursor: Point): Future[void] {.async.} = hoverComponentShowHoverForAsync(self, cursor).await |
| 56 | +proc hideHover*(self: HoverComponent) = hoverComponentHideHover(self) |
| 57 | +proc showHoverDelayed*(self: HoverComponent) = hoverComponentShowHoverDelayed(self) |
| 58 | +proc cancelHover*(self: HoverComponent) = hoverComponentCancelHover(self) |
| 59 | +proc showHoverView*(self: HoverComponent, view: View, location: Point) = hoverComponentShowHoverView(self, view, location) |
| 60 | +{.pop.} |
| 61 | + |
| 62 | +# Implementation |
| 63 | +when implModule: |
| 64 | + import std/[sequtils, streams, strformat] |
| 65 | + import misc/[util, custom_logger, rope_utils, async_process] |
| 66 | + import nimsumtree/[rope, buffer, clock] |
| 67 | + import document, document_editor, text_component, language_server_component |
| 68 | + import scripting_api except DocumentEditor, HoverComponent, AstDocumentEditor |
| 69 | + import command_service, service, platform_service, platform/platform |
| 70 | + |
| 71 | + logCategory "hover-component" |
| 72 | + |
| 73 | + proc handleModsChanged(self: HoverComponent, oldMods: Modifiers, newMods: Modifiers) {.gcsafe, raises: [].} |
| 74 | + |
| 75 | + var HoverComponentId: ComponentTypeId = componentGenerateTypeId() |
| 76 | + |
| 77 | + proc markDirty(self: HoverComponent) = |
| 78 | + self.owner.DocumentEditor.markDirty() |
| 79 | + |
| 80 | + proc getHoverComponent*(self: ComponentOwner): Option[HoverComponent] {.gcsafe, raises: [].} = |
| 81 | + return self.getComponent(HoverComponentId).mapIt(it.HoverComponent) |
| 82 | + |
| 83 | + proc newHoverComponent*(settings: HoverSettings): HoverComponent = |
| 84 | + return HoverComponent( |
| 85 | + typeId: HoverComponentId, |
| 86 | + settings: settings, |
| 87 | + initializeImpl: (proc(self: Component, owner: ComponentOwner) = |
| 88 | + let self = self.HoverComponent |
| 89 | + let platform = getServices().getService(PlatformService).get.platform |
| 90 | + self.onModsChangedHandle = platform.onModifiersChanged.subscribe proc(change: tuple[old: Modifiers, new: Modifiers]) {.gcsafe.} = |
| 91 | + self.handleModsChanged(change.old, change.new) |
| 92 | + ), |
| 93 | + deinitializeImpl: (proc(self: Component) = |
| 94 | + let self = self.HoverComponent |
| 95 | + if self.showHoverTask.isNotNil: |
| 96 | + self.showHoverTask.pause() |
| 97 | + if self.hideHoverTask.isNotNil: |
| 98 | + self.hideHoverTask.pause() |
| 99 | + let platform = getServices().getService(PlatformService).get.platform |
| 100 | + platform.onModifiersChanged.unsubscribe self.onModsChangedHandle |
| 101 | + ), |
| 102 | + ) |
| 103 | + |
| 104 | + proc handleModsChanged(self: HoverComponent, oldMods: Modifiers, newMods: Modifiers) = |
| 105 | + if not self.isHovered: |
| 106 | + return |
| 107 | + self.mouseHoverMods = newMods |
| 108 | + if self.showHover: |
| 109 | + self.showHoverDelayed() |
| 110 | + |
| 111 | + proc hoverComponentClearOverlayViews(self: HoverComponent) = |
| 112 | + for overlay in self.overlayViews: |
| 113 | + overlay.onMarkedDirty.unsubscribe(self.onHoverViewMarkedDirtyHandle) |
| 114 | + overlay.onDetached.unsubscribe(self.hoverViewCallbackHandles) |
| 115 | + self.overlayViews.setLen(0) |
| 116 | + |
| 117 | + proc hoverComponentClearHoverView(self: HoverComponent) = |
| 118 | + if self.hoverView != nil: |
| 119 | + self.hoverView.onMarkedDirty.unsubscribe(self.onHoverViewMarkedDirtyHandle) |
| 120 | + self.hoverView.onDetached.unsubscribe(self.hoverViewCallbackHandles) |
| 121 | + self.hoverView = nil |
| 122 | + |
| 123 | + proc detachHoverView(self: HoverComponent) = |
| 124 | + if self.hoverView != nil: |
| 125 | + self.overlayViews.add(self.hoverView) |
| 126 | + self.hoverView = nil |
| 127 | + self.showHover = false |
| 128 | + |
| 129 | + proc hoverComponentShowHoverForAsync(self: HoverComponent, cursor: Point): Future[void] {.async.} = |
| 130 | + if self.hideHoverTask.isNotNil: |
| 131 | + self.hideHoverTask.pause() |
| 132 | + |
| 133 | + let document = self.owner.DocumentEditor.currentDocument |
| 134 | + |
| 135 | + let ls = document.getLanguageServerComponent().getOr: |
| 136 | + log lvlWarn, &"Failed to show hover for '{cursor}': No language server" |
| 137 | + return |
| 138 | + |
| 139 | + let hoverInfo = await ls.getHover(document.filename, cursor.toCursor) |
| 140 | + if self.owner.isNil: |
| 141 | + return |
| 142 | + |
| 143 | + if hoverInfo.getSome(hoverInfo): |
| 144 | + self.showHover = true |
| 145 | + # self.showSignatureHelp = false # todo |
| 146 | + self.hoverScrollOffset = 0 |
| 147 | + self.hoverText = hoverInfo |
| 148 | + self.clearHoverView() |
| 149 | + self.hoverLocation = cursor |
| 150 | + else: |
| 151 | + self.clearHoverView() |
| 152 | + self.showHover = false |
| 153 | + |
| 154 | + self.markDirty() |
| 155 | + |
| 156 | + # proc showHover*(self: HoverComponent, message: string, location: Cursor) = |
| 157 | + # if self.hideHoverTask.isNotNil: |
| 158 | + # self.hideHoverTask.pause() |
| 159 | + |
| 160 | + # self.showHover = true |
| 161 | + # # self.showSignatureHelp = false # todo |
| 162 | + # self.hoverScrollOffset = 0 |
| 163 | + # self.hoverText = message |
| 164 | + # self.clearHoverView() |
| 165 | + # self.hoverLocation = location |
| 166 | + |
| 167 | + # self.markDirty() |
| 168 | + |
| 169 | + proc hoverComponentShowHoverView(self: HoverComponent, view: View, location: Point) = |
| 170 | + if self.hideHoverTask.isNotNil: |
| 171 | + self.hideHoverTask.pause() |
| 172 | + |
| 173 | + self.clearHoverView() |
| 174 | + self.showHover = true |
| 175 | + self.hoverScrollOffset = 0 |
| 176 | + self.hoverView = view |
| 177 | + self.hoverLocation = location |
| 178 | + self.onHoverViewMarkedDirtyHandle = view.onMarkedDirty.subscribe proc() = self.markDirty() |
| 179 | + view.onDetached.subscribe self.hoverViewCallbackHandles, proc() = self.detachHoverView() |
| 180 | + |
| 181 | + self.markDirty() |
| 182 | + |
| 183 | + proc hoverComponentCancelHover(self: HoverComponent) = |
| 184 | + if self.showHoverTask.isNotNil: |
| 185 | + self.showHoverTask.pause() |
| 186 | + |
| 187 | + proc hoverComponentHideHover(self: HoverComponent) = |
| 188 | + ## Hides the hover information. |
| 189 | + self.clearHoverView() |
| 190 | + self.showHover = false |
| 191 | + self.markDirty() |
| 192 | + |
| 193 | + proc hideHoverDelayed*(self: HoverComponent) = |
| 194 | + ## Hides the hover information after a delay. |
| 195 | + if self.showHoverTask.isNotNil: |
| 196 | + self.showHoverTask.pause() |
| 197 | + |
| 198 | + let hoverDelayMs = self.settings.delay.get() |
| 199 | + if self.hideHoverTask.isNil: |
| 200 | + self.hideHoverTask = startDelayed(hoverDelayMs, repeat=false): |
| 201 | + self.hideHover() |
| 202 | + else: |
| 203 | + self.hideHoverTask.interval = hoverDelayMs |
| 204 | + self.hideHoverTask.reschedule() |
| 205 | + |
| 206 | + proc runHoverCommand*(self: HoverComponent) = |
| 207 | + try: |
| 208 | + let commands = getServices().getService(CommandService).get |
| 209 | + var command = ".show-hover-for-current" |
| 210 | + var configCommand = self.settings.command.get() |
| 211 | + if configCommand != nil: |
| 212 | + let modsKey = $self.mouseHoverMods |
| 213 | + if configCommand.kind == jsonex.JObject and configCommand.hasKey(modsKey): |
| 214 | + configCommand = configCommand[modsKey] |
| 215 | + |
| 216 | + let (name, args, ok) = configCommand.parseCommand() |
| 217 | + if name == "": |
| 218 | + return |
| 219 | + if ok: |
| 220 | + discard commands.executeCommand(name & " " & args, record = false) |
| 221 | + return |
| 222 | + |
| 223 | + discard commands.executeCommand(command, record = false) |
| 224 | + except CatchableError as e: |
| 225 | + log lvlError, &"Failed to execute hover command: {e.msg}" |
| 226 | + |
| 227 | + proc hoverComponentShowHoverDelayed(self: HoverComponent) = |
| 228 | + ## Show hover information after a delay. |
| 229 | + |
| 230 | + if self.hideHoverTask.isNotNil: |
| 231 | + self.hideHoverTask.pause() |
| 232 | + |
| 233 | + let hoverDelayMs = self.settings.delay.get() |
| 234 | + if self.showHoverTask.isNil: |
| 235 | + self.showHoverTask = startDelayed(hoverDelayMs, repeat=false): |
| 236 | + self.runHoverCommand() |
| 237 | + else: |
| 238 | + self.showHoverTask.interval = hoverDelayMs |
| 239 | + self.showHoverTask.reschedule() |
| 240 | + |
| 241 | + proc init_module_hover_component*() {.cdecl, exportc, dynlib.} = |
| 242 | + discard |
0 commit comments